[日期时间] BAT批处理调用ftp怎样计算时间？

chejh

rem 获取一个小时前的时间
>"%temp%/MyDate.vbs" echo strLastHours=DateAdd("h", -1, time)
>>"%temp%/MyDate.vbs" echo strFmtDate=Right(Year(date()),4) ^& Right("0" ^& Month(date()),2) ^& Right("0" ^& Day(date()),2) ^& Right("0" ^& Hour(strLastHours),2)
>>"%temp%/MyDate.vbs" echo WScript.Echo strFmtDate
for /f %%a in ('cscript /nologo "%temp%/MyDate.vbs"') do (set ys=%%a)
复制代码

(不能显示15的上一天14号的23点)

rem 获取前一小时的日期
>"%temp%\MyDate.vbs" echo LastDate=date()-1
>>"%temp%\MyDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\MyDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\MyDate.vbs"') do (
  set DstDate=%%a
)
set /a h=%time:~0,2%-1
if %time:~0,2% gtr 10 (set ys=%date:~0,4%%date:~5,2%%date:~8,2%%h%)
if %time:~0,2% lss 10 (set ys=%date:~0,4%%date:~5,2%%date:~8,2%0%h%)
if %time:~0,2% equ 0 (set ys=%DstDate:~0,4%%DstDate:~4,2%%DstDate:~6,2%23)
复制代码

（不能显示10点的上一个小时9点）

本脚本显示的是当前时间的前一天 2014031714
第一个脚本0-1点时间不能自动减去1天
第二个脚本10点不能自动跳到9点

   大家最好能推荐一个支持被动的ftp工具，nat里面ftp服务器。用命令行客户端是不支持被动的，

Batcher

【方案一】BAT调用PowerShell

@echo off
REM Win7/Win8/Win10等系统自带PowerShell
REM 指定小时数
set "HoursAgo=1"

for /f "delims=" %%i in ('powershell -c "Get-Date (Get-Date).AddHours(-%HoursAgo%) -uformat '%%Y-%%m-%%d %%H:%%M:%%S'"') do (
    set "DstTime=%%i"
)
echo,%DstTime%
pause
复制代码

【方案二】BAT调用VBS

@echo off
REM 指定小时数
set "HoursAgo=1"

>"%temp%\MyDate.vbs" echo strLastHours=DateAdd("h", -%HoursAgo%, now)
>>"%temp%\MyDate.vbs" echo strFmtDate=Right(Year(strLastHours),4) ^& Right("0" ^& Month(strLastHours),2) ^& Right("0" ^& Day(strLastHours),2) ^& Right("0" ^& Hour(strLastHours),2) ^& Right("0" ^& Minute(strLastHours),2) ^& Right("0" ^& Second(strLastHours),2)
>>"%temp%\MyDate.vbs" echo WScript.Echo strFmtDate
for /f "delims=" %%i in ('cscript /nologo "%temp%\MyDate.vbs"') do (
    set "DstTime=%%i"
)
set DstTime=%DstTime:~0,4%-%DstTime:~4,2%-%DstTime:~6,2% %DstTime:~8,2%:%DstTime:~10,2%:%DstTime:~12,2%
echo,%DstTime%
pause
复制代码

【方案三】BAT调用日期时间函数

@echo off
REM 此类方法的关键在于如何获取标准化的当前系统日期
REM 请参考http://bbs.bathome.cn/thread-3328-1-1.html
REM 然后调用 Ritchie Lawrence 的日期函数，便可扩展出很多种方法，此处不再赘述。
REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html

REM 指定小时数
set "HoursAgo=1"

for /f "tokens=3" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate ^| findstr "sShortDate"') do (
    set RegDateOld=%%a
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f >nul
call :DateToSecs %date:~0,4% %date:~5,2% %date:~8,2% %time:~0,2% %time:~3,2% %time:~6,2% PassSeconds
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f >nul
set /a PassSeconds-=HoursAgo*60*60
call :SecsToDate %PassSeconds% DstYear DstMonth DstDay DstHour DstMinute DstSecond
set DstTime=%DstYear%-%DstMonth%-%DstDay% %DstHour%:%DstMinute%:%DstSecond%
echo,%DstTime%
pause
goto :eof

:DateToSecs %yy% %mm% %dd% %hh% %nn% %ss% secs
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5&set ss=%6
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a j=j*86400+hh*3600+nn*60+ss
endlocal&set %7=%j%&goto :EOF

:SecsToDate %secs% yy mm dd hh nn ss
setlocal ENABLEEXTENSIONS
set /a i=%1,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss% 
endlocal&set %7=%ss%&set %6=%nn%&set %5=%hh%&^
set %4=%dd%&set %3=%mm%&set %2=%yy%&goto :EOF
复制代码

chejh

日期不正确啊
  怎么会是一串乱七八糟的数字呢-  -

chejh

线面显示的年月不正确啊·

chejh

2014031714要以为这样的格式显示啊
  晚上12点过了之后0-1点之间要显示头一天比如今天是17号显示2014031623，
其他时间点正常显示2014031601,

Batcher

回复 3# chejh


    把那串乱七八糟的数字贴出来看看

Batcher

回复 5# chejh


    请直接复制2楼的代码，不要在你原来的代码上修改。

chejh

我复制的就是你那个代码·
  前面的数字1899123016

chejh

[img][/img]

chejh

[attach]7123[/attach][img][/img]

Batcher

2楼代码已更新
你再试试

chejh

可以了，谢谢

PowerShell

powershell送你把，解决日期计算类问题的金钥匙！   http://www.bathome.net/thread-25932-1-3.html
powershell代码

(get-date).adddays(-1)     --------减去一天

(get-date).AddHours(-2)  --------减去二小时
复制代码

用powershell即比vbs语法简单，又绝对无错，
不会有什么
不能自动减去1天
不能自动跳到9点
用了powershell 等于
刷 ！问题全不见了

然后再powershell。exe中调用微软的ftp客户端   ftp。exe 都是老旧稳定的程序。
命令行客户端是不支持被动的----这句话是错误的。
被动的ftp端口号一要大于1024，这是win linux默认规定，另外这个端口要开放，ftp。exe  ip 端口要能连上，即可。

chejh

回复 13# PowerShell


    是ftp在没有公网的情况下，中间有路由器做了nat，cmd命令行（注意：cmd命令行）不支持被动模式啊