批处理把十进制转换成二,八,十六进制

tmplinshi

转自: http://www.52sky.org/article/Computer%20Program/44.html

1. @echo off
   
2. :start210
   
3. cls
   
4. echo      十进制转换
   
5. echo.
   
6. :start20
   
7. set a=&set b=&set c=&set d=&set e=&set f=
   
8. set /p a=请输入^<十进制^>:
   
9. set e=%a%&set f=%a%
   
10. if "%a%"=="" cls&goto start210
    
11. if %a%==dd cls&goto start210
    
12. if %a%==q exit
    
13. :30
    
14. set /a b=%a%%%2
    
15. set /a c=%a%/2
    
16. set d=%b%%d%
    
17. if %c% geq 2 set a=%c%&goto 30
    
18. if %c% equ 0 set c=
    
19. echo  对应 [二进制]: %c%%d%
    
20. set b=&set c=&set d=
    
21. :10
    
22. set /a b=%e%%%8
    
23. set /a c=%e%/8
    
24. set d=%b%%d%
    
25. if %c% geq 8 set e=%c%&goto 10
    
26. if %c% equ 0 set c=
    
27. echo  对应 [八进制]: %c%%d%
    
28. set a=&set b=&set c=&set d=
    
29. :20
    
30. set /a b=%f%%%16
    
31. if %b%==10 set b=A
    
32. if %b%==11 set b=B
    
33. if %b%==12 set b=C
    
34. if %b%==13 set b=D
    
35. if %b%==14 set b=E
    
36. if %b%==15 set b=F
    
37. set /a c=%f%/16
    
38. set d=%b%%d%
    
39. if %c% geq 16 set f=%c%&goto 20
    
40. if %c%==10 set c=A
    
41. if %c%==11 set c=B
    
42. if %c%==12 set c=C
    
43. if %c%==13 set c=D
    
44. if %c%==14 set c=E
    
45. if %c%==15 set c=F
    
46. if %c%==0 set c=
    
47. echo  对应 [16进制]: %c%%d%&echo/
    
48. goto start20

复制代码

jay_16

很厉害呀，能帮忙解释一下大概思路....?!谢谢

techon

十进制与2、8、16 进制转换方法
模上2取余，除以二取整，实际就是 除以二取余数，当正好除尽时（这里不包括小数），将余数由低位到高位排列 即相应十进制的二进制表，其他进制同理

▄︻┻═┳一

代码太长了，，，

Batcher

4# ▄︻┻═┳一


你给个短的呗

CrLf

5# Batcher

貌似随风写过32进制以内的通用版

plp626

不考虑速度的话，用递归，代码应该很简短

zm感兴趣否？

terse

对输入数长度判断在16位以内 如需处理更大数 可自加判断
当然 有人可处理转其他进制

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. set/p Str=请输入十进制数:
   
4. set "Code=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_@"
   
5. for %%i in (2 8 16) do set S=!str!&call:lp %%i _%%i&ECHO !str! 对应 [%%i进制]: !_%%i!
   
6. pause&exit
   
7. :lp
   
8. set U=!S!FEDCBA9876543210
   
9. SET/A U=0x!U:~16,1!,R=0
   
10. for /l %%i in (0 1 %U%) do (
    
11.    set/a "N=!S:~%%i,1!+(R*10),r=N%%%1,N/=%1"
    
12.    set B=!B!!N!
    
13.    if !B! equ 0 set "B="
    
14. )
    
15.    set %2=!Code:~%R%,1!!%2!
    
16.    if defined B set S=!B!&set B=&goto lp
    

复制代码

CrLf

7# plp626


不太明白，个人感觉常规方法就很简洁了啊

neorobin

感觉2,8,16这些特殊进制(2的正整数次方幂)可以用位运算直接些

523066680

虽然不见得好，做了就贴上来了,0123456789abcde 字符截取，这一块是抄学的。

1. 
   
2. @echo off
   
3. setlocal enabledelayedexpansion
   
4. set str=0123456789abcdef
   
5. 
   
6. call :lp 10 2
   
7. echo %num%
   
8. call :lp 10 8
   
9. echo %num%
   
10. call :lp 10 16
    
11. echo %num%
    
12. pause
    
13. 
    
14. :lp
    
15. set "num="
    
16. :in
    
17. set /a x=%1/%2,y=%1 %% %2
    
18. set num=!str:~%y%,1!%num%
    
19. if %x% neq 0 (call :in %x% %2) else (goto :eof)
    

复制代码

CrLf

10# neorobin

老兄好久不见...
不过我感觉位此处用运算并没有优势啊

neorobin

12# zm900612
仅适用于 正数 并且要求 算术右移实现, 想到这个就写出来了, 也可把每位都存入(开头的 0 不存入)变量, if !code!==0 set "code="

1. @echo off & setlocal enableDelayedExpansion
   
2. REM 2147483647=~(1<<31)
   
3. set HEX_TAB=0123456789ABCDEF
   
4. for /l %%a in () do (
   
5.   set /p num="Input a decimal number: "
   
6. 
   
7.   set /a "test=1<<31
   
8.   <nul set /p="Binary: "
   
9.   for /l %%i in (31 -1 0) do (
   
10.     set /a "bit=num&test,test>>=1,test&=~(1<<31),bit>>=%%i,bit&=~(1<<31)"
    
11.     <nul set /p=!bit!
    
12.   )
    
13.   echo.
    
14. 
    
15.   <nul set /p="Hex.: "
    
16.   set /a "test=0xf<<4*(32/4-1)
    
17.   for /l %%i in (28 -4 0) do (
    
18.     set /a "bit=num&test,test>>=4,test&=(1<<28)-1,bit>>=%%i,bit&=(1<<28)-1"
    
19.     for %%p in (!bit!) do <nul set /p=!HEX_TAB:~%%p,1!
    
20.   )
    
21.   echo.
    
22. 
    
23.   <nul set /p="Octal: "
    
24.   set /a "test=07<<3*(32/3)" & rem 32=3*10+2
    
25.   for /l %%i in (30 -3 0) do ( rem Arithmetic Shift Right >>
    
26.     set /a "bit=num&test,test>>=3,test&=(1<<30)-1,bit>>=%%i,bit&=(1<<30)-1"
    
27.     <nul set /p=!bit!
    
28.   )
    
29.   echo.&echo.
    
30. )
    
31. exit /b
    

复制代码

neorobin

还是只用于正数, 位运算实现, 只显示有效数字

1. @echo off & setlocal enableDelayedExpansion
   
2. REM 2147483647=~(1<<31)
   
3. set HEX_TAB=0123456789ABCDEF
   
4. for /l %%a in () do (
   
5.   set /p num="Input a decimal number: "
   
6. 
   
7.   <nul set /p="Binary: "
   
8.   set code=
   
9.   set /a "test=1<<31
   
10.   for /l %%i in (31 -1 0) do (
    
11.     set /a "bit=num&test,test>>=1,test&=~(1<<31),bit>>=%%i,bit&=~(1<<31)"
    
12.     set "code=!code!!bit!"
    
13.     if !code!==0 set code=
    
14.   )
    
15.   echo !code!
    
16. 
    
17.   <nul set /p="Hex.: "
    
18.   set code=
    
19.   set /a "test=0xf<<4*(32/4-1)
    
20.   for /l %%i in (28 -4 0) do (
    
21.     set /a "bit=num&test,test>>=4,test&=(1<<28)-1,bit>>=%%i,bit&=(1<<28)-1"
    
22.     for %%p in (!bit!) do set "code=!code!!HEX_TAB:~%%p,1!"
    
23.     if !code!==0 set code=
    
24.   )
    
25.   echo !code!
    
26. 
    
27.   <nul set /p="Octal: "
    
28.   set code=
    
29.   set /a "test=07<<3*(32/3)" & rem 32=3*10+2
    
30.   for /l %%i in (30 -3 0) do ( rem Arithmetic Shift Right >>
    
31.     set /a "bit=num&test,test>>=3,test&=(1<<30)-1,bit>>=%%i,bit&=(1<<30)-1"
    
32.     set "code=!code!!bit!"
    
33.     if !code!==0 set code=
    
34.   )
    
35.   echo !code! & echo.
    
36. )
    
37. exit /b
    

复制代码

terse

输入数在可运算范围内的位移
如超出运算范围 8楼代码可处理大数

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. set/p T=输入10进制数:
   
4. set "Code=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_@"
   
5. for %%i in (1 3 4) do (
   
6.     set /a "i=1<<%%i,j=i-1"
   
7.     set S=%T%
   
8.     for /l %%j in (0 1 31) do (
   
9.         if !S! neq 0 (
   
10.            set/a "B=S&j,S>>=%%i"
    
11.            for %%k in (!B!) do set _%%i=!Code:~%%k,1!!_%%i!
    
12.         )
    
13.     )
    
14.     echo %T% 对应 !i! 进制 "!_%%i!"
    
15. )
    
16. pause
    

复制代码