[已解决]批处理如何将短路径还原成完整的路径？

ttszuo

TEMP的变量路径为C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp
如何通过C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp这样的短路径来获取长路径,同样的文件的长路径该怎么通过短路径来获取

WHY

1. @echo off
   
2. set "strShortPath=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp"
   
3. 
   
4. for %%i in ("%strShortPath%") do (
   
5.     pushd %%~di\
   
6.     if exist "%%~fi" (
   
7.         for /d /r %%j in ("%%~nxi?") do (
   
8.             if /i "%%~sj"=="%%~fi" set "strFullPath=%%~fj" & goto :message
   
9.         )
   
10.     ) else if exist "%%~fi" (
    
11.         for /r %%j in ("%%~nxi?") do (
    
12.             if /i "%%~sj"=="%%~fi" set "strFullPath=%%~fj" & goto :message
    
13.         )
    
14.     ) else set "strFullPath=NULL"
    
15. )
    
16. 
    
17. :message
    
18. echo %strFullPath%
    
19. pause

复制代码

ttszuo

回复 2# WHY
有没有其他第三方工具也行,的这个的执行速度实在是太慢了

WHY

1. @echo off
   
2. set "strShortPath=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp"
   
3. 
   
4. for /f "tokens=1*delims=|" %%i in ("%strShortPath%|%strShortPath%\..") do (
   
5.     if exist "%%~fi" (
   
6.         >~tmp.vbs echo WScript.Echo CreateObject("Shell.Application"^).NameSpace("%%~fi"^).Self.Path
   
7.     ) else if exist "%%~fi" (
   
8.         >~tmp.vbs echo WScript.Echo CreateObject("Shell.Application"^).NameSpace("%%~fj"^).ParseName("%%~nxi"^).Path
   
9.     ) else echo NULL&pause & exit
   
10. )
    
11. 
    
12. for /f "delims=" %%i in ('cscript //nologo ~tmp.vbs') do set "strFullPath=%%~fi"
    
13. del ~tmp.vbs
    
14. echo %strFullPath%
    
15. pause

复制代码

CrLf

1. @echo off
   
2. set "strShortPath=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp"
   
3. 
   
4. pushd "%strShortPath%\.."
   
5. for %%a in ("%strShortPath%") do set "strFullPath=%cd%\%%~nxa"
   
6. popd
   
7. 
   
8. echo %strFullPath%
   
9. 
   
10. pause

复制代码

bailong360

1. @echo off
   
2. set ShortPath=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp
   
3. call :GetLongPath LongPath "%ShortPath%"
   
4. echo %ShortPath%
   
5. echo %LongPath%
   
6. pause
   
7. :GetLongPath [RetVar] [ShortPath]   by bailong360 @bbs.bathome.net
   
8. @echo off&setlocal enabledelayedexpansion&set "S=%~2"&set "S=!S:\= !"
   
9. (for %%i in (!S!) do set /a n+=1&set "D!n!=%%i")&set "D1=!D1!"&set /a n-=1
   
10. (for /l %%i in (1 1 !n!) do (cd /d "!D%%i!"&set /a n=%%i+1
    
11. for %%j in (!n!) do (set "t=!D%%j:~,-1!?"&for /d %%k in (!t!) do (
    
12. if "%%~snxk"=="!D%%j!" set "L=!L!\%%~k"))))&if not exist "%~2" (for %%i in (!n!) do (
    
13. set "t=!D%%i:~,-1!?"&for /r %%j in (!t!) do if "%%~snxj"=="!D%%i!" set "L=!L!\%%~nxj"))
    
14. endlocal&set "%~1=%D1:~,2%%L%"&goto :eof

复制代码

参考资料:http://stackoverflow.com/questio ... rom-short-file-name
已修改,代码虽然看起来像屎一样,但效率还是挺高的

bailong360

回复 5# CrLf
巡查大人....XP 32位专业版 用户测试后表示行不通..

WHY

我来个递归方案：

1. @echo off
   
2. set "strShortPath=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp"
   
3. if not exist "%strShortPath%" echo NULL&pause & exit
   
4. 
   
5. call :getFullPath "%strShortPath%"
   
6. for %%i in ("%strFullPath%.") do set "strFullPath=%%~fi"
   
7. echo %strfullPath%
   
8. pause & exit
   
9. 
   
10. :getFullPath
    
11. for %%i in ("%~1\..") do (
    
12.     cd /d "%%~fi"
    
13.     for /f "delims=" %%j in ('dir /a /b "%~1?"') do (
    
14.         if /i "%%~snxj"=="%~nx1" (
    
15.             set "strFullPath=%%j\%strFullPath%"
    
16.             if /i not "%%~fi"=="%~d1" call :getFullPath "%%~fi"
    
17.         )
    
18.     )
    
19. )

复制代码

CrLf

回复 7# bailong360


    忘了加 echo 了，现在呢？

bailong360

回复 9# CrLf
不行
话说我忘记判定为文件的情况了....

ttszuo

昨天突然想到可以用dir+*来获取文件路径,不过代码比较多需要简化一下

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "Temp1=C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp"
   
4. set Temp1=%Temp1:\= %
   
5. for %%a in (%Temp1%) do (
   
6.     set name=%%a
   
7.     set name1=!name:~-2,1!
   
8.     set name2=!name:~0,1!
   
9.     cd /d "!flies!"
   
10.     if "!name1!"=="~" (
    
11.         for /f "delims=" %%i in ('dir /b/a "!flies!!name2!*"') do (
    
12.             if "%%~sfi"=="!flies1!!name!" (
    
13.                 set "flies=%%~fi"
    
14.                 set "flies1=%%~sfi"
    
15.             )
    
16.         )
    
17.     ) else (
    
18.         set "flies=!flies!!name!"
    
19.         set "flies1=!flies1!!name!"
    
20.     )
    
21. )
    
22. if not exist "!flies!" set flies=!flies:~0,-1!
    
23. echo.!flies!
    
24. pause
    

复制代码

ttszuo

回复 5# CrLf
.....我的也是xp系统,还是短路径输出