[游戏娱乐] 批处理青蛙跳

yslyxqysl

一个改编自Flash的游戏。

@echo off&setlocal ENABLEDELAYEDEXPANSION
title 青蛙跳&color e0&set g=goto start
:readme
echo 让左右两边的青蛙互换位置。&echo Y代表黄青蛙，R代表红青蛙。
echo 输入石头(---)下的数字移动。&echo 青蛙们可以按照上面的方向移一格，
echo 也可以跳过指定方向的一个青蛙，&echo 落到相邻的空石头上
echo R重来，E退出&echo.&pause>nul

:ready
for /l %%i in (1,1,3) do set s%%i=Y
set s4= &for /l %%i in (5,1,7) do set s%%i=R
set Y=→&set R=←

:start
set "qwfx="&set "tpstr="
for /l %%i in (1 1 7) do (
if %%i neq 1 set "tpstr= "
if !s%%i!a==Ya set qwfx=!qwfx!!tpstr! →
if !s%%i!a==Ra set qwfx=!qwfx!!tpstr! ←
if "!s%%i!"==" " set qwfx=!qwfx!!tpstr! 
)
cls&echo now
echo %qwfx%
echo, %s1% %s2% %s3% %s4% %s5% %s6% %s7%
echo --- --- --- --- --- --- ---
echo 1 2 3 4 5 6 7
echo.
set "tpstr=%s1%%s2%%s3%%s4%%s5%%s6%%s7%"
if "%tpstr:YYRR=%_%tpstr:YRR =%_%tpstr: YYR=%" neq "%tpstr%_%tpstr%_%tpstr%" (
echo You die^^!
goto end
)
if "%tpstr%"=="RRR YYY" echo You win^^!&&goto end

:input
set "move="&set /p move=请输入：
if /i "!move!"=="r" cls&&goto ready
if /i "!move!"=="e" exit
set input=&for /l %%e in (1,1,7) do if "%move%"=="%%e" set input=r
if %input%a neq ra %g%
if "!s%move%!"==" " %g%
if !s%move%!==Y (set "movefx=+") else set "movefx=-"
for %%t in (1 2) do set /a move%%t=%move%%movefx%%%t
if "!s%move1%!"==" " (set s%move1%=!s%move%!) else (
if "!s%move2%!"==" " (set s%move2%=!s%move%!) else echo 无法移动。&%g%
)
set "s%move%= "&cls&%g%

:end
set /p restart=再来？(Y,N) 
if /i "%restart%"=="y" goto ready
复制代码

pusofalse

不会玩~

yslyxqysl

http://www.4399.net/flash/7584_2.htm?800
flash的

yslyxqysl

连点鼓励分都没有，害我白搞那么久。

523066680

哦……白搞……

建议用batman抽奖机的那个模式，同步控制。
我是这样想的，有a.bat  x.txt  b.bat
b.bat是控制台，随时向x.txt发送信息，a.bat随时从x.txt读取信息，并分析执行
这样就可以制作一个比较生动的批处理游戏 而不用按一下 停一下

batman

就代码而言，可以大大地简化，重复和类似的语句都可用call和变量来简化。。。

wxcute

一运行就说“you DIE，再来”

yslyxqysl

没有啊

dai0992

锻炼一下智力！有意思

neorobin

还有点兴趣, 这种解谜游戏老能吸引我, 就算在批里如此的界面和如此的音画效果

仔细一看, 竟然是一年前的作品了

[ 本帖最后由 neorobin 于 2009-12-12 03:53 编辑 ]

abxialiang

唉，我实在不知道怎么玩，玩游戏这个事情我一向没有什么天赋的。

Seter

原帖由 523066680 于 2008-9-30 09:57 发表
哦……白搞……

建议用batman抽奖机的那个模式，同步控制。
我是这样想的，有a.bat  x.txt  b.bat
b.bat是控制台，随时向x.txt发送信息，a.bat随时从x.txt读取信息，并分析执行
这样就可以制作一个比较生动的批 ...

这么一个小游戏..我觉得已经可以了叭...用这个有点小题大做的意思,最多用来练习用
话说这东西我曾经也做过个FLASH,给我们心理老师了...而且附带答案的,1秒钟自动跳一次
我觉得...LZ给加个例子比较好~

xlw542350190

晕死，都不弄得有创意一点…………

UvUv555555

搞不懂，一点也不会玩

garyng

我玩过Flash版本的～