[文本处理] [已解决]批处理如何根据文件大小修改不同的后缀？

cc800

比如有2个文件 一个是.rar文件（大于5k）  一个是.txt文件 （5K）
现在统一修改它们的后缀为.gzo
现在想实现
直接拖拽到BAT
大于5K的
后缀自动还原为rar
5K以下的
后缀还原为txt

改为gzo后缀我已经知道

@REN "%~fs1" "%~n1.gzo"
复制代码

怎么加入根据文件大小改不同的后缀
如何还原（最好支持批量修改文件夹里的所有文件）

apang

@echo off
if "%~1"=="" goto :eof
if exist "%~1\" (
  for /f "delims=" %%a in ('dir /a-d /b /s "%~1\*.gzo"') do (
    if %%~za gtr 5120 (ren "%%~a" "%%~na.rar"
    ) else ren "%%~a" "%%~na.txt"
  )
) else (
  for %%a in (%*) do (
    if %%~za gtr 5120 (ren "%%~dpna.gzo" "%%~na.rar"
    ) else ren "%%~dpna.gzo" "%%~na.txt"
  )
)
复制代码

cc800

回复 2# apang
怎么不行啊
一闪而过
没改
是不是那个地方有误 还是

apang

回复 3# cc800


将文件或文件夹拖拽到bat，后缀为gzo的文件有效。

cc800

回复 4# apang
用了 还是不行
拖拽进去 没有变化

apang

回复 5# cc800

是拖拽文件不行还是拖拽文件夹不行？试试下面拖拽文件夹的

@echo off
if "%~1"=="" echo 请拖拽文件夹到BAT&pause&goto :eof
if exist "%~1\" (
  for /f "delims=" %%a in ('dir /a-d /b /s "%~1\*.gzo"') do (
    if %%~za gtr 5120 (ren "%%~a" "%%~na.rar"
    ) else ren "%%~a" "%%~na.txt"
  )
) else echo 请拖拽文件夹到BAT
pause
复制代码

cc800

回复 6# apang
这个可以拖拽文件夹成功 多谢！
那上面的拖拽文件怎么不行

apang

不清楚，但我在XP和Win7都可以拖拽成功的

cc800

回复 8# apang
找到原因了 呵呵 行啦 少了4个字符