[已解决]批处理如何把文本1的文件复制到文本2的路径？

jinzeyu · 发表于 2011-3-20 14:19:15

本帖最后由 jinzeyu 于 2012-1-9 17:18 编辑

文本1：（1.txt）

c:\123.txt
c:\245.txt
...

复制代码

文本2:（2.txt）

d:\123.txt
d:\245.txt
...

复制代码

要求：
把c:\123.txt复制到d:\123.txt
把c:\245.txt复制到d:\245.txt
...

hanyeguxing · 发表于 2011-3-20 18:23:15

本帖最后由 hanyeguxing 于 2011-3-20 18:30 编辑

@echo off
set a=-1
for /f "delims=" %%a in (文本1.txt) do (
set/a a+=1
call:a "%%~a"
)
exit
:a
if %a% geq 1 set "n=skip=%a% "
for /f "%n%delims=" %%a in (文本2.txt) do (
copy %1 "%%~a"
goto:eof
)

复制代码

1，根据需要选择copy的参数
2，不要让文本中有空行

wc726842270 · 发表于 2011-3-21 06:00:42

2# hanyeguxing
有几点不明白的地方
1。首先是对于LZ的问题真是没弄清楚
2，想了解一下SET “N=SKIP=%A% ”和“%n%delims="的用意，但是因为对于“1”实在是没弄清，所以无法构造条件。能否请教一下版主的用意。

hanyeguxing · 发表于 2011-3-21 07:32:59

本帖最后由 hanyeguxing 于 2011-3-21 07:42 编辑

3# wc726842270
1，楼主提的问题本质上说就是：实现两个文本内容的一一对应读取
2，skip=k参数使用时，有两个问题需要注意
第一，k不能为0，所以if %a% geq 1 set "n=skip=%a% "实际就是if %a% neq 0 set "n=skip=%a% "，也就是当a为0时，n为空（即不使用skip），当a不为0，n为skip=数字
第二，k可以为变量，但不能为延迟的变量，所以此文本2的命令for 语句必须在文本1解析的for语句外
以for /r为例说明：for /R "路径" %%a in (set) do (子句)
这里只有()内才可以使用%%b和!n!这样的变量，"路径"中是不可以的，只能使用%1或%n%这样的变量。for /f语句也是如此。原因很简单，%%b和!n!这样的变量在预处理时没有获取，导致for无法使用此参数

bluewing009 · 发表于 2011-3-21 08:05:57

本帖最后由 bluewing009 于 2011-3-21 08:09 编辑

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt) do (
set /a NO.+=1
set copy_path_1=%%i
for /f "tokens=1* delims=:" %%i in ('findstr /n .* 2.txt') do if %%i==!NO.! set copy_path_2=%%j
echo copy !copy_path_1! !copy_path_2!
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何把文本1的文件复制到文本2的路径？

评分

评分

评分

列行号对应

评分