[分享]批处理只保留字符串里面的数字

Batcher

【问题描述】

怎么提取字符串里面的数字，删除其它字符，
比如：123Bat456Home789论坛
结果：123456789

Batcher

【解决方案】

test_1.bat
这个代码有问题，请参考6楼的方法。

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "StrOld=123Bat456Home789论坛"
   
4. set "StrTmp=%StrOld%"
   
5. for /l %%i in (0 1 9) do (
   
6.     set "StrTmp=!StrTmp:%%i= !"
   
7. )
   
8. set "StrNew=%StrOld%"
   
9. for %%i in (!StrTmp!) do (
   
10.     set StrNew=!StrNew:%%i=!
    
11. )
    
12. echo,!StrNew!
    
13. pause

复制代码

Batcher

test_2.bat

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "str=123Bat456Home789论坛"
   
4. set "num="
   
5. :Loop
   
6. set "char=%str:~0,1%"
   
7. if %char% geq 0 (
   
8.     if %char% leq 9 (
   
9.         set "num=!num!%char%"
   
10.     )
    
11. )
    
12. set str=%str:~1%
    
13. if "%str%" neq "" (
    
14.     goto :Loop
    
15. )
    
16. echo,%num%
    
17. pause

复制代码

Batcher

test_3.bat

1. @echo off
   
2. set "StrOld=123Bat456Home789论坛"
   
3. for /f "delims=" %%i in ('powershell "'%StrOld%' -replace '[^\d]*',''"') do (
   
4.     set "StrNew=%%i"
   
5. )
   
6. echo,%StrNew%
   
7. pause

复制代码

hfxiang

来个第3方工具gawk（ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）的实现方法

1. 
   
2. echo;123Bat456Home789 论坛|gawk -vOFS="" -F"[^0-9]+" "$1=$1"
   

复制代码

qixiaobin0715

回复 2# Batcher
2楼代码有bug。如果对于数字分隔的非数字字段来说，存在前面字段包含于后面的字段，就会出现问题，比如：

1. set "StrOld=123Bat456BatHome789论坛"

复制代码

前面的Bat字段包含于后面的BatHome字段，处理后的结果为：

1. 123456Home789

复制代码

这样应当可以：

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "StrOld=123Bat456BatHome789论坛"
   
4. for /l %%i in (0 1 9) do (
   
5.     set "StrOld=!StrOld:%%i= %%i !"
   
6. )
   
7. for %%i in (!StrOld!) do (
   
8.     if %%i geq 0 (
   
9.         if %%i leq 9 (
   
10.             set StrNew=!StrNew!%%i
    
11.         )
    
12.     )
    
13. )
    
14. echo,!StrNew!
    
15. pause

复制代码

Batcher

回复 5# hfxiang


再来个sed

1. echo 123Bat456Home789论坛 | sed "s/[^0-9]//g"

复制代码

77七

回复 5# hfxiang


   大佬，请教下，我把命令写到for里面，为什么结果之前多了一个数字 1 呢？

1. @echo off
   
2. cd.>a1.txt
   
3. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
4.         for /f "delims=" %%j in ('echo;%%~ni^|gawk -vOFS^="" -F"[^0-9]+" "$1^=$1"') do (
   
5.                 echo [%%j]
   
6.         )
   
7. )
   
8. pause

复制代码

ShowCode

回复 8# 77七

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
3.         for /f "delims=" %%j in ('echo %%~ni ^| gawk -v OFS^="" -F "[^0-9]+" "$1=$1"') do (
   
4.                 echo [%%j]
   
5.         )
   
6. )

复制代码

C:\Test>dir /b *.txt
123Bat456Home789.txt

C:\Test>1.bat
[123456789]

C:\Test>gawk --version
GNU Awk 5.1.0, API: 3.0

77七

回复 9# ShowCode


   感谢大佬帮助！我测试了以字母开头的文件名，结果为空，比如 a1.txt。用5楼代码 测试 字母开头的字符串，结果同样为空。

aloha20200628

借8楼旧帖新续，也给几个版本仅供参考，示例题型》提取并链接当前目录中全部文本文件名包含的数值字段
一。采用纯P递归方法
二。调用jscript正则替换方法
三。调用sed.exe正则替换方法
四。调用powershell正则替换方法

1. 
   
2. @set @x=1 /* &@echo off &setlocal
   
3. for %%F in (*.txt) do (
   
4.         set "_F=" &(call :get#n "%%~nF")
   
5.         for /f %%a in (' cscript /nologo /e:jscript "%~f0" "%%~nF" ') do echo,%%a
   
6.         for /f %%a in (' echo,"%%~nF"^|sed "s/[^0-9]//g" ') do echo,%%a
   
7.         for /f %%a in (' powershell " '%%~nF' -replace '[^\d]' " ') do echo,%%a
   
8. )
   
9. endlocal&pause&exit/b
   
10. :get#n
    
11.         if "%~1"=="" echo,%_F%&exit/b
    
12.         set s=%~1
    
13.         set c=%s:~,1%
    
14.         if "%c%" geq "0" if "%c%" leq "9" set _F=%_F%%c%
    
15.         call :get#n "%s:~1%"
    
16.         exit/b
    
17. */
    
18. v=WSH.arguments, WSH.echo(v(0).replace(/[^\d]/g,'')), WSH.quit();
    

复制代码

WHY

回复 10# 77七


    echo;a1|gawk -vOFS="" -F"[^0-9]+" "$1=$1"
这个时候 $1 值为空，可能 gawk 认为 "$1=$1" 赋值后条件不成立，所以没有输出。

1. for /f %%i in ('echo;a123Bat456Home789 论坛^|gawk "{gsub(/[^0-9]+/, "")}1"') do echo [%%i]

复制代码

或者

1. for /f %%i in ('echo;a123Bat456Home789 论坛^|gawk -vOFS^="" -F"[^0-9]+" "NF=NF"') do echo [%%i]

复制代码

试试。

77七

回复 11# aloha20200628


   感谢大佬分享！正则替换很强大。

77七

回复 12# WHY


   感谢大佬分享！之前没有结果，我还以为是转义出现了问题，把引号内的等号也转义了，结果却多了个数字1。5楼的gawk代码我看不懂，尤其是$1，经过您指点，我大概理解是 批处理中的 第一列的意思，我尝试添加了第二列，结果居然是对的。

1. echo;a1b2c3|gawk -vOFS="" -F"[^0-9]+" "$1=$1;$2=$2"

复制代码

ShowCode

回复 10# 77七

1. @echo off
   
2. for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
   
3.     for /f "delims=" %%j in ('echo %%~ni ^| gawk -v OFS^="" -F "[^0-9]+" "NF+=0"') do (
   
4.         echo [%%j]
   
5.     )
   
6. )

复制代码