[已解决]批处理调用批处理配置mysql5.5.22

wangrz421 · 发表于 2014-9-17 15:14:48

配置mysql的批处理位置：D:\test\mysql-5.5.20-win32\service install.bat
D:\test\mysql-5.5.20-win32\ 路径下运行service install.bat，没有问题
但是当从：D:\test\测试.bat 调用D:\test\mysql-5.5.20-win32\service install.bat时，就不行
提示：

测试.bat代码如下：

start /wait call "%rar%mysql-5.5.20-win32\service install.bat"
pause

复制代码

service install.bat代码如下：

@echo off
rem @echo off的作用是关闭回显功能
rem 找到当前路径
rem 将temp.txt文件中内容拷贝到temp.bat文件中
rem temp.txt文件中的内容是“set PathTemp=”
rem 特别注意：“=”后面不能加回车
copy temp.txt temp.bat>nul
rem 将路径添加到temp.bat文件中
cd>>temp.bat
rem 执行temp.bat文件中命令
rem temp.bat文件执行后，路径已经保存在PathTemp变量中
call temp.bat
rem 删除temp.bat文件
del temp.bat
rem 设置my-huge.ini的标记位
set tag=[mysqld]
rem 设置添加到my.ini文件中的数据库路径和数据路径
rem set datadir=datadir=%PathTemp%\data的意思是：
rem 将字符串“datadir=”、变量PathTemp对应的字符串以及字符串“\data”赋值给datadir变量
set basedir=basedir=%PathTemp%
set basedir=%basedir:\=/%
set datadir=datadir=%PathTemp%
set datadir=%datadir:\=/%/data
rem 设置运行环境变量homedir
set homedir=%PathTemp%\bin
rem 设置变量延迟
rem 注意：使用变量延迟后，相关变量用！！包围，这样程序才能正确识别
setlocal enabledelayedexpansion
rem 循环查找my-huge.ini文件中的内容
for /f "tokens=*" %%i in (my-huge.ini) do (
rem 将从my-huge.ini文件中读到的字符串，赋值给变量p
set p=%%i
rem 如果变量p的内容和my-huge.ini的标记位相同
rem 将变量p的内容写入my.ini文件中，同时在其后面加入两行内容：
rem basedir的内容和datadir的内容；
rem 如果不同，只将变量p的内容写入my.ini文件中
if "!p!"== "%tag%" (
echo !p!>>my.ini
echo !basedir!>>my.ini
echo !datadir!>>my.ini
)
if not "!p!"== "%tag%" echo !p!>>my.ini
)
rem 设置安装mysql服务的命令
set installcmd=.\bin\mysqld.exe -install
rem 调用安装命令
call !installcmd!
rem 启动mysql服务
net start mysql
rem 调用update.sql文件中的sql语句，将mysql的远程访问方式打开，以备远程访问服务器；
rem 同时，将mysql的密码更改，本批处理命令将mysql密码更改为root
.\bin\mysql -u root <.\update.sql
rem 重启mysql服务
net stop mysql
net start mysql
start /wait call createDatabase.bat
exit

复制代码

Batcher · 发表于 2014-9-17 15:36:57

start /wait "" "%rar%mysql-5.5.20-win32\service install.bat"

复制代码

wangrz421 · 发表于 2014-9-17 15:46:28

回复 2# Batcher

刚刚试过，没成功，还是原来的问题。

DAIC · 发表于 2014-9-17 16:10:33

回复 3# wangrz421

把你修改之后的测试.bat 的完整代码发出来看看
还有测试结果页发出来

wangrz421 · 发表于 2014-9-17 16:23:31

回复 4# DAIC

测试.bat代码内容：
start /wait "" "%rar%mysql-5.5.20-win32\service install.bat"
pause

wangrz421 · 发表于 2014-9-17 16:24:22

回复 4# DAIC

额。。顺序是右边的先出现，然后是左边的

apang · 发表于 2014-9-17 16:45:28

在service install.bat的开头加上：

pushd "%~dp0"

复制代码

试试
另外，测试.bat中的%rar%是啥？去掉吧

wangrz421 · 发表于 2014-9-17 16:58:58

回复 7# apang

非常感谢，可以运行了，%rar% 是获取当前路径用的，set rar = %~dp0

DAIC · 发表于 2014-9-17 20:49:02

回复 8# wangrz421

等号两边不能有空格

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [已解决]批处理调用批处理配置mysql5.5.22