[游戏娱乐] 福利彩票双色球自动选号器之批处理彩色版

Batcher

@echo off
::Batcher@bbs.bathome.net
::2009-01-18
::福利彩票双色球自动选号器之批处理彩色版@CMD@XP
::http://bbs.bathome.net/thread-3109-1-1.html

title 福利彩票双色球自动选号器之批处理彩色版@%date%@bbs.bathome.net
:begin
set DstFolder=%temp%\ColorFolder
md "%DstFolder%" 2>nul
del /f /a /q "%DstFolder%\*.*" 2>nul
cd /d "%DstFolder%"
set RedNum=
set NumCnt=
set NumStr=
call :RandNum 1 11 2
set NumCnt=
set NumStr=
call :RandNum 12 22 2
set NumCnt=
set NumStr=
call :RandNum 23 33 2
set NumCnt=
set NumStr=
call :RandNum 1 16 1
set /p=<nul>"%RedNum:~1%"
call :ColorPrint 0c "%RedNum:~1%"
set /p= <nul
set /p=<nul>%BlueNum:~1%
call :ColorPrint 09 "%BlueNum:~1%"
set /p= 买一注双色球，你就为中国彩票的千亿元年销售额做出了贡献！<nul
echo.
pause
cls
del /f /a /q "%DstFolder%\*.*" 2>nul
goto :begin

:RandNum
set /a n=%random%%%(%2-%1+1)+%1
for %%a in (%NumStr%) do (
  if %n% equ %%a (
    goto :RandNum
  )
)
set NumStr=%NumStr% %n%
set /a NumCnt+=1
if %NumCnt% lss %3 (
  goto :RandNum
) else (
  if %3 equ 2 (
    set RedNum=%RedNum% %NumStr:~1%
  ) else if %3 equ 1 (
    set BlueNum=%NumStr%
  )
)
goto :eof

:ColorPrint
findstr /a:%1 .* "%~2*"
复制代码

tireless

@echo off
title 福利彩票《双色球》机选
:Input
set 注数=1
set /p 注数=请输入投注注数: 
cls
set /a "1/注数" 2>nul || (
  echo.&echo  请输入纯数字 !
  goto :Pause
)

:Repeat
setlocal

:Loop
set /a Red=%random%%%33+1
if defined %Red% goto :Loop
set /p=%Red% <nul
set /a n+=1
set %Red%=.
if %n% lss 6 goto :Loop

set /a Blue=%random%%%16+1
echo - %Blue%

endlocal
set /a 注数-=1,1/注数 2>nul && goto :Repeat

:Pause
echo. & set/p=请按任意键返回. . . <nul
pause>nul & cls & goto :Input
复制代码

[ 本帖最后由 tireless 于 2009-1-22 11:29 编辑 ]

zjhuzi

为什么出现6个蓝色的号码?

yslyxqysl

在findstr的后面加一句：

del "%~2"
复制代码

试试

Batcher

代码已更新，请重新测试。

523066680

batcher一定很帅的.....有GF了。。。羡慕
想起精华帖有个人这么问：GF是不是GrandFather

随风

似乎有个bug
3 7 18 20 26 31 3 7 18 20 26 313 买一注双色球，你就为中国彩票的千亿元年销售额做
出了贡献！
请按任意键继续. . .

Gentleman

测试了，还是有那种情况，期待进一步改进！

随风

凑热闹

::随机选双色球
:: @随风 @bbs.bathome.net @2010-09-04

@echo off & setlocal enabledelayedexpansion
::初始化数列
for /l %%i in (1 1 33) do set sj%%i=%%i

::获取随机红色球
for /l %%L in (1 1 5) do (
   call :Loop
   set "str="
   set /a w=!random! %% 16+101
   for /l %%i in (1 1 6) do (
      set n=0!sj%%i!
      set n=!n:~-2!
      set str=!str! !n!
    )
    call :sort0 "!str!" ok
    echo !ok! + !w:~-2!
)
pause
exit

::给红球排序
:sort0 排除法 可排序200位以内整数、0、负数、重复数（封装）
::位数越少速度越快默认20位 by 随风 @bbs.bathome.net @2009-02-28
setlocal enabledelayedexpansion&set w=20&set k=&set m=%~1
set lin=$$$$$$$$$$&set "lin=!lin!!lin!!lin!!lin!"
set lin=!lin!!lin!!lin!!lin!!lin!&set kf=&set "h="
for %%a in (!m!)do (set f=%%a&(if "!f:~0,1!"=="-" (
set f=!lin!!f:~1!&set "h=!h! a!f:~-%w%!"
) else (set f=!Lin!%%a&set h=!h! $!f:~-%w%!)))
(for %%a in (!m!)do (set n=$&set s=&(for %%i in (!h!)do (
if "%%i" geq "!n!" (set s=%%i !s!&set n=%%i)else set s=!s! %%i))
set h=!s:* =!&set n=!n:$=!&if "!n:~0,1!"=="a" (
set kf=!kf! !n:a=-!) else set k=!n! !k!))&set "k=!kf! !K!"
endlocal&set %~2=%k:~1,-1%&goto :EOF

:loop
:: 对数列进行随机交换
for /l %%i in (1,1,33) do (
    set /a x=!random! %% 33+1
    for %%j in (!x!) do set tmp=!sj%%j!
    set sj!x!=!sj%%i!
    set sj%%i=!tmp!
)
goto :EOF
复制代码

cjiabing

我顶~虽然基本上不会买
——想学学显示颜色


——最好再补充一个历史号码，也就是往期中奖号码，避免本期号码与上期号码有两个以上重复，与前十期中每期有三个以上重复，与前五十期有五个以上重复……主要是红色球的，——实际上是否如此不清楚。
不过，估计六位的随机数很难会全部重复，而以人工去推理随机数“买菜”似乎很愚蠢！……

[ 本帖最后由 cjiabing 于 2010-9-5 09:37 编辑 ]