批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程
[批处理文件精品]批处理版照片整理器[批处理文件精品]纯批处理备份&还原驱动在线第三方下载
返回列表 发帖

批处理与其它语言、脚本混合编程

批处理与VBS混合编程1
http://www.cn-dos.net/forum/viewthread.php?tid=25333

这个想法我思考了很久。

巧妙利用 bat 和 vbs 的语法特征,让同一个文件,被 cmd.exe 识别成批处理,让 wscrpt.exe 识别成 vbs,并且同时符合两者的语法,并且保证都没有错误,保证两者的高度兼容。经过一个通宵的努力,我实现了这种 bat/vbs 复合编程。

一个 批处理  .vbs 文件,在前面加一段代码(头),就变成了 .bat 批处理,注意,没有生成临时文件,不用修改任何原有代码。

例子:保存下列代码为 test.bat,注意是批处理,但是这个批处理却成功的被 wsh 解析执行了!
  1. :On Error Resume Next
  2. Sub bat
  3. echo off & cls
  4. echo Batching_codez_here_following_vbs_rules & pause
  5. start wscript -e:vbs "%~f0"
  6. Exit Sub
  7. End Sub
  8. MsgBox "This is vbs"
复制代码
保存代码为 test.bat,可以看到 echo 出来的东西和 msgbox 出来的消息,呵呵

以上代码只是一个示例,同时执行了 一段 批处理 和 vbs,没有生成临时文件。用了大量的 hack 技巧

下面粗略解释下代码

:On Error Resume Next
cmd.exe 识别成一段注释
wscript.exe 这样识别, : 在vbs语法里代表分行,然后 On Error Resume Next,也就是让WSH忽略一些错误

start wscript -e:vbs "%~f0"
cmd.exe 识别成:启动 wscript.exe ,其参数是:
① -e:vbs  设定以vbs解析文件自身
② "%~f0" 指这个批处理本身。

wscript.exe 把这句识别成:调用一个叫 start 的函数,函数参数是 wscript 这个变量,然后用这个函数的结果来 减去 e。接下来是又是一个 : ,分行,然后又是调用一个名叫 vbs 的函数,参数是字符: "%~f0"

这句是最为精巧的,因为它成功的让 vbs 引擎解释了一段批处理,而且没有错误!当然这些 start()、vbs()函数是不存在的,但是会被 cmd.exe 当成命令执行。为什么不用  wscript //e:vbs "%~f0" 来执行呢?vbs解析会出错的,呵呵

这段代码的核心思想已经介绍完毕了。下面,为了让 批处理 以vbs调用其自身后,马上退出,我们需要 exit 或者 goto :eof,但是 goto call exit 在vbs又是一个关键词,所以我们只能用符合 vbs 语法的 exit sub,所以我们在第二句加一个
sub bat,其实 cmd.exe 寻找了一个叫 sub.exe 的命令,但是这个命令是不存在的,cmd.exe 跳过。然后在 6、7 句加一个 exit sub 以及 end sub,让 批处理结束,同时又符合 vbs 的语法

那个 echo off & cls  ,批处理的意思就是相当于 @echo off ,但是 vbs 不认 @ 符号,所以改成 echo off & cls , vbs 可以解析为,调用一个叫 echo() 的函数,参数为 off & cls ,也就是两个字符串 off 和 cls 相加

Well,接下来,你可以自由地在批处理中书写vbs脚本了,效率和真正的vbs一样高!

这段代码的好处是:不用生成临时文件。其实用 echo 或者 more 或者 find 来生成临时vbs很浪费系统资源的,用我写的这段代码,就完全免去了这些麻烦。直接混合编程,以 start wscript -e:vbs "%~f0" 为界限,上面写 批处理,下面写 vbs,并行不悖!

好了,偶累了,休息去了。大家如果有更好的想法,请回帖,大家一起讨论。

代码以 GPL 发布,也就是说,你用了 est 的代码,你的代码就得给我开源,嘿嘿

================华丽的分割线====================

2006-12-5 新增:支持传递参数的版本:利用了vbs 对 ' 注释敏感的特性
  1. :On Error Resume Next
  2. :Sub bat
  3. echo off & cls
  4. echo Batching_codez_here_following_vbs_rules & pause >nul
  5. echo '>nul & start "" wscript //e:vbscript "%~f0" %*
  6. Exit Sub : End Sub
  7. MsgBox "This is vbs"
  8. for each i in wscript.arguments
  9. wscript.echo i
  10. next
复制代码
批处理与VBS混合编程2
http://www.cn-dos.net/forum/viewthread.php?tid=39082
  1. ' 2>nul 3>nul&@echo off&cls
  2. '&start wscript.exe /nologo /e:vbs %0&exit
  3. createobject("sapi.spvoice").speak("ger lee shir joan gwaur DOS lieng merng")
  4. msgbox "这里是中国DOS联盟!",,"Welcome"
复制代码
批处理与reg混合编程
http://www.cn-dos.net/forum/viewthread.php?tid=42261
  1. REGEDIT4
  2. ;@cls&regedit/s "%~f0"&goto bat
  3. /*
  4. bat-reg {s11ss@www.cn-dos.net 2008-8-18}
  5. :bat
  6. :bat代码部分--------开始
  7. @echo off
  8. echo 在HKEY_CURRENT_USER下成功添加了项CN-DOS!
  9. pause
  10. exit/b
  11. bat代码部分--------结束
  12. */
  13. #reg代码部分--------开始
  14. [HKEY_CURRENT_USER\CN-DOS]
  15. #reg代码部分--------结束
复制代码
批处理与HTML混合编程1
http://www.cn-dos.net/forum/viewthread.php?tid=39655
  1. :<!--
  2. ::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::
  3. ::::::::1.执行HTML代码之前的BAT代码::::::::
  4. @echo off
  5. call :e Starting mshta...
  6. pause
  7. ::::::::1.执行HTML代码之前的BAT代码::::::::
  8. ::执行HTML代码:
  9. start mshta %0
  10. ::::::::2.执行HTML代码之后的BAT代码::::::::
  11. call :e Mshta is executing HTML codes...
  12. pause
  13. ::::::::2.执行HTML代码之后的BAT代码::::::::
  14. ::退出BAT:
  15. exit/b
  16. :::::::BAT函数定义部分:::::::
  17. :e
  18. echo %*
  19. goto :eof
  20. :::::::BAT函数定义部分:::::::
  21. ::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::
  22. -->
  23. <!--此句用来清除第一行的:-->
  24. <script>document.body.innerText=""</script>
  25. <!--------------------------HTML-------------------------->
  26. <body onkeypress=window.close()>
  27. <hr color=red>
  28. <marquee><font color=green>HTML Codes</font></marquee>
  29. <hr color=red>
  30. <!--------------------------HTML-------------------------->
  31. <!--        BAT & HTML        {s11ss@www.cn-dos.net/forum 2008-4-22}
  32. 思路:当此文件被当作BAT文件执行时,未执行到HTML代码部分时就已退出;
  33.       当此文件被当作HTML文件执行时,BAT代码部分被注释,不会被执行。
  34. -->
复制代码
批处理与HTML混合编程2
http://www.cn-dos.net/forum/viewthread.php?tid=46757
  1. :<html><!--
  2. ::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::
  3. ::::::::1.执行HTML代码之前的BAT代码::::::::
  4. @echo off
  5. call :e Starting hh...
  6. pause
  7. ::::::::1.执行HTML代码之前的BAT代码::::::::
  8. ::执行HTML代码:
  9. start hh "%~f0"
  10. ::::::::2.执行HTML代码之后的BAT代码::::::::
  11. call :e hh is executing HTML codes...
  12. pause
  13. ::::::::2.执行HTML代码之后的BAT代码::::::::
  14. ::退出BAT:
  15. exit/b
  16. :::::::BAT函数定义部分:::::::
  17. :e
  18. echo %*
  19. goto :eof
  20. :::::::BAT函数定义部分:::::::
  21. ::::::::::::::::::::::::::::::::BAT::::::::::::::::::::::::::::::::
  22. -->
  23. <!--此句用来清除第一行的:-->
  24. <script>document.body.innerText=""</script>
  25. <!--------------------------HTML-------------------------->
  26. <body onkeypress=window.close()>
  27. <hr color=red>
  28. <marquee><font color=green>HTML Codes</font></marquee>
  29. <hr color=red>
  30. <!--------------------------HTML-------------------------->
  31. <!--        BAT & HTML        {[email]s11ss@www.cn-dos.net[/email]/forum 2009-4-2}
  32. 思路:当此文件被当作BAT文件执行时,未执行到HTML代码部分时就已退出;
  33.       当此文件被当作HTML文件执行时,BAT代码部分被注释,不会被执行。
  34. -->
复制代码
BAT与AutoIt混合编程
http://bbs.bathome.net/thread-5668-1-1.html

BAT与REG混合编程
http://bbs.bathome.net/thread-2803-1-1.html

BAT与VBS混合编程
http://bbs.bathome.net/thread-566-1-1.html
http://bbs.bathome.net/thread-1163-1-1.html

BAT与JS混合编程
http://bbs.bathome.net/thread-554-1-1.html

BAT与Perl混合编程
http://bbs.bathome.net/thread-11832-1-1.html
2

评分人数

    • erjnasrtnws: 感谢分享 很有用的技术!!!!我只会ba ...技术 + 1
    • 523066680: 感谢分享PB + 20
【批处理在线视频分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

我帮忙写的代码不需要付钱,不用找我要支付宝或微信账号。如果一定要给,请到微信群给大家发红吧。

曾经有过这么一个复合编程
利用VBS将其批处理调用在后台运行, 这个帖子学习到不少东西, 不过消化需要一些时间

TOP

回复 2楼 的帖子

混合编程的大意是指通一段代码能在两种或多种平台下运行,比如既可以作为BAT运行又可以作为BAT运行。
而用BAT动态生成一个VBS再调用,或者用VBS动态生成一个BAT再调用,则不属于混合编程的范围,你说的VBS调用BAT实现后台运行大概属于这种情况吧。
【批处理在线视频分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

我帮忙写的代码不需要付钱,不用找我要支付宝或微信账号。如果一定要给,请到微信群给大家发红吧。

TOP

很好的帖子,又学到一招

TOP

还是这个帖子丰富,学习了。
综合型编程论坛
Writing Code That Nobody Else Can Read.

TOP

我是新手  这几天刚开始逛批处理之家  也看了一些比较有意思的例子
想问下lz    能不能介绍下批处理可以做的事情   以及现在还不能做  以后可能可以做的事情

TOP

返回列表