批处理怎样截取文本倒数第三行的内容？

jwwlchen

有一系列.txt文本文件，行数不固定，怎么把每个文件的倒数第三行内容导出到一个文件中?

batman

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. (for %%a in (*.txt) do (
   
4.    for /f "usebackq delims=" %%b in ("%%a") do (
   
5.      set "str2=!str1!"
   
6.      set "str1=!str!"
   
7.      set "str=%%a"
   
8.    )
   
9.   if defined str2 echo,!str2!&set "str2="
   
10. ))>new.txt
    
11. start new.txt
    

复制代码

batman

附取文本倒数第N行的两种方法：
1、

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. (for /l %%a in (1,1,100) do echo %%a)>a.txt
   
4. set /a n=!random!%%100+1
   
5. for /f "delims=" %%a in (a.txt) do (
   
6.   for /l %%b in (%n%,-1,1) do (
   
7.     if %%b neq 1 (
   
8.       set /a a=%%b-1
   
9.       for %%c in (!a!) do set "str%%b=!str%%c!"
   
10.       ) else (
    
11.       set "str%%b=%%a"
    
12.     )
    
13.   )
    
14. )
    
15. echo 取得a.txt倒数第%n%行的值为：!str%n%!
    
16. pause>nul
    

复制代码

2、

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. (for /l %%a in (1,1,100) do echo %%a)>a.txt
   
4. for /f "delims=" %%a in (a.txt) do set /a m+=1&set "_!m!=%%a"
   
5. set /a n=!random!%%100+1,m-=n-1
   
6. echo 取得a.txt倒数第%n%行的值为：!_%m%!
   
7. pause>nul
   

复制代码

BAT-VBS

1. @echo off
   
2. set n=0
   
3. for /f %%a in (a.txt) do (
   
4.     set /a n+=1
   
5. )
   
6. echo %n%
   
7. set /a n-=3
   
8. call :getLine %n%
   
9. pause
   
10. goto :eof
    
11. 
    
12. :getLine
    
13. for /f "skip=%1 delims=" %%a in (a.txt) do (
    
14.     echo,%%a
    
15.     goto :eof
    
16. )

复制代码

terse

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. for /f "delims=" %%i in ('dir /b /a-d *.TXT') do (
   
4.     sort /+8192 "%%i"|more +2 >_ten.t
   
5.     set /pstr=<_ten.t
   
6.     >>_temp.txt echo;!str!
   
7. )
   
8. del _ten.t&pause

复制代码