如何提取两个字符之间的数值然后显示最小/最大数值

lvrendos · 发表于 2008-12-4 18:44:30

如何提取两个字符之间的数值然后显示最小/最大数值
比如有一a.txt内容为:
X-286.716 Y310.375 Z145.906
X-286.927 Y310.741 Z146.793
X-287.172 Y311.085 Z147.679
X-287.45 Y311.403 Z141.566
X-287.758 Y311.693 Z142.453
X-288.093 Y311.951 Z140.34
X-288.451 Y312.175 Z-149.226
X-288.83 Y312.362 Z-141.113
我要显示“z”与“."之间数值的最小植（-149），最大值（147）

lvrendos · 发表于 2008-12-4 18:45:21

如果我要同时搜索好几个txt文件该怎么弄

rat · 发表于 2008-12-4 20:37:02

@echo off&setlocal enabledelayedexpansion
set i=0&for /f "tokens=4 delims=Z." %%a in (a.txt b.txt c.txt)do set/ai+=1&if !i!==1 (set/amin=max=%%a)else if %%a lss !min! (set min=%%a)else if %%a gtr !max! set max=%%a
echo min: %min%&echo max: %max%&pause

[ 本帖最后由 rat 于 2008-12-4 20:45 编辑 ]

Batcher · 发表于 2008-12-4 20:40:43

@echo off
setlocal enabledelayedexpansion
set numMin=0
set numMax=0
for /f "tokens=4 delims=Z." %%a in (a.txt) do (
if %%a gtr !numMax! (
set numMax=%%a
) else if %%a lss !numMin! (
set numMin=%%a
)
)
echo 最小值：%numMin%
echo 最大值：%numMax%

复制代码

提示：该算法是错误的，具体原因见5楼。

pusofalse · 发表于 2008-12-4 22:04:06

貌似代码有错误。
if %%a lss !numMin! set numMin=%%a
若要比较的数字都是正数，就能看出出错结果了。

pusofalse · 发表于 2008-12-4 22:23:27

@Echo Off & Setlocal EnableDelayedExpansion
set /a Max=0
For /f "usebackq tokens=5 Delims=Z. " %%a In ("a.txt") Do (
If %%a Gtr !Max! (
set "Max=%%a"
) Else (
If %%a lss !Num! set "Min=%%a"
set "Num=%%a"
)
)
Echo Max : %Max%
Echo Min : %Min%
Pause

复制代码

lvrendos · 发表于 2008-12-6 18:27:56

G43 H9 Z50.
G00 X-579.844 Y-0.09 Z50. M8
Z16.
G01 Z0.0 F900
X-578.112 Y-1.09 F3000
G03 X-581.09 Y1.888 I-1.888 J1.09
Y-1.888 I1.09 J-1.888
X-578.112 Y-1.09 I1.09 J1.888
G01 X-579.844 Y-0.09
G00 Z50.
X580.156 Y0.09
Z16.
G01 Z0.0 F900
X581.888 Y1.09 F3000
G03 X577.82 Y0.0 I-1.888 J-1.09
X581.09 Y-1.888 I2.18 J0.0
X581.888 Y1.09 I-1.09 J1.888
G01 X580.156 Y0.09
G00 Z50.

lvrendos · 发表于 2008-12-6 18:37:06

如何提取两个字符之间的数值然后显示最小/最大数值
比如有一a.txt内容为:
G43 H9 Z50.
G00 X-579.844 Y-0.09 Z50. M8
Z-16.
G01 Z0.0 F900
X-578.112 Y-1.09 F3000
G03 X-581.09 Y1.888 I-1.888 J1.09
Y-1.888 I1.09 J-1.888
X-578.112 Y-1.09 I1.09 J1.888
G01 X-579.844 Y-0.09
G00 Z50.
X580.156 Y0.09
Z16.
G01 Z0.0 F900
X581.888 Y1.09 F3000
G03 X577.82 Y0.0 I-1.888 J-1.09
X581.09 Y-1.888 I2.18 J0.0
X581.888 Y1.09 I-1.09 J1.888
G01 X580.156 Y0.09
G00 Z50.
我要显示“z”与“."之间数值的最小植（-16），最大值（50）
之前我试了好几种，在一般的情况下可以，在这种情况下都不行

wxcute · 发表于 2008-12-6 19:32:44

@echo off
setlocal enableDelayedExpansion
for /f "usebackq delims=" %%i in ("bj.ini") do (
　set line=%%i
　set line=!line:*Z=Z!
　for /f "tokens=1* delims=Z." %%a in ("!line!") do (
　　if "%%a" lss "a" (
　　　set num=%%a
　　　if not defined Max set/a Max=num
　　　if not defined Min set/a Min=num
　　)
　　if !Max! lss !num! (
　　　set/a Max=num
　　)else if !Min! gtr !num! set/a Min=num
　)
)
echo Max:!Max!　Min:!Min!
pause

复制代码

batman · 发表于 2008-12-6 20:12:48

@echo off&setlocal enabledelayedexpansion
set /a min=0,max=0
for /f "tokens=1,2 delims=Z" %%a in ('findstr "Z" a.txt') do (
if "%%b" equ "" (
set "str=%%a"
) else (
set "str=%%b"
)
for /f "delims=." %%i in ("!str!") do (
if %%i leq !min! set "min=%%i"
if %%i geq !max! set "max=%%i"
)
)
echo 最小值为%min%，最大值为%max%。
pause>nul

复制代码

[ 本帖最后由 batman 于 2008-12-6 20:23 编辑 ]

pusofalse · 发表于 2008-12-6 20:20:22

回复batman兄，代码中有跟batcher同样的错误。
因为相对于整个文本来说，最小数是未知的，它有可能大于0。

batman · 发表于 2008-12-6 20:24:29

开始没考虑全，现已修改。。。

wxcute · 发表于 2008-12-6 20:26:32

这样负值会消失。没搞清是什么原因，所以就写个复杂点的了。

pusofalse · 发表于 2008-12-6 23:33:48

考虑到最大数有可能不是正数，最小数有可能不是负数，想想还是用补位的方法吧：

@Echo Off & Setlocal EnableDelayedExpansion
For /F "delims=" %%a In ('Findstr /i "z" "a.txt"') do (
set "var=%%a" & set "var=!var:*z=!"
For /F "delims=." %%d In ("!var!") do (
set "var=......................................%%d"
set "#!var:~-20!=%%d"
))
For /F "tokens=2 delims==" %%a in ('set #') do (
If Not Defined Flag Set "Flag=1" & Echo 最小值%%a
set "max=%%a"
)
Echo 最大值%max%

复制代码

[ 本帖最后由 pusofalse 于 2008-12-7 00:03 编辑 ]

pcl_test · 发表于 2016-9-24 15:03:13

//&cls&dir /a-d /b *.txt|cscript -nologo -e:jscript "%~f0"&pause&exit
var fso = new ActiveXObject('Scripting.FileSystemObject');
while(!WSH.StdIn.AtEndOfStream){
var line = WSH.StdIn.ReadLine();
try{
var m = fso.OpenTextFile(line, 1).ReadAll().match(/\bZ-?\d+/g).sort(function(a,b){return a.substr(1)-b.substr(1)});
if(m)WSH.Echo(fso.GetFileName(line)+':'+m+' min:'+m[0].substr(1)+' max:'+m[m.length-1].substr(1));
}catch(e){}
}

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 如何提取两个字符之间的数值然后显示最小/最大数值

如果我要同时搜索好几个txt文件该怎么弄

回复 1楼的帖子

回复 4楼的帖子

为什么下面这段字符不行的