yu2n

Windows XP 的 DiskPart 命令有 BUG ？ 我在虚拟机建立了一块硬盘（Disk 1），分区表为 GPT，用PAProCn、DiskGenius 都可以识别为 GPT 分区表，但是 DiskPart 命令识别不出来：

C:\Documents and Settings\Yu2n>ver

Microsoft Windows XP [Version 5.1.2600]

C:\Documents and Settings\Yu2n>diskpart

Microsoft DiskPart version 5.1.3565

Copyright (C) 1999-2003 Microsoft Corporation.
On computer: PC-02

DISKPART> list disk

  Disk ###  Status      Size     Free     Dyn  Gpt
  --------  ----------  -------  -------  ---  ---
  Disk 0    Online        20 GB      0 B
  Disk 1    Online        10 GB      0 B
  Disk 2    Online       500 GB      0 B

DISKPART>
复制代码

因为 DiskPart 不能正常工作，到此为止了……放个VBS代码上来，请自行测试吧：

2015.1.7 更新：感谢 apang 提醒 65 行 GetSize 少了个 S ，现已补上，谢谢。

RunAsAdmin
Main
Sub Main()
  Dim objWMI, colDisks
  Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
  Set colDisks = objWMI.ExecQuery("select * from Win32_DiskDrive where MediaType like 'fixed%'")
  For Each objDisk in colDisks
    s = s & "硬盘" & objDisk.Index & ":" & vbTab
    s = s & "大小:" & GetSize(objDisk.Size) & vbTab
    s = s & "型号:" & objDisk.Caption & vbTab
    s = s & "分区表:" & IsGPT(objDisk.Index) & vbCrLf
    strDiskID = Replace(objDisk.DeviceID, "\", "\\")
    Set colPartitions = objWMI.ExecQuery _
        ("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & strDiskID & """}" _
        & " where AssocClass=Win32_DiskDriveToDiskPartition")
    For Each objPartition in colPartitions
      strPartId = objPartition.DeviceID
      Set colLogicalDisks = objWMI.ExecQuery _
          ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & strPartId & """}  where AssocClass=Win32_LogicalDiskToPartition")
      For Each objLogicalDisk in colLogicalDisks
        size = objLogicalDisk.Size
        free = objLogicalDisk.Freespace
        used = FormatNumber((size - free) / size * 100, 2, true) & "%"
        s = s & "分区" & objLogicalDisk.DeviceID & vbTab
        s = s & "大小:" & GetSize(size) & vbTab
        s = s & "剩余:" & GetSize(free) & vbTab
        s = s & "使用率:" & used & vbCrLf
      Next
    Next
    s = s & vbCrLf
  Next
  WScript.Echo s
End Sub

' 格式化
Function GetSize(intSize)
  If intSize/1024/1024 > 1024 Then
    GetSize = FormatNumber(intSize/1024/1024/1024, 2, true) & "GB"
  Else
    GetSize = FormatNumber(intSize/1024/1024, 2, true) & "MB"
  End If
End Function

' 获取指定硬盘的分区表类型(GPT/MBR)
Function IsGPT(ByVal nDiskIndex)
  IsGPT = "MBR"   'XP 不支持diskpart 识别GPT，默认MBR。感谢 freesoft00 提醒。
  Dim wso, sLogFile, sText
  Set wso = CreateObject("WScript.Shell")
  sLogFile = wso.ExpandenVironmentStrings("%temp%\diskpart.log")
  wso.Run "cmd /c ""chcp 437 & cls & (echo list disk | diskpart | find /i ""Disk " & nDiskIndex & """) >""" & sLogFile & """ "" ", 0, False
  Call TxtFile(sLogFile, 1, -2, sText)
  If Trim(Right(sText,3)) = "*" Then IsGPT = "GPT"
End Function

' 对文本指定编码进行读写操作2
'nRW: 1只读, 2只写, 8追加 'nCharset: -2(系统), -1(Unicode), 0(ASCII)
Sub TxtFile(ByVal FileName, ByVal nRW, ByVal nCharset, ByRef sText)
  Dim fso :  Set fso = CreateObject("Scripting.filesystemobject")
  If sText <> "" And (nRW = 2 Or nRW = 8) Then
    fso.OpenTextFile(FileName, nRW, True, nCharset).Write sText
  ElseIf fso.FileExists(FileName) And nRW = 1 Then
    If fso.GetFile(FileName).Size > 0 Then _
      sText = fso.OpenTextFile(FileName, nRW, False, nCharset).ReadAll
  End If
End Sub

' 以管理员身份运行
Sub RunAsAdmin()
  Dim objItems, objItem, strVer, nVer
  Set objItems = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
  For Each objItem In objItems
    strVer = objItem.Version
  Next
  nVer = Split(strVer, ".")(0) & Split(strVer, ".")(1)
  If nVer >= 60 Then
    Dim oShell, oArg, strArgs
    Set oShell = CreateObject("Shell.Application")
    If Not WScript.Arguments.Named.Exists("ADMIN") Then
      For Each oArg In WScript.Arguments
        strArgs = strArgs & " """ & oArg & """"
      Next
      strArgs = strArgs & " /ADMIN:1"
      Call oShell.ShellExecute("WScript.exe", """" & WScript.ScriptFullName & """" & strArgs, "", "runas", 1)
      Set oShell = Nothing
      WScript.Quit(0)
    End If
    Set oShell = Nothing
  End If
End Sub
复制代码

ygqiang

Windows XP 的 DiskPart 命令有 BUG ？ 我在虚拟机建立了一块硬盘（Disk 1），分区表为 GPT，用PAProCn、Di ...
yu2n 发表于 2015-1-3 07:21

多谢了。。测试结果可以。不过是弹出窗口，需要用鼠标点击下“确定”按钮。

能否将vbs的结果 输出到txt文件里面
这个我就可以在bat里面显示txt的内容了



start c:\diskinfo.vbs
ping 127.0.0.1 -n 5 >nul 2>nul
cls
type c:\diskinfo.txt

czjt1234

批处理改为

cscript /nologo c:\diskinfo.vbs
pause

ygqiang

批处理改为

cscript /nologo c:\diskinfo.vbs
pause
czjt1234 发表于 2015-1-3 10:08

    多谢

能否修改下16楼的vbs代码，   让vbs生成结果放到txt里面

这样bat里面可以直接显示出txt里面的结果

ygqiang

去掉这个弹出窗口，将结果保存到txt文件里面

freesoft00

回复 16# yu2n


    xp系统不支持gpt分区，只有2003以上的系统才支持，可以加一个判断，如果当前系统是xp系统就不判断gpt，直接就是mbr格式的。

apang

顶楼代码第65行有一处笔误，Getize 应该为 GetSize

ygqiang

硬盘-格式及分区检测DynamicScript-修正版

@echo off
echo ——————————————————————————————————————— >nul 2>nul
echo 判断硬盘是MBR分区还是GTP分区

if exist "c:\diskinfo.*" (del /q "c:\diskinfo.*" >nul 2>nul)
for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (
    more +%%i "%~f0" > c:\diskinfo.vbs
)
ping 127.0.0.1 -n 2 >nul 2>nul
cls
cscript /nologo c:\diskinfo.vbs
ping 127.0.0.1 -n 2 >nul 2>nul
CScript /NoLogo c:\diskinfo.vbs>c:\diskinfo.txt
ping 127.0.0.1 -n 2 >nul 2>nul
cls
Type c:\diskinfo.txt
ping 127.0.0.1 -n 5 >nul 2>nul & if exist "c:\diskinfo.*" (del /q "c:\diskinfo.*" >nul 2>nul)

echo ——————————————————————————————————————— >nul 2>nul
if exist "c:\diskinfo.*" (del /q "c:\diskinfo.*" >nul 2>nul)
set "vbs=c:\diskinfo.vbs"
set "log=c:\diskinfo.log"
for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (more +%%i "%~f0" > "%vbs%")
CScript //NoLogo "%vbs%" > "%log%"
cls
type "%log%"
ping 127.0.0.1 -n 5 >nul 2>nul & if exist "c:\diskinfo.*" (del /q "c:\diskinfo.*" >nul 2>nul) & exit/b
goto :eof

echo ——————————————————————————————————————— >nul 2>nul
:DynamicScript
Main
Sub Main()
  Dim objWMI, colDisks
  Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
  Set colDisks = objWMI.ExecQuery("select * from Win32_DiskDrive where MediaType like 'fixed%'")
  For Each objDisk in colDisks
    s = s & "硬盘" & objDisk.Index & ":" & vbTab
    s = s & "大小:" & GetSize(objDisk.Size) & vbTab
    s = s & "型号:" & objDisk.Caption & vbTab
    s = s & "分区表:" & IsGPT(objDisk.Index) & vbCrLf
    strDiskID = Replace(objDisk.DeviceID, "\", "\\")
    Set colPartitions = objWMI.ExecQuery _
        ("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & strDiskID & """}" _
        & " where AssocClass=Win32_DiskDriveToDiskPartition")
    For Each objPartition in colPartitions
      strPartId = objPartition.DeviceID
      Set colLogicalDisks = objWMI.ExecQuery _
          ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & strPartId & """}  where AssocClass=Win32_LogicalDiskToPartition")
      For Each objLogicalDisk in colLogicalDisks
        size = objLogicalDisk.Size
        free = objLogicalDisk.Freespace
        used = FormatNumber((size - free) / size * 100, 2, true) & "%"
        s = s & "分区" & objLogicalDisk.DeviceID & vbTab
        s = s & "大小:" & GetSize(size) & vbTab
        s = s & "剩余:" & GetSize(free) & vbTab
        s = s & "使用率:" & used & vbCrLf
      Next
    Next
    s = s & vbCrLf
  Next
  WScript.Echo s
' 把显示的内容保存在TXT文件
' WScript.Echo s替换为下面的代码
' CreateObject("Scripting.filesystemobject").CreateTextFile("结果.txt",2).Write s
End Sub
' 格式化
Function GetSize(intSize)
  If intSize/1024/1024 > 1024 Then
    GetSize = FormatNumber(intSize/1024/1024/1024, 2, true) & "GB"
  Else
    GetSize = FormatNumber(intSize/1024/1024, 2, true) & "MB"
  End If
End Function
' 获取指定硬盘的分区表类型(GPT/MBR)
Function IsGPT(ByVal nDiskIndex)
  IsGPT = "MBR"
  Dim wso, sLogFile, sText
  Set wso = CreateObject("WScript.Shell")
  sLogFile = wso.ExpandenVironmentStrings("%temp%\diskpart.log")
  wso.Run "cmd /c ""chcp 437 & cls & (echo list disk | diskpart | find /i ""Disk " & nDiskIndex & """) >""" & sLogFile & """ "" ", 0, False
  Call TxtFile(sLogFile, 1, -2, sText)
' If Trim(Right(sText,3)) = "*" Then IsGPT = "GPT"
If InStrRev(sText, "*")>0 Then IsGPT = "GPT"
End Function
' 对文本指定编码进行读写操作2
'nRW: 1只读, 2只写, 8追加 'nCharset: -2(系统), -1(Unicode), 0(ASCII)
Sub TxtFile(ByVal FileName, ByVal nRW, ByVal nCharset, ByRef sText)
  Dim fso :  Set fso = CreateObject("Scripting.filesystemobject")
  If sText <> "" And (nRW = 2 Or nRW = 8) Then
    fso.OpenTextFile(FileName, nRW, True, nCharset).Write sText
  ElseIf fso.FileExists(FileName) And nRW = 1 Then
    If fso.GetFile(FileName).Size > 0 Then _
      sText = fso.OpenTextFile(FileName, nRW, False, nCharset).ReadAll
  End If
End Sub
' 以管理员身份运行
Sub RunAsAdmin()
  Dim objItems, objItem, strVer, nVer
  Set objItems = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
  For Each objItem In objItems
    strVer = objItem.Version
  Next
  nVer = Split(strVer, ".")(0) & Split(strVer, ".")(1)
  If nVer >= 60 Then
    Dim oShell, oArg, strArgs
    Set oShell = CreateObject("Shell.Application")
    If Not WScript.Arguments.Named.Exists("ADMIN") Then
      For Each oArg In WScript.Arguments
        strArgs = strArgs & " """ & oArg & """"
      Next
      strArgs = strArgs & " /ADMIN:1"
      Call oShell.ShellExecute("WScript.exe", """" & WScript.ScriptFullName & """" & strArgs, "", "runas", 1)
      Set oShell = Nothing
      WScript.Quit(0)
    End If
    Set oShell = Nothing
  End If
End Sub
复制代码