[已解决]批处理如何生成超过5位数的指定范围内的随机数

nbtnt

使用random时，
规定最大值为498000，最小值为88000
但是取出的随机数的最大值总在100000左右徘徊。

aa77dd@163.com

1. @echo off & setlocal enableDelayedExpansion
   
2. mode 80,2000
   
3. for /L %%a in (1 1 1000) do (
   
4.     set /a "t=1088000 + (1!random:~-2!!random:~-4!-1000000) %% (498000-88000+1)"
   
5.     echo;!t:~-6!
   
6. )
   
7. 
   
8. pause
   
9. exit /b
   

复制代码

回复 1# nbtnt

pcl_test

random返回的是基于系统时间生成的一个0~32767之间的随机整数
set /a的计算数值范围为-2^31~2^31-1，即-2147483648~2147483647

1. @echo off&setlocal enabledelayedexpansion
   
2. rem 拆分拼接(8,8000)~(8,9999);(9,0000)~(9,9999);……(48,0000)~(48,9999);(49,0000)~(49,8000)
   
3. (for /l %%a in (1 1 1000) do (
   
4.     set /a a=8+!random!%%42&rem 8~49
   
5.     if !a! equ 8 (
   
6.         set /a b=8000+!random!%%2000&rem 8000~9999
   
7.         echo;!a!!b!
   
8.     ) else (
   
9.         if !a! equ 49 (
   
10.             set /a b=10000+!random!%%8001&rem 10000~18000
    
11.         ) else (
    
12.             set /a b=10000+!random!%%10000&rem 10000~19999
    
13.         )
    
14.         echo;!a!!b:~1!
    
15.     )
    
16. ))>result.txt
    
17. pause

复制代码

pcl_test

1. @echo off
   
2. set min=88000
   
3. set max=498000
   
4. for /f "delims=" %%a in ('mshta "javascript:(new ActiveXObject('Scripting.Filesystemobject')).GetStandardStream(1).Write(Math.floor(Math.random()*(%max%-%min%+1)+%min%));close()"') do echo;%%a
   
5. pause

复制代码

1. rem win7及以上系统运行
   
2. powershell -c "get-random -min 88000 -max 498001"
   
3. pause

复制代码

happy886rr

1. 
   
2. @echo off&setlocal enabledelayedexpansion
   
3. REM 设置随机数位数
   
4. set BITS=9
   
5. for /l %%i in (1,1,200) do (
   
6.         set "s=$"
   
7.         for /l %%i in (1,1,!BITS!) do (
   
8.                 set/a "r=!random!%%10"&set "s=!s!!r!"
   
9.         )
   
10.         set/p=!s!, <NUL
    
11.         set/a "n=%%i%%5"
    
12.         if !n! equ 0 (echo;)
    
13. )
    
14. pause
    

复制代码