[文本处理] [已解决]如何根据一个文本列出的字符串替换关系式对另一个文本相应的字符串进行替换

沸羊羊

各位，我现在遇到个问题，想请教您一下：
我有两个txt文件，分别为a.txt,b.txt,a.txt里边内容格式为
111111,1
111111,2
111,1
而b.txt里面格式如：
aaa,s,aa,111111,ads,asd
aa,a,ad,111,sd,dd
现在我就是想读取a.txt的每一行数据，比如第一行，在b.txt中对应查找有没有111111,有的话，就将111111替换为1，需要注意的是，在b.txt中只有一行111111，但是a.txt中有两行111111，所以需要在b.txt中添加一行数据，并将111111替换为2，请问这个bat怎么写？

沸羊羊

或者我想问下，能否先复制查找到的字符串所在行，再进行替换操作？

沸羊羊

我现在有两个文件，分别是a.txt,b.txt
我想循环读取a.txt的每一行数据，然后在b.txt中，行一一对应的替换字符串(b.txt文件中，已经经过排序，所以是必定与a.txt中的数据一一对应的)
请问，这个bat脚本怎么写？文件格式见附件

GNU

回复 3# 沸羊羊

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1-8 delims=," %%a in ('type "b.txt"') do (
    set /p StrLine=
    for /f "tokens=2 delims=," %%x in ("!StrLine!") do (
        set StrCol=%%x
    )
    echo ,%%a,%%b,!StrCol!,%%d,%%e,%%f,%%g,%%h
))<"a.txt" > "c.txt"
复制代码

沸羊羊

回复 4# GNU


    大神，您的脚本确实实现了我的需求，不过我是新手，能不能麻烦您给我详细解释下各行的意思呢？万分感谢！

沸羊羊

@echo off
rem setlocal enabledelayedexpansion
if exist C:\"Program Files"\"aa bb"\test.txt del /q C:\"Program Files"\"aa bb"\test.txt
if exist C:\"Program Files"\"aa bb"\c.txt del /q C:\"Program Files"\"aa bb"\c.txt
set file=C:\Program Files\aa bb\a.txt
set file2=C:\Program Files\aa bb\20160818_Export_c.txt
set "tmpFile=C:\Program Files\aa bb\c.txt"
set "dirFile=C:\Program Files\aa bb\test.txt"
for /f "tokens=1,2 delims=," %%a in ("%file%") do (
for /f "tokens=*" %%i in ('type "%file2%" ^| findstr %%a') do (
echo %%i>>"%tmpFile%"
)
rem call :G_getrows "C:\Users\fan-17\Desktop\a.txt" kk
)
setlocal enabledelayedexpansion
(for /f "tokens=1-8 delims=," %%a in ('type "%tmpFile%"') do (
    set /p StrLine=
    for /f "tokens=2 delims=," %%x in ("!StrLine!") do (
        set StrCol=%%x
    )
    echo ,%%a,%%b,!StrCol!,%%d,%%e,%%f,%%g,%%h
))<"%file%" > "%dirFile%"

if exist "%tmpFile%" del /q "%tmpFile%"
复制代码

回复 4# GNU


    您好，这是我结合您给的脚本，写的一个批处理，如果文件路径中没有空格，则可以执行，但是如果路径中有空格，就会提示找不到文件，我在网上找资料，说是只要在有空格的路径上加双引号就行，可是我加了之后还是没用，请您指教

GNU

回复 6# 沸羊羊


一个路径加一对双引号就够了。

if exist "C:\Program Files\aa bb\test.txt" del /q "C:\Program Files\aa bb\test.txt"
复制代码

GNU

@echo off
set "file=C:\Program Files\aa bb\a.txt"
set "file2=C:\Program Files\aa bb\20160818_Export_c.txt"
set "tmpFile=C:\Program Files\aa bb\c.txt"
set "dirFile=C:\Program Files\aa bb\test.txt"
if exist "%tmpFile%" del /q "%tmpFile%"
if exist "%dirFile%" del /q "%dirFile%"

for /f "tokens=1,2 delims=," %%a in ("%file%") do (
    for /f "tokens=*" %%i in ('type "%file2%" ^| findstr %%a') do (
        >>"%tmpFile%" echo %%i
    )
    rem call :G_getrows "C:\Users\fan-17\Desktop\a.txt" kk
)

setlocal enabledelayedexpansion
(for /f "tokens=1-8 delims=," %%a in ('type "%tmpFile%"') do (
    set /p StrLine=
    for /f "tokens=2 delims=," %%x in ("!StrLine!") do (
        set StrCol=%%x
    )
    echo ,%%a,%%b,!StrCol!,%%d,%%e,%%f,%%g,%%h
))<"%file%" > "%dirFile%"

if exist "%tmpFile%" del /q "%tmpFile%"
复制代码

如果这个代码还是报错，你可以把 @echo off 删掉，在CMD窗口执行 test.bat 这样可以看到具体是哪里在报错。

沸羊羊

回复 8# GNU


    您好，根据您的脚本，执行后，发现报错，注释掉echo off，查看执行结果，发现 我的临时文件 c.txt 没有生成，这个是怎么回事？

我逐行执行脚本，发现  for /f "tokens=1,2 delims=," %%a in ("%file%") do (
echo %%a

这句话，输出的%%a 是个路径，而不是 文本内容的值，是不是双引号加的不对导致的？

GNU

回复 9# 沸羊羊


那种写法会导致 for 命令认为 "%file%" 是个字符串而不是一个文件
改成这样试试：
for /f "tokens=1,2 delims=," %%a in ('type "%file%"') do (

沸羊羊

回复 10# GNU


    谢谢，长知识，确实好用

沸羊羊

回复 10# GNU

@echo off
rem 号与号的对应文件
set file=C:\Program Files\aa bb\a.txt
rem 文件
set file2=C:\Program Files\aa bb\20160818_Export_c.txt
rem 生成的临时文件，最后会删掉
set tmpFile=C:\Program Files\aa bb\c.txt
rem 生成的新的文件
set dirFile=C:\Program Files\aa bb\test.txt
if exist "%tmpFile%" del /q "%tmpFile%"
if exist "%dirFile%" del /q "%dirFile%"

for /f "tokens=1,2 delims=," %%a in ('type "%file%"') do (
    for /f "tokens=*" %%i in ('type "%file2%" ^| findstr %%a') do (
        >>"%tmpFile%" echo %%i
    )
)
setlocal enabledelayedexpansion

(for /f "tokens=1-8 delims=," %%a in ('type "%tmpFile%"') do (
    set /p StrLine=
    for /f "tokens=2 delims=," %%x in ("!StrLine!") do (
        set StrCol=%%x
    )
    echo ,%%a,%%b,!StrCol!,%%d,%%e,%%f,%%g,%%h
))<"%file%" > "%dirFile%"

if exist "%tmpFile%" del /q "%tmpFile%"
复制代码

请问，如何在 'type "%file2%" ^| findstr %%a' 时，判断有没有查找到字符串呢？没有的话则跳过，有的话，则输出到临时文件中
还有，能不能一行行复制，而不是根据逗号分隔，再输出1-8列，这样就被限制死了。谢谢！

xxpinqz

回复 12# 沸羊羊

没找到本来就不执行写入tmpfile，一行一行的替换需要考虑有两列及其以上的字段相同时，会替换其它的值。

GNU

回复 12# 沸羊羊

判断有没有查找到字符串呢？没有的话则跳过，有的话，则输出到临时文件中

代码14行到16行就是为了实现这个功能

沸羊羊

回复 14# GNU


    我试了下，确实可以，只是执行太慢，以为是卡死在那了，还有最后一个问题，能不能做到一行行的替换，而不是使用tokens=1-8，限定了输出列数？