[文本处理] [已解决]批处理如何把txt文本按照顺序把没有的修改递补上？

wslqy

问个问题，一个文件夹里面有1---200左右的文本，1.txt，2.txt,5.txt......,如何按照顺序把没有的修改递补上：1.txt,2.txt,3.txt,也就是说，把5.txt的递修改为3.txt以此类推

0428_hai

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
::本批处理功能为将当前文件夹下所有以阿拉伯数字命名的文本文件“按序”排列
::注意事项：当前文件夹中的文本文件名必须为阿拉伯数字，数字之间不允许空格
::当然可以根据自己的需求继续完善
set max=1
for %%a in (*.txt) do (
	set %%~na=%%~na
	if !max! lss %%~na set max=%%~na
	set /a cnt+=1
)

for /l %%a in (1,1,%cnt%) do (
	if defined %%a (
		set %%a=
	) else (
		set _tmp=%%a
		call :reName %%a
	)
)
echo done......
pause>nul
exit

:reName
for /l %%a in (1,1,%max%) do (
	set /a _tmp+=1
	if defined !_tmp! (
		echo ren !_tmp!.txt %1.txt
		set !_tmp!=
		pause>nul
		goto :eof
	)
)
复制代码

wslqy

多谢0428_hai 大师的帮助

CUer

@echo off
setlocal enabledelayedexpansion
set num=1000
for /f %%a in ('dir /b *.txt') do (
    set /a num+=1
    ren %%a !num!.txt
)
for /f %%a in ('dir /b *.txt') do (
    set /a newname=%%~na%%1000
    ren %%a !newname!.txt
)
复制代码

wslqy

CUer 的代码文本名称是可以改变，但文本的时间属性被重新排列了

CUer

5# wslqy


没看到你顶楼有这个需求啊

wslqy

不过还是要感谢大家对我的帮助，再次谢谢大家

wslqy

不好意思，无法把要的结果截图到这里面来，非常抱歉

ArdentMan

@Echo Off&SetLocal EnableDelayedExpansion
For /F "delims=" %%i In ('Dir /od /b *.txt') Do (
  If Not Defined Num (
    Set /A Num=%%~ni
    ) Else (
    Set /A Num+=1
    If !Num! NEQ %%~ni Ren %%i !Num!.txt
  )
) 
复制代码

wslqy

不是像我刚刚截图要的结果

wslqy

2楼和9楼使用效果都一样，很好很不错

wslqy

所有的问题已经解决，再次谢谢各位大师

0428_hai

如下图所示，不知为何我测试时，程序最后把编号编到242了，而我的txt文本只有50个啊

ArdentMan

13# 0428_hai
是因为你最小序号的文本文件的创建时间不是最早的~~~~

0428_hai

是的。
对于楼主的实际应用，看来用dir/o-d的排序效果就达到要求了。
我用于测试所创建的文本文件创建时间几乎全都一样吧，对于实际情况没有什么意义了。
只是对于这种“特殊情况”不适用罢了