taofan712

请展示下ini文件中的部分内容

ygqiang

@echo off
setlocal enabledelayedexpansion
del /q newconnection.ini
echo;输入新ip，按回车 &set /p "rip="
for /f "tokens=1* delims==" %%a in ('findstr "svrIP=" connection.ini' ) do set tip=%%b
for /f "tokens=1* delims=:" %%i in ('findstr /n .* connection.ini') do (
	set str=%%j
	if "!str!"=="" (
		echo;
	) else (
		echo;!str:%tip%=%rip%!
	)
)>>newconnection.ini
复制代码

lamcelot

回复 16# taofan712
顶楼已更新给出

taofan712

回复 18# lamcelot

18楼代码第五行处，可以考虑把行号一起获取，在替换的时候对比行号。就像userx那问题，其实我是对比着行号在处理，你可以参考下。

Nsqs

@echo off
set "fileName=config.ini"
for /f "tokens=1 delims=:" %%1 in ('findstr /n "^::VBS$" "%0"')do set n=%%1
more "%0" +%n%>@
type %filename%|cscript -nologo -e:"vbs" "@">%filename% %读取文件config%
pause
::以下是你自定义代码部分


::此行以下不要修改
goto :eof
::VBS
set fso=createobject("scripting.filesystemobject")
set regexp=new regexp
s="999" '替换为999
with regexp
	.multiline=-1:.global=-1
	.pattern="^(address=).*" '需要匹配修改的部分
	wsh.echo .replace(wsh.stdin.readall,"$1"&s)
end with
fso.deletefile wsh.scriptfullname
复制代码

taofan712

@echo off
set /p rip=输入替换IP（如10.10.10.10）
findstr /n .* connection.ini>temp.ini
for /f "tokens=1* delims=:" %%a in ('findstr /b /n svrIP= connection.ini') do (
	set /a tn=%%a
	for /f "tokens=2 delims==" %%c in ("%%b") do set tip=%%c
) 
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in (temp.ini) do (
	set /a ln=%%i
	set line=%%j
	if !ln! equ !tn! (
	echo;!line:%tip%=%rip%!
	) else (
	echo;!line!
	)
)>>newconnection.ini
del /f /q temp.ini
复制代码

GNU

回复 21# taofan712


1、获取IP和获取IP所在的行号，两个操作可以合并在同一个for命令里面完成。
2. temp.ini这个临时文件是多余的，直接在后面那个for里面用命令替换就行了。
3、最后那个for命令里面ln这个变量是多余的。

@echo off
set /p rip=输入替换IP（如10.10.10.10）
for /f "tokens=1,3 delims=:=" %%a in ('findstr /b /n "AppServer=" 1.ini') do (
    set tn=%%a
    set tip=%%b
)
setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%i in ('findstr /n .* 1.ini') do (
    set "line=%%j"
    if %%i equ !tn! (
        echo;!line:%tip%=%rip%!
    ) else (
        echo;!line!
    )
))>2.ini
复制代码

WHY

@echo off
set /p Input=输入：
for /f "delims=" %%i in ('findstr /n .* 1.ini') do (
        set "s=%%i"
        setlocal enabledelayedexpansion
        set "s=!s:*:=!"
        if /i "!s:~0,10!" == "AppServer=" (
                echo;AppServer=%Input%
        ) else (
                echo;!s!
        )
        endlocal
)
pause
复制代码

@if (0)==(0) echo off
set /p Input=输入：
cscript //nologo //e:jscript "%~f0" < 1.ini "%Input%"
pause & goto :EOF
@end

var s = WSH.StdIn.ReadAll().replace(/^(AppServer=)[^\r\n]*/gmi,'$1' + WSH.Arguments(0));
WSH.Echo(s)
复制代码

set "Input=1.1.1.1"
gawk "BEGIN{IGNORECASE=1};{sub(/^AppServer=.*/,\"AppServer=%Input%\",$0);print}" 1.ini
复制代码

set "Input=1.1.1.1"
sed -r "s/^(AppServer=).*/\1%Input%/" 1.ini
复制代码

set "Input=1.1.1.1"
PowerShell -c "(type 1.ini) -replace '(?<=^AppServer=).*', '%Input%'"
复制代码