[已解决]如何用批处理去除txt文本里每一行中相同的字符串

qzwifi · 发表于 2012-12-17 15:42:00

本帖最后由 pcl_test 于 2016-7-6 11:09 编辑

例：

文本a.txt内容为：
01 08 12 16

b.txt为：
01 02 03 04 05 06 07 08 09 10
11 12 13 14 15 16 17 18 19 20

处理后为：
02 03 04 05 06 07 09 10
11 13 14 15 17 18 19 20

就是把文本b.txt内有包含到文本a.txt里的数字去除

保存为3.txt

apang · 发表于 2012-12-17 18:48:54

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
for %%b in (%%a) do set .%%b=1
)
(for /f "delims=" %%a in (b.txt) do (
for %%b in (%%a) do (
if not defined .%%b set "str=!str! %%b"
)
if defined str echo,!str:~1!&set "str="
))>3.txt

复制代码

qzwifi · 发表于 2012-12-17 19:08:06

回复 2# apang

OK，谢谢 apang 大哥！

悬崖之树 · 发表于 2012-12-18 21:11:27

本帖最后由悬崖之树于 2012-12-18 21:13 编辑

兄弟，帮我看看我的代码错在哪里了？谢谢！

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (b.txt) do (
for %%b in (%%a) do (
for /f "delims=" %%c in (a.txt) do (
for %%d in (%%c) do (
if "%%b" equ "%%d" (set /a n+=1)
)
)
if "!n!" equ "0" set "str=!str! %%b"
set n=0
)
echo !str:~1!&echo.
)
pause

复制代码

我自己是无能为力了。

apang · 发表于 2012-12-18 23:36:28

本帖最后由 apang 于 2012-12-18 23:41 编辑

回复 4# 悬崖之树

11行：if "!n!" equ "" (set "str=!str! %%b") else set "n="
12行：删掉
14行：建议 if "!str!" neq "" echo,!str:~1!&set "str=" 否则当str为空值时，echo,!str:~1!显示的是很奇怪的字符

PS：思路对的，for嵌套级数多了点。。。

悬崖之树 · 发表于 2012-12-20 17:47:10

本帖最后由悬崖之树于 2012-12-20 18:05 编辑

真是谢谢apang大哥了，我是茅塞顿开啊。
关键在于没有想到 set /a n=n+1 在没有运行前，n不是0 而是空。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]如何用批处理去除txt文本里每一行中相同的字符串

评分

评分

apang兄，为什么我的代码不灵了？