批处理for嵌套循环中，如何实现满足指定条件后结束/退出当前子循环

ngd

比如a.txt中内容如下
212
541
442
333
我想得到每行最大的一个数字

1. @echo off&setlocal enabledelayedexpansion
   
2. for /f %%a in (a.txt) do (
   
3.     set str=%%a
   
4.     echo !str!
   
5.     for /l %%i in (5,-1,0) do (        
   
6.         if "!str!" NEQ "!str:%%i=!" echo %%i
   
7.     )
   
8. )
   
9. pause

复制代码

运行结果为
212
2
1
541
5
4
1
442
4
2
333
3
而我想要的结果是
212
2
541
5
442
4
333
3
这样的如何实现，重要的是在这样的 for嵌套循环中 如何满足条件后结束当前循环 返回上一级

pcl_test

1. @echo off
   
2. for /f %%a in ('type "a.txt"') do (
   
3.     set str=%%a
   
4.     echo;%%a
   
5.     call :loop %%a
   
6. )
   
7. pause&exit
   
8. :loop
   
9. set num=%~1
   
10. setlocal enabledelayedexpansion
    
11. for /l %%i in (9,-1,0) do (        
    
12.     if "!num!" neq "!num:%%i=!" echo;%%i&goto :eof
    
13. )

复制代码

pcl_test

1. @echo off
   
2. for /f %%a in ('type "a.txt"') do (
   
3.     set str=%%a&set/p=%%a <nul
   
4.     setlocal enabledelayedexpansion
   
5.     for /l %%i in (0,1,10) do (rem 指定数字最大长度为10位数      
   
6.         if not defined max (
   
7.             set max=!str:~%%i,1!
   
8.         ) else if !str:~%%i^,1! geq !max! set max=!str:~%%i,1!
   
9.     )
   
10.     echo;!max!
    
11.     endlocal
    
12. )
    
13. pause
    

复制代码

pcl_test

win7以上系统

1. powershell -c "gc 'a.txt'|%%{$_+' '+($_ -split ''|sort)[-1]}"
   
2. pause

复制代码

WHY

1. @echo off & setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in (a.txt) do (
   
3.     set "s=%%i" & set "max="
   
4.     for /l %%j in (0 1 9) do if "!s:%%j=!" NEQ "!s!" set "max=%%j"
   
5.     echo;!s!&echo;!max!
   
6. )

复制代码

WHY

1. @echo off & setlocal enabledelayedexpansion
   
2. for /f "delims=" %%i in (a.txt) do (
   
3.     set "s=%%i" & set "max="
   
4.     for /l %%j in (9 -1 0) do if "!s:%%j=!" NEQ "!s!" if not defined max set "max=%%j"
   
5.     echo;!s!&echo;!max!
   
6. )

复制代码