[已解决] 批处理输入变量的内容包含特殊字符时， 如何处理？

极品小猫

代码如下, 例如输入的内容为 | * 等特殊字符时, 会直接出错, 有什么办法可以在不需要输入预处理符号的情况下, 对输入包含特殊字符的内容进行处理

要求: 在输入非0-9的字符时, 进行提示. 另外, 变量为空值时不会退出批处理

1. 
   
2. @echo off
   
3. :if
   
4. set num=
   
5. set /p "num=请输入: "
   
6. ::遍历 num 寻找非 0-9 的字符, 并提示
   
7. for /f "delims=" %%i in ('echo %num%^|findstr "[^0-9]"') do (
   
8.         cls
   
9.         if not "%%i"=="" echo 请输入纯数字!
   
10.         goto :if
    
11. )
    
12. 
    
13. if /i %num% lss 10 (set num=0%num%) else (echo %num%)
    
14. echo %num%

复制代码

powerbat

“预处理”这个词好流行啊。。。
这件事情怎么预处理？
你的伤口怎么预处理？
城管打人怎么预处理？

powerbat

预处理是cmd内部自动进行的，你是无法改变的，除非你重写一个cmd。
你要做的是如何“处理”特殊字符，而不是如何“预处理”。

1. 
   
2. set num|findstr /x "num=[0-9]*" >nul || (echo 请输入纯数字！&goto :if)

复制代码

CrLf

可在 for /f 内部使用变量延迟：

1. for /f ... in ('cmd /v /c echo !num!^|findstr "[^0-9]') do ...

复制代码

可以用逻辑连接符简化成：

1. cmd /v /c echo !num!|findstr "[^0-9]||echo 请输入纯数字!

复制代码

不过更好的办法是改进思路：

1. for /f "eol=0 delims=0123456789" %%a in ("%num:"=""%") do echo 请输入纯数字!
   
2. ::将数字设为分隔符，若能取到第一节，则存在非数字字符

复制代码

1. set /a test=num
   
2. if "%test%" neq "%num:"=""%" echo 请输入纯数字!
   
3. ::数值运算，八进制数和十六进制数会被转为十进制，而非纯数字变量则会被赋为0，运算后比较前后变量，若不相同则可知不为纯数字

复制代码

CrLf

另：

1. if not "%%i"=="" echo 请输入纯数字!

复制代码

这句是多余的，当 tokens 所取的节（隐式声明为 tokens=1）不存在时，for是不会为当前行执行命令的，举个例子，下面这段代码：

1. for /f "tokens=1,2" %%a in (a.txt) do (
   
2.    echo %%a,%%b
   
3. )

复制代码

实际效果等几乎等于：

1. for /f "tokens=1,2" %%a in (a.txt) do (
   
2.    if "%%a" neq "" (
   
3.       if "%%b" neq "" (
   
4.          echo %%a,%%b
   
5.       )
   
6.    )
   
7. )

复制代码

这就是 for 一定会跳过空行的本质原因

yangfengoo

版主神人。。。

极品小猫

可在 for /f 内部使用变量延迟：可以用逻辑连接符简化成：不过更好的办法是改进思路：
CrLf 发表于 2012-6-14 13:21

回复powerbat: 发帖的时候也感觉标题有点问题

Ctrlv5, 感谢Ctrl版大的指导, 很详细的解释, 发帖的时候忘记说了一个问题.

希望在变量的值为空的时候也不会退出批处理.

Batcher

版主V5