[文本处理] [已解决]文字txt内文字,批处理如何删除最尾的符号？

skpkmon

如何bat批量删除最尾的符号？请帮忙，谢谢

ShowCode

回复 1# skpkmon


    请选2个txt文件作为例子打包上传到网盘

skpkmon

回复 2# ShowCode

https://vip.123pan.cn/1714872/%E5%88%86%E4%BA%AB/Desktop.rar

Nsqs

powershell -noprofile executionpolicy bypass "(gc 'a.txt') -replace '(.+).$','$1'">b.txt

hfxiang

回复 3# skpkmon

用第3方工具sed（ http://bcn.bathome.net/tool/4.9/sed.exe ）实现方法如下：
[code]
sed -r "/[ ,.;\t]+$/s///" 原始有符号.txt>删除符号.txt
[code]

ShowCode

回复 1# skpkmon

@echo off
set "OldFile=1.txt"
set "NewFile=2.txt"
cd /d "%~dp0"
powershell "(Get-Content '%OldFile%') -replace '[,.;!]+$'" >"%NewFile%"
复制代码

qixiaobin0715

如果还有别的符号可在第4行后面按照第4行的方式添加即可：

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in (1.txt) do (
    set "str1=%%i.........."
    set "str1=!str1:,..........=.!"
    for %%j in ("!str1!") do echo,%%~nj
))>2.txt
复制代码

注意：文本中不能存在“/\*?”之类的干扰符号。

ShowCode

回复 7# qixiaobin0715


    误删 setlocal enabledelayedexpansion

77七

@echo off
cd /d "%~dp0"
set _"."=1
set _","=1
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		set str=%%b
		setlocal enabledelayedexpansion
		if "!str!" equ "" (
			echo=
		) else (
			set _str=!str:~-1!
			if defined _"!_str!" (
				echo=!str:~0,-1!
			) else (
				echo !str!
			)
		)
		endlocal
	))>"%%~ni_2.txt"
)
pause
复制代码

skpkmon

回复 6# ShowCode


成功了，谢谢你帮忙，这里是好地方，高手如云，再次多谢申出援手的师兄！

qixiaobin0715

回复 8# ShowCode
谢谢提醒，已修改。

qixiaobin0715

这样可能更通用一些：

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in (1.txt) do (
    set "str=%%i.........."
    set "str=!str:,..........=!"
    set "str=!str:...........=!"
    set "str=!str:..........=!"
    echo,!str!
))>2.txt
pause
复制代码

存在“/\*?”也没问题。

ShowCode

回复 12# qixiaobin0715


    原始文件里的空行被误删了

aloha20200628

先给一段纯P代码对应一楼示例的解法》

@echo off
::定义中英文标点符号链表
set "ps=,.;，。；"
(for /f "tokens=1* delims=:" %%1 in ('findstr /n ".*" 原始有符号.txt') do (
	set "_s=%%2"
	if not defined _s (echo,) else (
		setlocal enabledelayedexpansion &set "endC=!_s:~-1!"
		for %%c in ("!endC!") do if "!ps!" neq "!ps:%%~c=!" (set "_s=!_s:~,-1!")
		echo,!_s!&endlocal
	)
))>"处理结果.txt"
endlocal&exit/b
复制代码

借以上代码复习一遍多年老帖流传下来的三个纯P造码要点》
一。在 for 循环语句块内保全读入文本行中 ^&!%<\|/> 等特殊字符的关键，是安排变量延迟的开关位置，参考句式如下》
        for /f "delims=" %%a in (test.txt) do (
                set "s=%%a"
                setlocal enabledelayedexpansion
                ... 处理文本行变量 !s! ...
                endlocal
        )
        也许还有其他技法，请知者分享。
二。在 for 循环语句块内保留读入文件中的空行，其捷径是利用 findstr /n 功能，参考句式如下》
        for /f "tokens=1* delims=:" %%1 in (test.txt) do (
                set "s=%%2"
                if not defined s ( ...空行处理... ) else (
                        ...非空行处理...
                )
        )
        也许还有其他技法，请知者分享。
三。调用字符串截取和替换函数时，若内外层参数均为变量时须讲究变量类型，形象而言就是内层变量须为百分号变量(普通全局变量/循环变量/命令行变量)，外层变量须是感叹号变量，例如》!lv:%gv%=!, !v:%%a=!, !v:%1=! 都是有效的。反之 %gv:!lv!=% 是无效的。
        若上述有缺，请知者补全。

qixiaobin0715

回复 14# aloha20200628
读入文本空行也可采取  “(for循环 + set /p)<被读入的文件”  的方式，稍复杂些，也算是回答了13楼ShowCode的提醒。以本帖为例：

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('find /c /v "" 1.txt') do set /a n=%%j
(for /l %%i in (1,1,!n!) do (
    set /p str=
    if not defined str (
        echo,
    ) else (
        set "str=!str!..........
        set "str=!str:,..........=!"
        set "str=!str:...........=!"
        set "str=!str:..........=!"
        echo,!str!
        set str=
    )
))<1.txt>2.txt
pause
复制代码