批处理怎样将文件夹内的文件用文件夹名来重命名？

pujizhongxue · 发表于 2022-12-21 18:45:00

我手上有几十个文件夹，每个文件夹内都只有一个文件，我想将这些文件夹内的文件都用其所在的文件夹名称来重命名，系统是win10家庭版，请大家帮忙。

hfxiang · 发表于 2022-12-21 19:51:51

@echo off
@rem 保存为ANSI格式
cd /d "%~dp0"
for /f %%a in ('dir /a-d/s/b') do (
if "%%~fa" NEQ "%~f0" (
for %%b in ("%%~dpa.") do (
move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
)
)
)

复制代码

pujizhongxue · 发表于 2022-12-21 20:16:51

回复 2# hfxiang
十分感谢，但是有个奇怪的问题，这个批处理为什么换一个文件夹就失效了呢？

hfxiang · 发表于 2022-12-21 20:27:34

回复 3# pujizhongxue

能把问题描述得具体些吗？

77七 · 发表于 2022-12-21 20:28:01

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
pushd "%%i"
for /f "delims=" %%a in ('dir /b /a-d') do (
ren "%%a" "%%~ni%%~xa"
)
popd
)
pause

复制代码

pujizhongxue · 发表于 2022-12-21 20:49:36

回复 4# hfxiang
@echo off
@rem 保存为ANSI格式
cd /d "%~dp0"

for /f %%a in ('dir /a-d/s/b') do (
if "%%~fa" NEQ "%~f0" (
for %%b in ("%%~dpa.") do (
move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
pause)
)
)
我加了一个pause，发现提示是这样写的：找不到系统指定文件

hfxiang · 发表于 2022-12-21 21:12:03

回复 6# pujizhongxue

用你加pause后的代码测试，只是多了个暂停，其它一切正常。

77七 · 发表于 2022-12-21 23:16:48

本帖最后由 77七于 2022-12-21 23:18 编辑

回复 7# hfxiang

应该是文件夹名或者文件名含特殊符号了

Batcher · 发表于 2022-12-22 09:45:30

回复 6# pujizhongxue

加个echo命令观察一下，看看代码是试图进行什么操作的时候报错了。

for /f %%a in ('dir /a-d/s/b') do (
if "%%~fa" NEQ "%~f0" (
      for %%b in ("%%~dpa.") do (
         echo move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
         move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
         pause
      )
)
)

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理怎样将文件夹内的文件用文件夹名来重命名？