[已解决]批处理怎么删除文本中不包含特定字符的所有行？

Bearxy · 发表于 2011-5-24 23:18:20

我有许多文本需要处理,内容很复杂,需要将含有FOUND的行保留,其余的行全部删除.如果不包含有FOUND的文本就执行删除操作。
我在论坛搜索过,没有看到类似的帖,所以无奈只得来求助了.

当然不是下面代码这样简单，呵呵。

findstr "FOUND" "1.txt">>2.txt

复制代码

我的思路是把含有FOUND的行提取出来，然后输出到新文本，最后将新文本命名为原来的文件名。
只是文本太多了，我实在不知道怎么写了。

batman · 发表于 2011-5-24 23:59:00

本帖最后由 batman 于 2011-5-25 00:02 编辑

请先测试。。。

@echo off
for %%a in (*.txt) do (
if exist $ del /q $
for /f "delims=" %%b in ('findstr "FOUND" "%%a"' ) do echo %%b>>$
if exist $ (
move $ "%%a"
) else (
del /q "%%a"
)
)

复制代码

applba · 发表于 2011-5-25 00:17:42

(for /f "delims=" %%i in (1.txt) do (echo %%i|find /i "found") )>2.txt

Bearxy · 发表于 2011-5-25 00:17:51

batman..

老大,我纠结四个多小时了。.

Bearxy · 发表于 2011-5-25 00:28:58

测试完全通过，激动啊,只是有点不明白$的作用,没看到有讲解过……
非常谢谢batman 和applba 这么晚还给予我帮助，非常感谢。

batman · 发表于 2011-5-25 00:37:56

本帖最后由 batman 于 2011-5-25 00:46 编辑

$就是一个临时文件，当要搜索的txt中没有found关键字时，第二个for中do后面的命令是不会执行的，所以就不会生成临时文件$，后面通过判断是否存在临时文件$来决定是move还是del。。。

applba · 发表于 2011-5-25 00:50:19

本帖最后由 applba 于 2011-5-25 01:01 编辑

@echo off
set tmpfile=tmp%random%.txt
for /r %%a in (*.txt) do (
( for /f "usebackq delims=" %%b in ("%%~a") do ( echo %%b | find /i "found"))>%tmpfile%
if not exist "%%~na.bak.txt" ren "%%~a" "%%~na.bak.txt"
move /y "%tmpfile%" "%%~a"
)

复制代码

move /y 直接搞定啊，还要del做神马……

fengyun530 · 发表于 2011-5-25 09:41:01

都很不错。不过还是batman斑竹写的更让我容易看得懂些。

applba的也可以。不过写得我有点看不太懂。"%%~a"尤其是这个。虽然我知道他表示的是其中某一个txt文件。%tmpfile%表示的效果和$临时文件应该效果差不多！

好象看懂了applba代码的一些。原理是：
便历当前目录下所有txt文件。包括子目录(/r)
再次便历单独的某个txt文件。如果某行包括“found"就把该行移到%tmpfile%
然后重命令该文件为%%~na.bak.txt%，目的只是为了下面的move操作，别无其他意思
把找到的"found"行写回%%~a。这里就省去了一个删除，但是代码结构上好象更让人不容易直白性的理解！不过也算是一种突破吧。

lvsehuaxue · 发表于 2011-5-25 12:05:49

本帖最后由 lvsehuaxue 于 2011-5-25 12:09 编辑

@echo off
for %%i in (*.txt) do (findstr /i "found" %%i)>$&&move $ %%i||del /q %%i

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理怎么删除文本中不包含特定字符的所有行？

评分

评分