如何加速从国外服务器下载图片？

yu2n

如何加速从国外服务器下载图片？
用GoAgent代理发现更慢……

@echo off
SetLocal EnableDelayedExpansion
set "MeDir=%~dp0"
set "MeDir=%MeDir:~0,-1%"
set "save_dir=%MeDir%\img"
set "url_0=http://xz1.mm667.com/xz"

for /l %%a in (1,1,100) do (
	set "url_1=000%%a"
	set "url_1=!url_1:~-2!"
	for /l %%b in (1,1,100) do (
		set "url_2=000%%b"
		set "url_2=!url_2:~-3!"
		set "url_3=!url_0!!url_1!/images/!url_2!.jpg"
		echo,!url_3!
		wget -c -x -t 5 "!url_3!" -P "%save_dir%"
	)
)
pause
复制代码

注：
1. Wget.exe 请自行下载。
2. 代码中的网址可能不安全，可能造成无法预料的后果，请不要轻易访问。(也许会有福利呢？……XD)

bjc5233

哈哈，收到祝福啦！！！
另外问一句，还有吗？

523066680

开5个进程？比如一个WGET 是30KB/S 其实5个进程的话各自也差不多是20-30KB/S
以前用批处理写过批量下H站封面图 ，后来感觉很低俗，连脚本一起被我删掉了。

大致就是循环里面建立一个 递增变量i
i%5=0 的时候在当前进程wget ， 非0的时候start 另开进程wget
因为各个进程下载速度差不多，当前进程的下载会产生延时效果，进程不会很快爆发
一般在5-10个进程浮动。

yu2n

开5个进程？比如一个WGET 是30KB/S 其实5个进程的话各自也差不多是20-30KB/S
以前用批处理写过批量下H站封 ...
523066680 发表于 2014-11-30 10:47

感谢 523066680 版主的提醒，下面是开同时开10个 wget.exe 进程的方法：

@echo off
SetLocal EnableDelayedExpansion
set "MeDir=%~dp0"
set "MeDir=%MeDir:~0,-1%"
set "save_dir=%MeDir%\img"
set "url_0=http://xz1.mm667.com/xz"

for /l %%a in (1,1,100) do (
  set "url_1=000%%a"
  set "url_1=!url_1:~-2!"
  for /l %%b in (1,1,100) do (
    set "url_2=000%%b"
    set "url_2=!url_2:~-3!"
    set "url_3=!url_0!!url_1!/images/!url_2!.jpg"
    rem 限制 10 个 wget.exe 进程
    set/a n=0
    for /f %%c in ('tasklist/nh') do (if /i "wget.exe"=="%%c" set/a n+=1)
    if !n! geq 9 (
      wget -c -x -t 5 "!url_3!" -P "%save_dir%"
    ) else (
      start /min "" wget -c -x -t 5 "!url_3!" -P "%save_dir%"
    )
  )
)
pause
复制代码

523066680

回复 4# yu2n


    start 的句子加上/min 参数，窗口自动最小化，就不会影响其他应用窗口

CrLf

回复 3# 523066680


    你要相信楼主是纯洁的

523066680

回复 6# CrLf


    我只是举个栗子

yu2n

回复 2# bjc5233

XD
没有这种了……

其他的要翻墙。