[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[日期时间] 批处理删除指定天数日期之前的文件夹(2023-10-08)

【方案一】BAT + PowerShell

1-1-以文件夹的修改日期为准.bat
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 如果显示的待删除文件夹列表正确无误
  4. REM 把 Select-Object FullName 修改成 Remove-Item -Force -Recurse 再次执行即可真正删除文件夹
  5. REM Win7/Win10/Win11等系统自带PowerShell
  6. REM ----------------------------------------------------------------------------------------
  7. REM 指定待删除文件夹所在的路径
  8. set "SrcDir=E:\Test"
  9. REM 指定天数
  10. set "DaysAgo=7"
  11. powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.LastWriteTime)).days -gt %DaysAgo% -and $_.PsISContainer -eq $True)} | Select-Object FullName"
复制代码
1-2-以文件夹的创建日期为准.bat
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 如果显示的待删除文件夹列表正确无误
  4. REM 把 Select-Object FullName 修改成 Remove-Item -Force -Recurse 再次执行即可真正删除文件夹
  5. REM Win7/Win10/Win11等系统自带PowerShell
  6. REM ----------------------------------------------------------------------------------------
  7. REM 指定待删除文件夹所在的路径
  8. set "SrcDir=E:\Test"
  9. REM 指定天数
  10. set "DaysAgo=7"
  11. powershell -c "Get-ChildItem -Path '%SrcDir%' -Recurse -ErrorAction:SilentlyContinue | Where-Object -FilterScript {(((get-date) - ($_.CreationTime)).days -gt %DaysAgo% -and $_.PsISContainer -eq $True)} | Select-Object FullName"
复制代码
【方案二】以文件夹的修改日期为准 forfiles
  1. @echo off
  2. REM ------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件的最后修改日期为准)的文件夹。
  4. REM 如果演示结果无误,把rd前面的echo去掉,即可实现真正删除。
  5. REM Win7/Win10/Win11等系统自带forfiles命令
  6. REM ------------------------------------------------------------------------------
  7. REM 指定待删除文件的存放路径
  8. set "SrcDir=C:\Test\BatHome"
  9. REM 指定天数
  10. set "DaysAgo=7"
  11. forfiles /p "%SrcDir%" /m * /d -%DaysAgo% /c "cmd /c if @isdir==TRUE (echo rd /s /q @path)"
  12. pause
复制代码
【方案三】BAT + REG + VBS
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件夹的最后修改日期为准)的文件夹。
  4. REM 如果演示结果无误,把rd前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了临时VBS代码进行日期计算
  6. REM 本例为兼容不同的日期格式,调用reg命令统一设置日期格式,
  7. REM 处理完毕之后再把日期格式恢复成原来的状态。
  8. REM ----------------------------------------------------------------------------------------
  9. REM 指定待删除文件夹的存放路径
  10. set "SrcDir=E:\Test"
  11. REM 指定天数
  12. set "DaysAgo=7"
  13. for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  14.     set "RegDateOld=%%a"
  15. )
  16. set RegDateOld=%RegDateOld:~-8%
  17. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  18. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  19. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  20. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  21. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  22.     set "DstDate=%%a"
  23. )
  24. set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
  25. for /d %%a in ("%SrcDir%\*.*") do (
  26.     if "%%~ta" leq "%DstDate%" (
  27.         if exist "%%a\" (
  28.             echo rd /s /q "%%a"
  29.         )
  30.     )
  31. )
  32. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  33. pause
复制代码
【方案四】BAT + REG + Ritchie Lawrence 日期函数
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件夹的最后修改日期为准)的文件夹。
  4. REM 如果演示结果无误,把rd前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了 Ritchie Lawrence 的日期函数进行日期计算
  6. REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
  7. REM 本例为兼容不同的日期格式,调用reg命令统一设置日期格式,
  8. REM 处理完毕之后再把日期格式恢复成原来的状态。
  9. REM ----------------------------------------------------------------------------------------
  10. REM 指定待删除文件夹的存放路径
  11. set "SrcDir=E:\Test"
  12. REM 指定天数
  13. set "DaysAgo=7"
  14. for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  15.     set "RegDateOld=%%a"
  16. )
  17. set "RegDateOld=%RegDateOld:~-8%"
  18. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  19. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
  20. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  21. set /a PassDays-=%DaysAgo%
  22. call :DaysToDate %PassDays% DstYear DstMonth DstDay
  23. set "DstDate=%DstYear%%DstMonth%%DstDay%"
  24. set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"
  25. for /d %%a in ("%SrcDir%\*.*") do (
  26.     if "%%~ta" leq "%DstDate%" (
  27.         if exist "%%a\" (
  28.             echo rd /s /q "%%a"
  29.         )
  30.     )
  31. )
  32. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  33. pause
  34. goto :eof
  35. :DateToDays %yy% %mm% %dd% days
  36. setlocal ENABLEEXTENSIONS
  37. set yy=%1&set mm=%2&set dd=%3
  38. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
  39. set /a dd=100%dd%%%100,mm=100%mm%%%100
  40. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
  41. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
  42. endlocal&set %4=%j%&goto :EOF
  43. :DaysToDate %days% yy mm dd
  44. setlocal ENABLEEXTENSIONS
  45. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
  46. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
  47. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
  48. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
  49. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码
【方案五】BAT + VBS
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件夹的最后修改日期为准)的文件夹。
  4. REM 如果演示结果无误,把rd前面的echo去掉,即可实现真正删除。
  5. REM 本例调用了临时VBS代码进行日期计算,并统一设置系统日期格式,处理完毕
  6. REM 之后再把日期格式恢复成原来的状态。摆脱了对reg命令的依赖。
  7. REM ----------------------------------------------------------------------------------------
  8. REM 指定待删除文件夹的存放路径
  9. set "SrcDir=E:\Test"
  10. REM 指定天数
  11. set "DaysAgo=7"
  12. >"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  13. >>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
  14. for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
  15.     set "RegDateOld=%%a"
  16. )
  17. >"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  18. >>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
  19. cscript /nologo "%temp%\UnifyDate.vbs"
  20. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  21. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  22. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  23. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  24.     set "DstDate=%%a"
  25. )
  26. set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"
  27. for /d %%a in ("%SrcDir%\*.*") do (
  28.     if "%%~ta" leq "%DstDate%" (
  29.         if exist "%%a\" (
  30.             echo rd /s /q "%%a"
  31.         )
  32.     )
  33. )
  34. >"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
  35. >>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
  36. cscript /nologo "%temp%\RecoverDate.vbs"
  37. pause
复制代码
【方案六】字符串截取

根据日期出现在文件夹名称中的具体位置,调整第24行字符串截取。
具体语法请参考参考set命令教程第8页
http://bbs.bathome.net/thread-31727-1-1.html
  1. @echo off
  2. REM ----------------------------------------------------------------------------------------
  3. REM 演示:删除指定路径下指定天数之前(以文件夹名中包含的日期字符串为准)的文件夹。
  4. REM 如果演示结果无误,把rd前面的echo去掉,即可实现真正删除。
  5. REM 本例假设文件夹名中包含的日期字符串(比如:Archive-2009-12-25)
  6. REM ----------------------------------------------------------------------------------------
  7. REM 指定待删除文件夹的存放路径
  8. set "SrcDir=E:\Test"
  9. REM 指定天数
  10. set "DaysAgo=7"
  11. >"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
  12. >>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
  13. >>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
  14. for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  15.   set "DstDate=%%a"
  16. )
  17. set "DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%"
  18. setlocal enabledelayedexpansion
  19. for /d %%a in ("%SrcDir%\*.*") do (
  20.     set "FolderDate=%%~na"
  21.     set "FolderDate=!FolderDate:~8,10!"
  22.     if "!FolderDate!" leq "%DstDate%" (
  23.         if exist "%%a\" (
  24.             echo rd /s /q "%%a"
  25.         )
  26.     )
  27. )
  28. endlocal
  29. pause
复制代码
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

还是VBS方便吧,用那个VBS外部命令。。。

TOP

回复 2楼 的帖子

萝卜青菜,各有所爱^_^
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 4楼 的帖子

“取不到时间的阴气的”是什么意思?

不要双击运行
把代码保存为C:\test.bat
把@echo off删除
在合适的地方加上pause
开始
运行
cmd
C:\test.bat
看看执行过程是哪一步出错了?
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 10楼 的帖子

2003系统中的reg命令返回值和XP的略有不同,我马上去修改一下顶楼的代码。

顶楼代码已更新,把skip=4改成skip=3即可。请重新测试。
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 12楼 的帖子

能看看执行过程吗?像7楼那种
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 14楼 的帖子

感谢测试,顶楼代码已再次更新。
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 16楼 的帖子

1、请把@echo off删除,贴出完整过程。
2、我的代码用的是for /d,你的测试结果是for /r,你确定自己测试是顶楼的代码?
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 18楼 的帖子

1、请你回头看看7楼你贴的内容到底是for /r还是for /d
2、17楼是希望你能够删除@echo off,贴出完整执行过程,你是不是贴错了?
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 15楼 的帖子

楼主你好,刚刚在自动删除文件上得到可用的代码,非常感谢!
不过自动删除文件夹上,这3个方案在xp系统下cmd下运行时都是:
命令语法不正确
不知道什么原因!

TOP

回复 20楼 的帖子

请参考5楼
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 21楼 的帖子

楼主,我把运行的结果拷贝贴图如下:

TOP

这个也需要慢慢学习一下。

TOP

回复 22# thth


    你和我运行的结果一样,不知道为为什么```希望楼主给我们解答一下```

TOP

回复 21# Batcher


    我和22楼运行的结果一样,貌似是缺个“(”吧?希望楼主帮个忙`

TOP

返回列表