[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[代码合集] [原创BAT]CMD命令帮助信息助手

本帖最后由 pcl_test 于 2016-6-19 20:12 编辑
  1. @echo off&Setlocal enabledelayedexpansion
  2. ::作者 小程936 QQ1781047213
  3. call :vbs
  4. set ch= 1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz
  5. set umu=ASSOC ATTRIB BREAK BCDEDIT CACLS CALL CD CHCP CHKDSK CHKNTFS CHOICE CLS CMD COLOR COMP COMPACT CONVERT COPY DATE DEL DIR DISKPART DISM DOSKEY DRIVERQUERY ECHO ENDLOCAL EXIT FC FIND FINDSTR FOR FORMAT FSUTIL FTYPE GOTO GPRESULT GRAFTABL HELP ICACLS IF LABEL MD MKLINK MODE MORE MOVE NET OPENFILES PATH PAUSE POPD PRINT PROMPT PUSHD RD RECOVER REG REM REN REPLACE ROBOCOPY SET SETLOCAL SC SCHTASKS SHIFT SHUTDOWN SORT START SUBST SYSTEMINFO TASKLIST TASKKILL TIME TITLE TREE TYPE VER VERIFY VOL XCOPY WMIC
  6. set um2=DISKPART DISM NET
  7. REM 针对特殊命令的优化 (ECHO+?&EXIT)|DISKPART   net help
  8. reg query "HKU\S-1-5-19" >nul 2>&1 &&set adm=1||set adm=0
  9. echo A-Z搜索命令 1首选 2末选 5退出 9帮助 0清屏 空格翻页
  10. :so
  11. if DEFINED so (title %so% - soBAT) else title soBAT
  12. CHOICE /C%ch% /N /CS /T 45 /D 0
  13. (set /a er=%ERRORLEVEL%)&if %ERRORLEVEL% GTR 36 call cap.vbs
  14. if %er% LEQ 10 cls&goto num
  15. set so=%so%!ch:~%ER%,1!
  16. set /a n+=1,sn=0
  17. call :soso
  18. goto so
  19. :0
  20. set so=&set n=&title soBAT&goto :eof
  21. :soso
  22. cls
  23. for %%z in (%umu%) do (set zz=%%z&if /I "!so:~,%n%!" == "!zz:~,%n%!" (set szz=%%z&goto sosoc))
  24. :sosoc
  25. for %%z in (%umu%) do (set zz=%%z&if /I "!so:~,%n%!" == "!zz:~,%n%!" (echo %%z&set sz=%%z&set /a sn+=1))
  26. if %sn%==1 call :data %sz%
  27. if %sn%==0 ((call :0)&goto :eof)
  28. if /i %szz%==%so% echo 按1选择%szz%
  29. goto :eof
  30. :小程936
  31. if /I %1 == DISKPART (if %adm%==1 ((ECHO+?&EXIT)|DISKPART) else echo 权限不足,拒绝访问)|more
  32. if /I %1 == DISM (if %adm%==1 (DISM /?) else echo 权限不足,拒绝访问)|more
  33. if /I %1 == NET (%1 HELP)|more
  34. echo+&goto :eof
  35. :data
  36. title %1 - soBAT - 空格键翻页
  37. for %%z in (%um2%) do if /i "%%z" == "%1" ((call :小程936 %1)&(call :0)&(goto :eof))
  38. if EXIST %1.txt (more %1.txt) else ((%1 /?&echo+)|more)
  39. call :0
  40. goto :eof
  41. :vbs
  42. pushd "%~pd0"
  43. md he 2>nul
  44. cd he||(echo 权限不足,无法初始化&pause>nul&exit /b 1)
  45. >cap.vbs echo Set obb = CreateObject^(^"Wscript.Shell^"^)
  46. >>cap.vbs echo obb.SendKeys^"^{CAPSLOCK^}^"
  47. >ti.vbs echo Wscript.Sleep Wscript.Arguments^(0^)
  48. set n=
  49. goto :eof
  50. :num
  51. if %er%==1 call :data %szz%
  52. if %er%==2 call :data %sz%
  53. if %er%==5 exit /b
  54. if %er%==9 echo A-Z搜索命令 1首选 2末选 5退出 9帮助 0清屏 空格翻页
  55. if %er%==10 call :0
  56. goto so
复制代码
介绍:
直接按IF即输出IF的帮助,无需按Enter
直接按P即输出所有以P开头的命令,再按U即输出PUSHD的帮助,无需按Enter
按任意字母输出所有以该字母开头的命令,若只有一条直接显示命令帮助,若没有符合的命令自动清空输入,命令帮助支持换页输出
A-Z搜索命令 1首选 2末选 5退出 9帮助 0清屏 空格翻页
1首选 即 快速选择搜索结果的第一项
2末选 即 快速选择搜索结果的最后一项
采用CHOICE命令检测用户输入,不用set /p,只为少按Enter
优先搜索 自身目录\he\命令.TXT 找不到文件则输出 系统帮助,方便自定义帮助文件
改名为he.cmd并复制到C:\Windows\system32目录,即可在CMD中输入he调用本工具。

菜鸟前来学习了~~

TOP

这样的形式漂亮,缺少了at,其他不知道
目的,学习批处理

TOP

不错,跟字典有的一拼。

TOP

回复 3# hlzj88
C:\Users\batvb>AT
AT 命令已弃用。请改用 schtasks.exe。


不支持该请求。


C:\Users\batvb>


如果你需要添加命令,在第五行的字典加一个即可

TOP

返回列表