[分享]BAT和JS轻松实现混合编程

youxi01

JS可以利用/* */来实现 多行注释，利用这个特点,我们可以轻松实现JS和bat的混合编程,即:一批处理文件，在作为批处理文件的同时，还可以被脚本引擎WSH识别,演示代码如下:

1. 
   
2. @set @this_call_started=1 /*
   
3. @echo off
   
4. echo 前面的 /* 在 JS 中已经被定义为注释，所以
   
5. echo 在运行的时候，下面的代码将不被js解析。
   
6. echo hello,world
   
7. call CScript.EXE "%~dpnx0" //Nologo //e:jscript %*
   
8. goto :end
   
9. 下面这句是告诉 js 说明文字已经结束，开始解析。
   
10. rem */
    
11. //这里写入JS代码；
    
12. pop=WScript.CreateObject("Wscript.Shell")
    
13. pop.popup ("这是一段JS代码",4,"HOHO")
    
14. //JS代码结束。
    
15. /* 又开始JS注释
    
16. ============以下自由书写批处理代码；=======
    
17. :end
    
18. echo 程序运行完成，感觉怎么样？
    
19. pause>nul
    
20. @rem */

复制代码

ieutk

厉害呀，什么时候也来个bat和vbs混合的呀！

HAT

总结了 3 种方法。（只是第一行内容不一样）

1. 缺陷：修改了一个变量的值

1. @set @a=1/*
   
2. @echo off
   
3. echo Hello World!
   
4. start wscript -e:jscript "%~f0"
   
5. pause
   
6. goto :eof
   
7. */
   
8. WSH.Echo("Hello World!");

复制代码

2. 缺陷：清屏了

1. echo=1/*>nul&@cls
   
2. @echo off
   
3. echo Hello World!
   
4. start wscript -e:jscript "%~f0"
   
5. pause
   
6. goto :eof
   
7. */
   
8. WSH.Echo("Hello World!");

复制代码

3.

1. @if (1==1) @end/*
   
2. @echo off
   
3. echo Hello World!
   
4. start wscript -e:jscript "%~f0"
   
5. pause
   
6. goto :eof
   
7. */
   
8. WSH.Echo("Hello World!");

复制代码

转自：http://www.cn-dos.net/forum/viewthread.php?tid=50369

ai20110304

回复 3# HAT


    获益匪浅。谢谢

woetu

还有一种

1. 
   
2. @if (0)==(0) echo off
   
3. cscript -nologo -e:jscript %~s0
   
4. goto :EOF
   
5. @end
   
6. 
   
7. // ****************************  JavaScript  *******************************
   

复制代码