【已解决】BAT如何逐列统计数据出现次数多少，并从多到少排序？

思想之翼

有378个txt文本，每个txt数据只有一行，为0-9十个数值的乱序排列，格式为：8 1 9 2 0 6 5 4 7 3 （约定从左到右分别为第1、2、3...10列）
欲：
统计378个txt文本中第1列的数据出现次数多少，并从多到少排序（出现次数相同的，则从小到大排序；出现次数为零的数值，也从小到大排序）
统计378个txt文本中第2列的数据出现次数多少，并从多到少排序（出现次数相同的，则从小到大排序；出现次数为零的数值，也从小到大排序）
...
统计378个txt文本中第10列的数据出现次数多少，并从多到少排序（出现次数相同的，则从小到大排序；出现次数为零的数值，也从小到大排序）

之后，将上述第1列、第2列...第10列的统计排序，合并成一行，存放在新建的txt文本中，格式为：7 5 8 0 6 3 9 1 4 2 2 1 4 5 3 7 8 9 0 6 ...

恳望得到帮助！

terse

1. @echo off&setlocal enabledelayedexpansion
   
2. for /L %%i in (0,1,9) do for /L %%j in (0,1,9) do set _%%i_%%j=0
   
3. for /f "delims=" %%i in ('dir /b/a-d *.txt') do (
   
4.     for /f "usebackq delims=" %%j in ("%%i") do (
   
5.         set n=-1
   
6.         for %%a in (%%j) do (
   
7.             set /a n+=1
   
8.             set /a $!n!_%%a+=1
   
9.         )
   
10.     )
    
11. )
    
12. for /L %%i in (0,1,9) do for /L %%j in (0,1,9) do (
    
13.     set "str=000!$%%i_%%j!"
    
14.     set /a n=9-%%j
    
15.     set "$%%i=!$%%i! !str:~-3!#!n!-%%j"
    
16. )
    
17. set "str="
    
18. for /L %%i in (0,1,9) do (
    
19.     for /f "tokens=2 delims=-" %%a in ('"(for %%j in (!$%%i!) do @echo %%j)|sort/r"') do (
    
20.         set "str=!str!%%a"
    
21.     )
    
22. )
    
23. >new_text.txt echo;!str!
    
24. pause

复制代码

xxpinqz

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. for /l %%a in (1,1,378) do (
   
4.     set /p str=<%%a.txt
   
5.     set n=0
   
6.     for %%b in (!str!) do set /a #!n!.%%b+=1,n+=1
   
7. )
   
8. for /l %%a in (0,1,9) do (
   
9.     for /l %%b in (0,1,9) do (
   
10.         set /a m=0
    
11.         for /l %%c in (0,1,9) do (
    
12.             if !#%%a.%%b!%%c lss !#%%a.%%c!%%b set /a m+=1
    
13.         )
    
14.     set "!m!=%%b"
    
15.     )
    
16.     for /l %%i in (0,1,9) do set "echo=!echo!!%%i! "
    
17. )
    
18. echo,%echo%>new.txt
    

复制代码

思想之翼

感谢2位大师的鼎力帮助！

apang

纯练习

1. @set @n=1 //&dir /a-d/b *.txt|cscript -nologo -e:jscript "%~0" &pause&exit /b
   
2. fso = new ActiveXObject("Scripting.FileSystemObject");
   
3. a = new Array();b = new Array();s = new Array();
   
4. for (i=0;i<10;i++) {a[i] = ""};
   
5. while (!WSH.StdIn.AtEndOfStream) {
   
6.     f = WSH.StdIn.ReadLine();
   
7.     arr = fso.OpenTextFile(f).ReadLine().split(" ");
   
8.     for (i=0;i<10;i++) {a[i] += arr[i] + " "};
   
9. }
   
10. for (i=0;i<10;i++) {
    
11.     for (j=0;j<10;j++) {
    
12.         b[j] = a[i].split(j).length + 1000 + (9-j).toString();
    
13.     };
    
14.     b.sort(function(x,y){return y-x});
    
15.     s[i] = b.join(" ").replace(/\d{4}(\d)/g,
    
16.         function(s0,s1){return 9-s1}
    
17.     );
    
18. };
    
19. fso.OpenTextFile("Result.txt",2,true).Write(s.join(" "));

复制代码