批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程
[批处理文件精品]批处理版照片整理器[批处理文件精品]纯批处理备份&还原驱动在线第三方下载
返回列表 发帖

[原创] VBS硬件信息 Hardware_Info.vbs

本帖最后由 fastslz 于 2011-8-28 15:28 编辑

代码没有技术水准,网上搜索有一大堆类似代码,关键是中文描述方式
支持多个硬盘、显卡、内存、声卡、网卡,CPU超频识别
支持cmd调用
  1. 'Hardware_Info.vbs v1.1 BY: fastslz    http://bbs.bathome.net
  2. On Error Resume Next
  3. Dim WMI,WS,Fso
  4. Set WMI = GetObject("Winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
  5. Set cOSs = WMI.ExecQuery("Select * from Win32_OperatingSystem")
  6. For Each oOS in cOSs
  7. OSx = oOS.Caption &" " & oOS.CSDVersion  & vbCrLf
  8. Next
  9. BBx= "————————————主板信息————————————"  & vbCrLf
  10. Set Board = WMI.InstancesOf("Win32_BaseBoard")
  11. Set Bios = WMI.InstancesOf("Win32_Bios")
  12. For Each oBoard In Board
  13. BBx = BBx _
  14.     & "主板名称: " & oBoard.Product &vbTab & oBoard.Version & vbCrLf _
  15.     & "制造厂商: " & oBoard.Manufacturer                    & vbCrLf
  16. Next
  17. For Each oBios In Bios
  18. BBx = BBx _
  19.     & "BIOS厂商: " & oBios.Manufacturer                     & vbCrLf _
  20.     & "BIOS日期: " & FormatDateTime(wDate(Trim(oBios.ReleaseDate)),1)  & vbCrLf _
  21.     & "BIOS版本: " & oBios.SMBIOSBIOSVersion & vbCrLf _
  22.     & "OEM 版本: " & oBios.Version           & vbCrLf
  23. Next
  24. Set Bios = Nothing:Set Board  = Nothing
  25. CPUx = "———————————处理器信息———————————"  & vbCrLf
  26. Set CPUs = WMI.InstancesOf("Win32_Processor")
  27. Set Caches = WMI.InstancesOf("Win32_CacheMemory")
  28. For Each ObjCPU In CPUs
  29. MCS = ObjCPU.MaxClockSpeed :CCS = ObjCPU.CurrentClockSpeed
  30. If ObjCPU.MaxClockSpeed Mod 2 = 1 Then MCS = CCS + 1
  31. If ObjCPU.CurrentClockSpeed Mod 2 = 1 Then CCS = CCS + 1
  32. OC = QOC(CCS,MCS)
  33. If (OC-MCS) >  10 and (OC-MCS) > 0 Then OCLC = "  超频比率: " & FormatPercent((OC-MCS)/MCS)
  34. If (OC-MCS) < -10 and (OC-MCS) < 0 Then OCLC = "  降频比率: " & FormatPercent((OC-MCS)/MCS)
  35. CPUx = CPUx _
  36.      & "CPU 名称: " & Trim(ObjCPU.Name)                & vbCrLf _
  37.      & "CPU 构架: " & ObjCPU.Description               & vbCrLf _
  38.      & "制造厂商: " & ObjCPU.Manufacturer              & vbCrLf _
  39.      & "接口规格: " & ObjCPU.SocketDesignation         & vbCrLf _
  40.      & "CPU 数量: " & ObjCPU.CpuStatus                 & vbCrLf _
  41.      & "核心数量: " & ObjCPU.NumberOfCores             & vbCrLf _
  42.      & "线程数量: " & ObjCPU.NumberOfLogicalProcessors & vbCrLf _
  43.      & "地址位宽: " & ObjCPU.AddressWidth & " Bit"     & vbCrLf _
  44.      & "数据位宽: " & ObjCPU.DataWidth    & " Bit"     & vbCrLf _
  45.      & "CPU 电压: " & ObjCPU.CurrentVoltage / 10 & "V" & vbCrLf _
  46.      & "外部频率: " & ObjCPU.ExtClock  & " MHz"        & vbCrLf _
  47.      & "当前频率: " & OC               & " MHz" & OCLC & vbCrLf _
  48.      & "原始频率: " & MCS              & " MHz"        & vbCrLf _
  49.      & "CPU 使用: " & ObjCPU.LoadPercentage  & "%"     & vbCrLf
  50. Next
  51. Function QOC(CCS,MCS)
  52.     If CCS = MCS Then
  53.         Set wReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
  54.         wReg.GetDWORDValue &H80000002,"HARDWARE\DESCRIPTION\System\CentralProcessor\0","~MHz",strValue
  55.         OC = strValue :Set wReg = Nothing
  56.         Else
  57.         OC = CCS
  58.     End If
  59.     QOC = OC :If QOC Mod 2 = 1 Then QOC = QOC + 1
  60. End Function
  61. For Each ObjCache In Caches
  62.     If objCache.MaxCacheSize > 0  Then
  63.         Select Case objCache.Purpose
  64.         case "L1-Cache"
  65.         CPUx = CPUx & "一级缓存: " & objCache.MaxCacheSize & "KB    (L1数据+L1缓存)" & vbCrLf
  66.         case "L2-Cache"
  67.         CPUx = CPUx & "二级缓存: " & objCache.MaxCacheSize & " KB" & vbCrLf
  68.         case "L3-Cache"
  69.         CPUx = CPUx & "三级缓存: " & objCache.MaxCacheSize & " KB" & vbCrLf
  70.         End Select
  71.     End If
  72. Next
  73. Set Caches = Nothing:Set CPUs = Nothing
  74. Memx = "————————————内存信息————————————" & vbCrLf
  75. Set Memorys = WMI.InstancesOf("Win32_PhysicalMemory")
  76. Set MemKY = WMI.InstancesOf("Win32_OperatingSystem")
  77. For Each aKY In MemKY
  78.     ZL = aKY.TotalVisibleMemorySize
  79.     KY = aKY.FreePhysicalMemory
  80. Next
  81. Mems = 0:Memc = 0
  82. Types = Array("Unknown","Other","DRAM","Synchronous DRAM","Cache DRAM","EDO","EDRAM","VRAM","SRAM", "RAM", _
  83.                "ROM","Flash","EEPROM","FEPROM","EPROM","CDRAM","3DRAM","SDRAM","SGRAM","RDRAM","DDR","DDR2")
  84. For Each Mem In Memorys
  85.     For i = 0 To UBound(Types)
  86.         If Mem.MemoryType = i Then MemType = Types(i) :End If
  87.     Next
  88.     For j = 0 To 6
  89.         Select Case Mem.Tag
  90.             case "Physical Memory " & j
  91.             Mems = Mems+(Mem.Capacity)
  92.             Memx = Memx  &"插槽" & Mem.DeviceLocator & ": " & Round(Mem.Capacity/1048576) &" MB  " _
  93.                          & MemType & "-" & Mem.Speed & "MHz" & " 数据带宽" & Mem.DataWidth _
  94.                          & "Bit" & " 总带宽" & Mem.TotalWidth &"Bit" & vbCrLf
  95.         End Select
  96.     Next
  97. Next
  98. Memx = Memx _
  99.      & "内存安装: "& Round(Mems/1048576)&" MB " & vbCrLf _
  100.      & "内存总量: "& Round(ZL/1024)& " MB" & vbCrLf _
  101.      & "内存可用: "& Round(KY/1024)& " MB" & vbCrLf _  
  102.      & "内存使用率: " &FormatPercent((ZL-KY)/ZL)& vbCrLf
  103. Set Memorys = Nothing:Set MemKY = Nothing
  104. Vx= "————————————显卡信息————————————"  & vbCrLf
  105. Set cVID = WMI.ExecQuery("SELECT DeviceID FROM Win32_VideoController")
  106. For Each oVID In cVID
  107.     Set Video = WMI.ExecQuery("SELECT * FROM Win32_VideoController WHERE DeviceID='"& oVID.DeviceID &"'")
  108.     For Each oVideo In Video
  109.         Vx = Vx _
  110.         & "显卡名称: " & oVideo.Name                                    & vbCrLf _
  111.         & "制造厂商: " & oVideo.AdapterCompatibility                    & vbCrLf _
  112.         & "物理显存: " & Round(oVideo.AdapterRAM/1048576)&" MB "        & vbCrLf _
  113.         & "显示模式: " & oVideo.CurrentHorizontalResolution &" X " _
  114.                        & oVideo.CurrentVerticalResolution   &" "_
  115.                        & oVideo.CurrentBitsPerPixel         &"Bit " _
  116.                        & oVideo.CurrentRefreshRate          &"Hz"     & vbCrLf
  117.     Next
  118. Next
  119. Set Video = Nothing:Set cVID = Nothing
  120. Dx= "————————————硬盘信息————————————"  & vbCrLf
  121. Set IDE = WMI.ExecQuery("Select * from Win32_DiskDrive WHERE InterfaceType='IDE'")
  122. Set cPPP = WMI.ExecQuery("SELECT * FROM Win32_PerfRawData_PerfDisk_PhysicalDisk")
  123. For Each oIDE In IDE
  124.     For i = 0 To IDE.Count
  125.         Select Case oIDE.Index
  126.             Case i
  127.                For Each oPPP In cPPP
  128.                    If InStr(oPPP.Name, i) Then vName = oPPP.Name
  129.                Next
  130.                Dx = Dx & "硬盘" & i &"型号:" & oIDE.Caption                   & vbCrLf _
  131.                & vbTab & "标称容量: "    & Round(oIDE.Size/1000000000) &" GB" & vbCrLf _
  132.                & vbTab & "实际容量: "    & Round(oIDE.Size/1073741824) &" GB" & vbCrLf _
  133.                & vbTab & "柱面数: "      & oIDE.TotalCylinders                & vbCrLf _
  134.                & vbTab & "磁头数: "      & oIDE.TotalHeads                    & vbCrLf _
  135.                & vbTab & "每道扇区数: "  & oIDE.SectorsPerTrack               & vbCrLf _
  136.                & vbTab & "扇区大小: "    & oIDE.BytesPerSector                & vbCrLf _
  137.                & vbTab & "总扇区数: "    & oIDE.TotalSectors                  & vbCrLf _
  138.                & vbTab & "分区状态: "    & vName  & vbCrLf
  139.                DevID = Replace(oIDE.DeviceID, "\", "\\")
  140.                Set cDP = WMI.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID="""& DevID &"""}" _
  141.                & "WHERE AssocClass = Win32_DiskDriveToDiskPartition")
  142.                For Each oDP In cDP
  143.                  Set cLD = WMI.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID="""& oDP.DeviceID &"""}" _
  144.                  & "WHERE AssocClass = Win32_LogicalDiskToPartition")
  145.                    For Each oLD In cLD
  146.                      Dx = Dx _
  147.                         & vbTab & oLD.DeviceID &" " & Left(oLD.VolumeName&"         " ,11) & Left(oLD.FileSystem&"   " ,6) & "共:" _
  148.                         & Right("    "&Round(oLD.Size/1073741824,1),6)                &" GB    可用:" _
  149.                         & Right("    "&Round(oLD.FreeSpace/1073741824,1),6)           &" GB    已用:" _
  150.                         & Right("    "&Round((oLD.Size-oLD.FreeSpace)/1073741824,1),6)&" GB" & vbCrLf
  151.                    Next
  152.               Next
  153.         End Select
  154.     Next
  155. Next
  156. Set cLD = Nothing:Set cDP = Nothing:Set IDE = Nothing:Set cDP = Nothing:Set cPPP =  Nothing
  157. Sx= "————————————声卡信息————————————"  & vbCrLf
  158. Set cSD = WMI.ExecQuery("SELECT * FROM Win32_SoundDevice")
  159. For Each oSD In cSD
  160.     Sx = Sx & "声卡名称: " & oSD.ProductName  & vbCrLf
  161. Next
  162. Set cSD = Nothing
  163. Nx= "————————————网卡信息————————————"  & vbCrLf
  164. Set cNet = WMI.ExecQuery("Select * from Win32_NetworkAdapter WHERE PhysicalAdapter ='TRUE'")
  165. If CStr(cNet.Count) < 0 Then
  166.     Set cNet = WMI.ExecQuery("Select * from Win32_NetworkAdapter WHERE PNPDeviceID Like 'PCI%%' or PNPDeviceID Like 'USB%%'")
  167.     For Each oNet In cNet
  168.         If oNet.NetConnectionStatus > 0 Then
  169.            Nx = Nx & "网卡名称: "& oNet.Name & vbCrLf
  170.            Else
  171.            Nx = Nx & "网卡名称: "& oNet.Name & vbCrLf
  172.         End If
  173.     Next
  174.     Else
  175.     For Each oNet In cNet
  176.         If oNet.NetEnabled = TRUE Then
  177.            Nx = Nx & "网卡名称: "& oNet.Name & vbTab & "活跃状态" & vbCrLf
  178.            Else
  179.            Nx = Nx & "网卡名称: "& oNet.Name & vbTab & "空闲状态" & vbCrLf
  180.         End If
  181.     Next
  182. End If
  183. Set cNet = Nothing
  184. If (Lcase(Right(Wscript.FullName,11)) = "wscript.exe") Then
  185.     MsgBox OSx & BBx & CPUx & Memx ,,"Hardware_Info.vbs v1.0 BY: fastslz"
  186.     MsgBox Vx & Sx & Nx  ,,"Hardware_Info.vbs v1.0 BY: fastslz"
  187.     MsgBox Dx ,, "Hardware_Info.vbs v1.0 BY: fastslz"
  188.     MsgN = MsgBox ("是否保存到文件?" , 32+4 , "Hardware_Info.vbs v1.0 BY: fastslz")
  189.     If MsgN = 6 Then JZCSx = JZCS :wInfo
  190.     Else
  191.     WScript.Echo OSx & BBx & CPUx & Memx & Vx & Sx & Nx & Dx
  192. End If
  193. Set WMI = Nothing
  194. Sub wInfo()
  195.     Set WS = CreateObject("WScript.Shell")
  196.     Set Fso = CreateObject("Scripting.FileSystemObject")
  197.     aFile = WS.CurrentDirectory &"\"& WS.ExpandEnvironmentStrings("%COMPUTERNAME%")&"_Hardware_Info.txt"
  198.     Set HInfo = Fso.CreateTextFile(aFile , True)
  199.     HInfo.WriteLine "Hardware_Info.vbs BY: fastslz  http://bbs.bathome.net"
  200.     HInfo.WriteLine OSx & BBx & CPUx & Memx & Vx & Sx & Nx & Dx & JZCSx
  201.     HInfo.Close
  202.     WS.Run Chr(34) & aFile & Chr(34)
  203. Set WS = Nothing:Set Fso = Nothing:Set HInfo = Nothing
  204. End Sub
  205. Function wDate(nD)
  206.     If Not IsNull(nD) Then
  207.     wDate = CDate(Mid(nD,5,2)&"/"&Mid(nD,7,2)&"/"&Left(nD,4)&" "&Mid(nD,9,2)&":"&Mid(nD,11,2)&":"&Mid(nD,13,2))
  208.     End If
  209. End Function
  210. Function JZCS()
  211.     NumMsg = vbCrLf & "———————————简易CPU基准测试———————————" & vbCrLf
  212.     Dim I,T1,T2,Tempvalue,aRunTime,bRunTime
  213.     T1 = Timer()
  214.     For I = 1 To 2000000
  215.         Tempvalue= 2^0.5
  216.     Next
  217.     T2 = Timer()
  218.     aRunTime = FormatNumber((T2-T1)*1000,2)
  219.     NumMsg =  NumMsg & "CPU 200万次开方计算所需时间:" &aRunTime&" 毫秒" & vbCrLf
  220.     T1 = Timer()
  221.     For I = 1 To 6000000
  222.         Tempvalue= 1 + 1
  223.     Next
  224.     T2 = Timer()
  225.     bRunTime = FormatNumber((T2-T1)*1000,2)
  226.     NumMsg =  NumMsg & "CPU 600万次加法计算所需时间:"&bRunTime&" 毫秒" & vbCrLf
  227.     JZCS = NumMsg
  228. End Function
复制代码
2

评分人数

本帖最后由 fastslz 于 2011-6-29 20:06 编辑

cmd调用方法
  1. @echo off
  2. for /f "delims=*" %%a In ('Cscript //Nologo "Hardware_Info.vbs"^|find ":"') do echo %%a
  3. :在第二个硬盘第一个分区新建Backup文件夹
  4. for /f "tokens=2,*" %%a In ('Cscript //Nologo "Hardware_Info.vbs"^|findstr  "分区状态"') do (
  5.     if %%a#==1# for /f "tokens=1" %%i In ("%%b") do MD "%%i\Backup")
  6. pause
复制代码
Hardware_Info.vbs BY: fastslz  http://bbs.bathome.net
..................................
————————————主板信息————————————
主板名称: P5QL PRO        Rev 1.xx
制造厂商: ASUSTeK Computer INC.
BIOS厂商: American Megatrends Inc.
BIOS日期: 2009年7月1日
BIOS版本: 1004   
OEM 版本: _ASUS_ - 7000901
———————————处理器信息———————————
CPU 名称: Intel(R) Core(TM)2 Quad CPU    Q8300  @ 2.50GHz
CPU 构架: Intel64 Family 6 Model 23 Stepping 10
制造厂商: GenuineIntel
接口规格: LGA775
CPU 数量: 1
核心数量: 4
线程数量: 4
地址位宽: 64 Bit
数据位宽: 64 Bit
CPU 电压: 1.3V
外部频率: 402 MHz
当前频率: 3000 MHz  超频比率: 20.00%
原始频率: 2500 MHz
CPU 使用: 2%
一级缓存: 128KB    (L1数据+L1缓存)
二级缓存: 4096 KB
————————————内存信息————————————
插槽DIMM0: 2048 MB  DDR-1066MHz 数据带宽64Bit 总带宽64Bit
插槽DIMM2: 2048 MB  DDR-1066MHz 数据带宽64Bit 总带宽64Bit
内存安装: 4096 MB
内存总量: 4095 MB
内存可用: 2039 MB
内存使用率: 50.22%
————————————显卡信息————————————
显卡名称: NVIDIA GeForce GT 220
制造厂商: NVIDIA
物理显存: 512 MB
显示模式: 1440 X 900 32Bit 60Hz
————————————声卡信息————————————
声卡名称: NVIDIA High Definition Audio
声卡名称: Realtek High Definition Audio
声卡名称: NVIDIA High Definition Audio
声卡名称: NVIDIA High Definition Audio
声卡名称: NVIDIA High Definition Audio
————————————网卡信息————————————
网卡名称: Atheros AR8121/AR8113/AR8114 PCI-E Ethernet Controller        活跃状态
————————————硬盘信息————————————
硬盘1:        Maxtor 6L080P0 ATA Device        固件: BAJ41G20
        标称容量: 82 GB        实际容量: 76 GB
        柱面数: 9964        磁头数: 255
        每道扇区数: 63        扇区大小: 512
        总扇区数: 160071660
        分区状态: 1 J: K:
                .....................................
硬盘0:        ST3500418AS        固件: CC49
        标称容量: 500 GB        实际容量: 466 GB
        柱面数: 60801        磁头数: 255
        每道扇区数: 63        扇区大小: 512
        总扇区数: 976768065
        分区状态: 0 C: D: E:
                .....................................
———————————简易CPU基准测试———————————
CPU 200万次开方计算所需时间:593.75 毫秒
CPU 600万次加法计算所需时间:375.00 毫秒

TOP

这个太给力了, 没想到找个自动改移动设备盘符的方法还发现了这么好的东西

TOP

WMI,不错。
『千江有水千江月』千江有水,月映千江;万里无云,万里青天。    http://yu2n.qiniudn.com/

TOP

很不错的东西

TOP

网卡那一段有些冗杂,一是可以精简点,二则是判断活跃网卡那里是不是写错了?
If CStr(cNet.Count) < 0 Then....应该写成 If CStr(cNet.Count) < 1 Then

这一段可以精简成:
On Error Resume Next
Set cNet = WMI.ExecQuery("Select * from Win32_NetworkAdapter WHERE PNPDeviceID Like 'PCI%%' or PNPDeviceID Like 'USB%%'")
For Each oNet In cNet
  If CStr(cNet.Count) > 0 Then
      Nx = Nx & "网卡名称: "& oNet.Name & vbTab & "活跃状态" & vbCrLf
  Else
      Nx = Nx & "网卡名称: "& oNet.Name & vbCrLf
  End If
Next
On Error goto 0
Set cNet = Nothing

TOP

回复 6# 9zhmke


    开始我也是不绕弯弯的,这样做只是因为多个网卡状态下区分,正在使用中的网卡即活跃空闲状态

TOP

返回列表