批处理获取多网卡系统中指定网络连接对应的MAC地址

Batcher · 发表于 2014-9-30 17:42:36

@echo off
REM 设置网络适配器的名称
REM 英文系统一般是：Local Area Connection
REM set "AdapterName=Local Area Connection"
REM 中文系统一般是：本地连接
set "AdapterName=本地连接"
set "FileTmp=%temp%\ipList.txt"
ipconfig /all >"%FileTmp%"
for /f "delims=:" %%i in ('findstr /n /c:"%AdapterName%" "%FileTmp%"') do (
set "SkipRow=%%i"
goto :DoSkip
)
:DoSkip
for /f "tokens=2 delims=:" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr "..-..-..-..-..-.."') do (
set "MAC=%%i"
goto :ShowResult
)
:ShowResult
set "MAC=%MAC: =%"
echo,%MAC%
pause

复制代码

Linuxer · 发表于 2014-9-30 18:19:12

学习下代码思路，。多谢大神~~还是沙发。。哦

Rocmind · 发表于 2014-12-18 20:24:17

很好的工具，实用有效

Batcher · 发表于 2022-10-19 14:41:22

批处理获取多网卡系统中指定网络连接对应的MAC地址和IP地址

@echo off
REM 设置网络适配器的名称
set "AdapterName=以太网 2"
set "FileTmp=%temp%\ipList.txt"
ipconfig /all >"%FileTmp%"
for /f "delims=:" %%i in ('findstr /n /c:"%AdapterName%" "%FileTmp%"') do (
set "SkipRow=%%i"
goto :FindMAC
)
:FindMAC
for /f "tokens=2 delims=:" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr "..-..-..-..-..-.."') do (
set "MAC=%%i"
goto :FindIP
)
:FindIP
for /f "tokens=2 delims=:(" %%i in ('more +%SkipRow% "%FileTmp%" ^| findstr /v "IPv6" ^| findstr "IP"') do (
set "IP=%%i"
goto :ShowResult
)
:ShowResult
set "MAC=%MAC: =%"
echo,%MAC%
set "IP=%IP: =%"
echo,%IP%
pause

复制代码

wxf617 · 发表于 2022-10-29 16:07:06

很实用的东西，谢谢楼主

1319484094 · 发表于 2024-12-5 23:36:37

这么久还更新，楼主牛逼

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[网络工具] 批处理获取多网卡系统中指定网络连接对应的MAC地址