[文本处理] [已解决]批处理如何将文本内容行倒排序？

wh1234567

批处理如何将文本内容行倒排序？并输出到另外文本里

例如原文本内容：
2222
222v飞v
342
不同提供343

处理后：
不同提供343
342
222v飞v
2222

CrLf

小吹一下，我发现我貌似在算法方面小有天赋...

@echo off&setlocal enabledelayedexpansion
findstr /n .* 1.txt >2.txt
set "str=[0-9][0-9][0-9][0-9]"
(for /l %%a in (1 1 4) do (
   for /f "tokens=1* delims=:" %%b in ('findstr "^^!str!:" 2.txt^|sort /r') do echo %%c
   set str=!str:*]=!
))>b.txt
pause
复制代码

applba

sort这么好用吗？
打上编号，再倒过来就行了。

CrLf

修正了两处笔误。

batman

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do set "str="%%a" !str!"
(for %%a in (!str!) do echo %%~a)>tem
del /q a.txt&ren tem a.txt
start a.txt
复制代码

wh1234567

5# batman

版主您好，为什么这个批处理只能处理一半就退出了，不能完全处理，例如21.6KB的文本只能处理10.8KB，是不是需要修改一下代码？昨天我也发现另外一个批处理也是不能够完全处理，小文本可以处理，同样格式的大文本就无法执行处理了，不知道是代码咋回事

CrLf

因为变量长度有限。2楼代码已修正原先的两处笔误，试下有没有用

batman

因为cmd中的变量名+值的字节数上限为8190，当文本足够大时，代码中的str变量就会发生溢出，修改如下：

@echo off&setlocal enabledelayedexpansion
set /a num=1
for /f "delims=" %%a in (a.txt) do (
     set /a n+=1,m=n%%100
     if !m! equ 0 set /a num+=1
     for %%b in (!num!) do set "str_%%b="%%a" !str_%%b!"
)
(for /l %%a in (%num%,-1,1) do (
      for %%b in (!str_%%a!) do echo %%~b
))>tem
del /q a.txt&ren tem a.txt
start a.txt
复制代码

wh1234567

8# batman

好像还是不能正常处理

wh1234567

2# zm900612

这个可以正常处理，很感谢大家的帮助

Batcher

1# wh1234567

tac a.txt | more > b.txt
复制代码

http://bbs.bathome.net/thread-1114-1-1.html

batman

9# wh1234567
代码中少写了一个do，笔误，已改正，应该能处理了。

你如果不是小白应该能够发现这个问题改正啊，晕。。。。

hanyeguxing

12# batman


我以为只有我才常干这种事。。。

wc726842270

我也凑凑热闹，好久没发贴子了，都快忘了，呵呵

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n .* 1.txt') do set 

str=%%i&&set _!str!=%%j&set /a n+=1
:1
echo !_%n%!
set /a n-=1
if %n% equ 0 (pause&goto :eof) else goto :1
复制代码

batman

14# wc726842270
处理超大文本不考虑效率是不行的，如果文本足够大，你这个代码估计最后没有结果出来。。。