批处理如何实现给文本内容添加行号？

wh1234567

文本内容比较多，但每行内容的前面没有序号，想用批处理自动给文本内容每行前面加个行号，请问如何写呢？
例如文本内容如下：
11.txt
需v师德师风
bdbdfbd-dfvd=dfd
231231323223123123232312323[fff]
sddfsfsfsd3231方便更方便
自动处理后格式为：
1-bdbdfbd-dfvd=dfd
2-231231323223123123232312323[fff]
3-sddfsfsfsd3231方便更方便
并输出到另外一个文本22.txt里

jingyu9575

1. 
   
2. @echo off
   
3. set i=1
   
4. >22.txt (for /f "delims=" %%s in (11.txt) do (
   
5.         setlocal enabledelayedexpansion
   
6.         <nul set /p "_=!i!"
   
7.         setlocal disabledelayedexpansion
   
8.         <nul set /p "_=-%%s"
   
9.         echo,
   
10.         set /a i+=1
    
11. ))
    

复制代码

如果分隔符用冒号就简单了：

1. findstr /N ".*" 11.txt > 22.txt

复制代码

DAIC

1. sed = 11.txt | sed "N;s/\n/-/" > 22.txt

复制代码

DAIC

1. gawk "{print NR"-"$0}" 11.txt > 22.txt

复制代码

DAIC

1. powershell -c "foreach ($i in $(gc 11.txt)) {$n++; "$n-" + $i}" > 22.txt

复制代码

wh1234567

回复 2# jingyu9575


   为什么会出现!i!这种情况，不能全部正常处理

wh1234567

不想使用第三方程序，希望大虾们帮助下吧，

wh1234567

每行前面添加行号和固定字符（例如-或.或空格）

CrLf

1. hash /printf:"%d-%s",number,string /file 11.txt >22.txt

复制代码

CrLf

1. @echo off
   
2. (for /f "tokens=1* delims=:" %%a in ('findstr /n .* 11.txt') do echo %%a-%%b)>22.txt

复制代码

CrLf

1. @echo off
   
2. for /f %%a in ('find /c /v "" ^<11.txt') do set count=%%a
   
3. (for /l %%a in (1 1 %count%) do (
   
4.   setlocal enabledelayedexpansion
   
5.   set /p "str="&echo;%%a-!str!
   
6.   endlocal
   
7. ))<11.txt >22.txt

复制代码

wh1234567

回复 10# CrLf


    哦，这个正常，感谢您了

CrLf

1. @echo off
   
2. ((for /f "delims=" %%a in ('findstr /n .* 11.txt') do (
   
3.    set "str=%%a"
   
4.    set /a n+=1
   
5.    setlocal enabledelayedexpansion
   
6.    set "str=!str:*:=!"
   
7.    echo !n!-!str!
   
8.    endlocal
   
9. ))>22.txt

复制代码

wh1234567

回复 11# CrLf


    这个不行，输不出

CrLf

1. @set @a=0;/*&echo off
   
2. findstr /n .* 11.txt |cscript /nologo /e:jscript %0 >22.txt
   
3. pause&exit
   
4. */
   
5. str = WScript.StdIn.ReadAll()
   
6. str = str.replace(/^(\d+):/gm,'$1-')
   
7. WScript.Echo(str)
   

复制代码