[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[游戏娱乐] 人机对战五子棋批处理游戏

在网上看到多个关于五子棋的批处理游戏,已经可以做到,人与人对战,并判断胜负。但是大多数人认为批处理的效率有问题,都不敢做人与机对战的尝试。批处理的效率真的有那么低吗?出于对dos的热爱,我就不相信批处理真的就做不到真正的五字棋人机对战!于是,这个问题花了我二天的时间,功夫不负有心人,批处理人机对战游戏出来了! 此批处理的棋盘延用了batman的显示方案,但是在输出算法上有所不同。虽然,这个话题已经有很多人写了很多代码,但是,此批处理的算法关键部分由本人自己写出来,所以打上了原创,若有不妥,请大家指正改过。谢谢。(初版3.85K,已多次更新增强)

注:
一楼保持了第一版,是能实现的基本原理,不想改了。

以下为更新记录:
5.6 根据一些网友的意见,做了一点改进:
把棋盘搞大一点了,增加了悔棋功能,增加了音效,
把系统提示放到了更合理的地方,
并增加了一点电脑方的棋艺,(还是不够完善,没有做到多方考虑)

5.7 修改:增加了电脑方最后一手特别显示

5.10修改:固定为黑子先手,第一手固定下在天元 JJ10 位置增加了几行代码,却提速不少,

5.14 修改:提速100%(最主要是原来代码中的一个BUG改正)
以上修改在7楼)

5.17 修改(在20楼):电脑智能升级了,但速度却慢了,

5.21 更新(原在23楼):完善了电脑智能,并在有多个等效下法时进行随机取位,增加了可玩性,速度也不错。

5.25 增加了背景音乐《春江花月夜》,如高山流水般的声音,听着下五棋子,太爽了
6.2 小更新 (在23楼) 小更新:增强了一点点电脑棋艺。
      ***看到网上有人贴出,玩家先下时,九手就赢了电脑,特此改进。 ***
6.14 增加了可以用鼠标操作,但是用到了一个鼠标支持的三方工具,(请看32楼)

2009.8.14修改
修正一些bug,并更新三方鼠标工具,并组合了背景音乐。

2009.10.2 更新
修正了,存放路径中含有空格时出错的问题

请看一楼附件
  1. @echo off&setlocal enabledelayedexpansion
  2. set li0=┌───────────────────┐
  3. set li1=│┌┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┐│1
  4. for /l %%a in (2,1,18) do (set li%%a=│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│%%a)
  5. set li19=│└┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┘│19
  6. set li20=└───────────────────┘
  7. set li21=   A B C D E F G H I J K L M N O P Q R S
  8. for %%a in (%li21%) do (set/a .+=1,%%a=.&set z!.!=%%a)
  9. set z0= &set z20= &set "z21= "
  10. set li5=!li5!   五 棋 子 人 机 对 战
  11. set li7=!li7!        批 处 理
  12. set li9=!li9!   电 脑 水 平 中 等
  13. set li12=!li12!  由 netbenton 编写完成
  14. set li14=!li14!  棋盘设计参照了 batman
  15. title   批处理五子棋
  16. set str=###################
  17. set .=0
  18. for /l %%a in (1,1,19) do (
  19. set he%%a=!str!&set sh%%a=!str!
  20. for /l %%b in (1,1,19) do set [%%a.%%b=0
  21. )
  22. set .=33
  23. for /l %%a in (5,1,19) do (
  24. set pi%%a=!str:~,%%a!&set ni%%a=!str:~,%%a!
  25. set pi!.!=!str:~,%%a!&set ni!.!=!str:~,%%a!
  26. set/a .-=1
  27. )
  28. set ●=○&set a●=电脑
  29. set ○=●&set a○=玩家
  30. ::设置电脑IQ
  31. set idea=@@@@#1 #@@@@5 @#@@@4 @@@#@2 @@#@@3 $#$$$4 $$#$$3 $$$#$2 $$$$#1 #$$$$5 #$$#$#3 #$#$$#4 #@@@##2 ##@@@#5 #@@#@#3 #@#@@#4 #@@@#1
  32. set idea=!idea! ##@@@4 @@@##2 ##$$$#5 #$$$##2 #$$$#1 ##@@#4 #@@##2 ##$$#4 #$$##2 #$#$#3 @@###3 ###@@3
  33. set idea=!idea! ##@##2 ###@#3 #@###3 @####4 ####@2 ##############7 ###########6 ########4 #####3 ####2
  34. set ttr=!idea:@=●!&set ttr=!ttr:$=○!
  35. for %%a in (!ttr!) do (set var=%%a&set !var:~,-1!=!var:~-1!&set idea=!idea! !var:~,-1!)
  36. set ttr=
  37. ::设置电脑IQ
  38. :restart
  39. for /l %%a in (0,1,21) do (echo    !z%%a!!li%%a!)
  40. setlocal enabledelayedexpansion
  41. set li21=!li21!      reboot重新开始,exit退出。
  42. set /p var=选择谁先下[ W,玩家  D,电脑  Q,退出 ]:
  43. if /i "!var!" equ "Q" goto :eof
  44. if /i "!var!" equ "W" (set zhi=●) else (set zhi=○)
  45. echo.
  46. :loop
  47. if %zhi% equ ● goto :men
  48. set .=&set put1=
  49. for %%a in (!idea!) do (
  50. for %%b in (he sh) do (
  51.   for /l %%c in (1,1,19) do (
  52.    if "!%%b%%c:%%a=!" neq "!%%b%%c!" set/a .+=1&set put!.!=%%b %%c
  53. ) )
  54. for %%b in (pi ni) do (
  55.   for /l %%c in (5,1,33) do (
  56.    if "!%%b%%c:%%a=!" neq "!%%b%%c!" set/a .+=1&set put!.!=%%b %%c
  57. ) )
  58. if defined put1 set put=%%a&goto :get
  59. )
  60. echo. 已经和棋了
  61. pause
  62. goto :restart
  63. :men
  64. for /l %%a in (0,1,21) do (echo    !z%%a!!li%%a!)
  65. set /p user=[列前,行后]:
  66. echo.
  67. if "!user!" equ "reboot" endlocal&goto :restart
  68. if "!user!" equ "exit" exit
  69. set/a pos=!user:~0,1!,poh=!user:~1,2!,var=pos-1 2>nul
  70. if not defined [!poh!.!pos! echo 输入点不存在&goto :men
  71. if "!he%poh%:~%var%,1!" neq "#" echo 该点已经有子&goto men
  72. goto :getok
  73. :get
  74. set /a .=!random!%%.+1
  75. set put=!put%.%! !put!
  76. ::随机取最佳的走法
  77. for /f "tokens=1-3" %%a in ("%put%") do (
  78. set var=!%%a%%b:*%%c=!srqponmlkjihgfedcba0
  79. set/a var=!var:~19,1!+%%c
  80. if "%%a" equ "he" (set/a poh=%%b,pos=20-var)
  81. if "%%a" equ "sh" (set/a poh=20-var,pos=%%b)
  82. if %%b lss 19 (set/a var=%%b-var+1) else (set/a var=38-%%b-var+1)
  83. if "%%a" equ "pi" (if %%b lss 19 (set/a pos=var,poh=%%b-var+1) else (set/a poh=20-var,pos=%%b-19+var))
  84. if "%%a" equ "ni" (if %%b lss 19 (set/a pos=var,poh=19-%%b+var) else (set/a poh=var,pos=%%b-19+var))
  85. )
  86. echo  电脑最后下在:!z%pos%!!z%poh%!(%poh%)
  87. :getok
  88. set zhi=!%zhi%!&set win=!zhi!!zhi!!zhi!!zhi!!zhi!
  89. set/a piph=poh+pos-1,lips=pos+1,niph=19+pos-poh
  90. if !piph! lss 19 (set/a pips=pos) else (set/a pips=20-poh)
  91. if !niph! lss 19 (set/a nips=pos) else (set/a nips=poh)
  92. for %%a in ("li!poh! !lips!" "he!poh! !pos!" "sh!pos! !poh!" "pi!piph! !pips!" "ni!niph! !nips!") do (
  93. for /f "tokens=1,2" %%b in (%%a) do (
  94.   if defined %%b (
  95.    set/a .=%%c-1
  96.    for %%d in (!.!) do (set %%b=!%%b:~0,%%d!%zhi%!%%b:~%%c!)
  97.   if "!%%b:%win%=!" neq "!%%b!" set win=y
  98.   )
  99. )
  100. )
  101. set/a asc%zhi%+=1
  102. if !win! neq y goto :loop
  103. for /l %%a in (0,1,21) do (echo    !z%%a!!li%%a!)
  104. set/p=   !a%zhi%! %zhi%子 第!asc%zhi%!手  胜出     <nul
  105. pause
  106. endlocal&goto :restart
复制代码
附件: 您需要登录才可以下载或查看附件。没有帐号?注册
6

评分人数

    • 基拉freedom: 支持!技术 + 1 PB + 5
    • Seter: 大大加油啊!PB + 10
    • 523066680: 这将改变一些人对批处理的观点。PB + 30 技术 + 1
    • 随风: 智能和效率都很不错啊!PB + 20 技术 + 1
    • yslyxqysl: 加入技术组吧技术 + 1

占位,发红包,发红包^_%

[ 本帖最后由 wjjy 于 2009-5-6 02:52 编辑 ]
1

评分人数

TOP

厉害,这个五子棋p的iq 很棒。

TOP

set idea 这个思路相当精彩!相当!
批处理之家论坛官方 QQ 群 :【当前人数/人数上限】【2009-07-08】
群①:43011867(181/200);群②:(暂缺数据);群③:66165582(120/200)。

TOP

       A B C D E F G H I J K L M N O P Q R S      reboot重新开始,exit退出。
   玩家 ○子 第10手  胜出     请按任意键继续. . .
    ┌───────────────────┐
   A│┌┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┐│1
   B│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│2
   C│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│3
   D│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│4
   E│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│5   五 棋 子 人 机 对 战
   F│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│6
   G│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│7        批 处 理
   H│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│8
   I│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│9   电 脑 水 平 中 等
   J│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│10
   K│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│11
   L│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│12  由 netbenton 编写完成
   M│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│13
   N│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│14  棋盘设计参照了 batman
   O│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│15
   P│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│16
   Q│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│17
   R│├┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼┤│18
   S│└┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┴┘│19
    └───────────────────┘
       A B C D E F G H I J K L M N O P Q R S
选择谁先下[ W,玩家  D,电脑  Q,退出 ]:
少了cls不好看。
还有,电脑的智商还是不高,能不能像Flash那样把我下赢?

[ 本帖最后由 yslyxqysl 于 2009-5-6 16:55 编辑 ]

TOP

实在静不下心来研究楼主的算法,
测试了下,智能很不错,效率也很不错,佩服!
技术问题请到论坛发帖求助!

TOP

  1. @echo off&setlocal enabledelayedexpansion
  2. mode con: lines=43 cols=110
  3. set li39=    A  B  C  D  E  F  G  H  I  J  K  L  M  N  O  P  Q  R  S
  4. set  li0=  ┌─────────────────────────────────────┐
  5. set  li1=A│┌─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┬─┐│A
  6. set var=1
  7. for %%a in (!li39:~5^,-1!) do (set/a var+=2&set li!var!=%%a│├─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┼─┤│%%a)
  8. for /l %%a in (2,2,36) do (set li%%a=  ││  │  │  │  │  │  │  │  │  │  │  │  │  │  │  │  │  │  ││)
  9. set li37=S│└─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┴─┘│S
  10. set li38=  └─────────────────────────────────────┘
  11. set str=a b c d e f g h i j k l m n o p q r s
  12. for %%a in (%str%) do (set/a .+=1,%%a=.&set z!.!=%%a)
  13. set li5=!li5!   五 棋 子 人 机 对 战
  14. set li7=!li7!        批 处 理
  15. set li10=!li10!      电 脑 水 平 中 等
  16. set li31=!li31!  由 netbenton 编写完成
  17. set li33=!li33!  棋盘设计参照了 batman
  18. title   批处理五子棋
  19. set str=###################
  20. set .=0
  21. for /l %%a in (1,1,19) do (
  22. set he%%a=!str!&set sh%%a=!str!
  23. for /l %%b in (1,1,19) do set [%%a.%%b=0
  24. )
  25. set .=33
  26. for /l %%a in (5,1,19) do (
  27. set pi%%a=!str:~,%%a!&set ni%%a=!str:~,%%a!
  28. set pi!.!=!str:~,%%a!&set ni!.!=!str:~,%%a!
  29. set/a .-=1
  30. )
  31. set ●=○&set ○=●
  32. set zhi=●
  33. set say=say
  34. ::设置电脑IQ
  35. set idea=@@@@#1 #@@@@5 @#@@@4 @@@#@2 @@#@@3 $$$$#1 #$$$$5 $$#$$3 $#$$$4 $$$#$2 #@@@##2 ##@@@#5 #@@#@#3 #@#@@#4 #@#@@3 @#@@#4 #@@@#1
  36. set idea=!idea! ##@@@4 @@@##2 @##@@#4 #@##@@3 #@#@#@4 @#@#@#3 #$$#$#3 #$#$$#4 ##$$$#5 #$$$##2 #$$$#1 ##@@#4 #@@##2 #@#@#3 ##$$#4 #$$##2 #$#$#3 #$##$#3
  37. set idea=!idea! @@###3 ###@@3 ##@##2 ###@#3 #@###3 @####4 ####@2 ##$##2 #####3
  38. set idea=!idea! #$###3 $####3 ##$##2 ###$#3 ####$3 $$###3 ###$$3 $#$##2 ##$#$4 #$##$3 $##$#3 $###$3 $$$##2 #$$#$2 $$##$2 $#$$#4 $##$$3 ##$$$4
  39. :restart
  40. (
  41. setlocal enabledelayedexpansion
  42. for /l %%a in (0,1,39) do (echo    !li%%a!)
  43. set li39=!li39!   reboot重新开始,exit退出。
  44. set li37=!li37!       back 悔棋
  45. set /p var=选择谁先下[ W,玩家  D,电脑  Q,退出 ]:
  46. if /i "!var!" equ "Q" goto :eof
  47. if /i "!var!" equ "D" (set onez=○&set towz=●&set hou=☆) else (set onez=●&set towz=○&set hou=★)
  48. set a!onez!=电脑&set a!towz!=玩家
  49. )
  50. (
  51. set ttr=!idea:@=%onez%!&set ttr=!ttr:$=%towz%!
  52. set idea=
  53. for %%a in (!ttr!) do (set var=%%a&set !var:~,-1!=!var:~-1!&set idea=!idea! !var:~,-1!)
  54. set ttr=
  55. set li27=!li27!    !onez! !a%onez%!
  56. set li25=!li25!    !towz! !a%towz%!
  57. set/a pos=10,poh=10&goto :getok
  58. )
  59. :loop
  60. (if %zhi% equ %onez% goto :men
  61. set .=
  62. for %%a in (!idea!) do (
  63. for %%b in (he sh) do (
  64.   set all=!%%b1!!%%b2!!%%b3!!%%b4!!%%b5!!%%b6!!%%b7!!%%b8!!%%b9!!%%b10!!%%b11!!%%b12!!%%b13!!%%b14!!%%b15!!%%b16!!%%b17!!%%b18!!%%b19!
  65.   if "!all:%%a=!" neq "!all!" (
  66.    for /l %%c in (1,1,19) do (
  67.     if "!%%b%%c:%%a=!" neq "!%%b%%c!" set/a .+=1&set put!.!=%%b %%c
  68.    )
  69. ) )
  70. for %%b in (pi ni) do (
  71.   set all=!%%b5!!%%b6!!%%b7!!%%b8!!%%b9!!%%b10!!%%b11!!%%b12!!%%b13!!%%b14!!%%b15!!%%b16!!%%b17!!%%b18!!%%b19!!%%b20!!%%b21!!%%b22!!%%b23!!%%b24!!%%b25!!%%b26!!%%b27!!%%b28!!%%b29!!%%b30!!%%b31!!%%b32!!%%b33!
  72.   if "!all:%%a=!" neq "!all!" (
  73.    for /l %%c in (5,1,33) do (
  74.     if "!%%b%%c:%%a=!" neq "!%%b%%c!" set/a .+=1&set put!.!=%%b %%c
  75.    )
  76. ) )
  77. if defined . set put=%%a&goto :get
  78. ))
  79. echo. 已经和棋了
  80. pause
  81. endlocal&goto :restart
  82. :men
  83. (
  84. set/a .=lips-1&for /f "tokens=1-3" %%b in ("li!liph! !lips! !.!") do (set %%b=!%%b:~0,%%d!%hou%!%%b:~%%c!)
  85. set li38=!li38![%悔:~,24%]
  86. cls
  87. for /l %%a in (0,1,39) do (echo    !li%%a!)
  88. for /f "tokens=1-3" %%b in ("li!liph! !lips! !.!") do (set %%b=!%%b:~0,%%d!%zhi%!%%b:~%%c!)
  89. set li38=%li38%
  90. set /p user=!say:say=%error%! [列前,行后]:
  91. if "!user!" equ "reboot" endlocal&goto :restart
  92. if "!user!" equ "exit" exit
  93. if "!user!" equ "back" call :悔&goto :men
  94. set/a pos=!user:~0,1!,poh=!user:~1,2!,var=pos-1 2>nul
  95. if not defined [!poh!.!pos! set error=输入点不存在&goto :men
  96. )
  97. if "!he%poh%:~%var%,1!" neq "#" set error=该点已经有子&goto men
  98. goto :getok
  99. :get
  100. set /a .=!random!%%.+1
  101. set put=!put%.%! !put!
  102. ::随机取最佳的走法
  103. for /f "tokens=1-3" %%a in ("%put%") do (
  104. set var=!%%a%%b:*%%c=!srqponmlkjihgfedcba0
  105. set/a var=!var:~19,1!+%%c
  106. if "%%a" equ "he" (set/a poh=%%b,pos=20-var)
  107. if "%%a" equ "sh" (set/a poh=20-var,pos=%%b)
  108. if %%b lss 19 (set/a var=%%b-var+1) else (set/a var=38-%%b-var+1)
  109. if "%%a" equ "pi" (if %%b lss 19 (set/a pos=var,poh=%%b-var+1) else (set/a poh=20-var,pos=%%b-19+var))
  110. if "%%a" equ "ni" (if %%b lss 19 (set/a pos=var,poh=19-%%b+var) else (set/a poh=var,pos=%%b-19+var))
  111. )
  112. set say=say !z%pos%!!z%poh%!(%poh%)&set error=电脑最后下在:
  113. :getok
  114. set zhi=!%zhi%!&set win=!zhi!!zhi!!zhi!!zhi!!zhi!
  115. (set/a piph=poh+pos-1,lips=pos*2+1,niph=19+pos-poh,liph=poh*2-1
  116. if !piph! lss 19 (set/a pips=pos) else (set/a pips=20-poh)
  117. if !niph! lss 19 (set/a nips=pos) else (set/a nips=poh)
  118. for %%a in ("li!liph! !lips!" "he!poh! !pos!" "sh!pos! !poh!" "pi!piph! !pips!" "ni!niph! !nips!") do (
  119. for /f "tokens=1,2" %%b in (%%a) do (
  120.   set/a .=%%c-1
  121.   for %%d in (!.!) do (set %%b=!%%b:~0,%%d!%zhi%!%%b:~%%c!)
  122.   if "!%%b:%win%=!" neq "!%%b!" set win=y
  123. )
  124. ))
  125. (set/a asc%zhi%+=1
  126. set 悔= !z%pos%!!z%poh%!!悔!
  127. if !win! neq y goto :loop)
  128. for /l %%a in (0,1,39) do (echo    !li%%a!)
  129. set/p=   !a%zhi%! %zhi%子 第!asc%zhi%!手 !z%pos%!!z%poh%!(%poh%)  胜出     <nul
  130. pause
  131. endlocal&goto :restart
  132. :悔
  133. if not defined 悔 goto :eof
  134. if "!悔:~6,1!" equ "" goto :eof
  135. for %%a in (!悔:~^,6!) do (set str=%%a
  136. set/a poh=!str:~-1!,pos=!str:~,1!
  137. set/a piph=poh+pos-1,niph=19+pos-poh,liph=poh*2-1,lips=pos*2+1
  138. if !piph! lss 19 (set/a pips=pos) else (set/a pips=20-poh)
  139. if !niph! lss 19 (set/a nips=pos) else (set/a nips=poh)
  140. for %%a in ( "he!poh! !pos!" "sh!pos! !poh!" "pi!piph! !pips!" "ni!niph! !nips!") do (
  141. for /f "tokens=1,2" %%b in (%%a) do (
  142.    set/a .=%%c-1
  143.    for %%d in (!.!) do (set %%b=!%%b:~0,%%d!#!%%b:~%%c!)
  144. )
  145. )
  146. for /f "tokens=1,2" %%b in ("li!liph! !lips!") do (
  147. set/a .=%%c-1
  148. for %%d in (!.!) do (set %%b=!%%b:~0,%%d!┼!%%b:~%%c!)
  149. ))
  150. set/a asc%zhi%-=1
  151. set 悔=!悔:~6!
  152. set error=你悔棋,耍赖皮!
  153. if not defined 悔 goto :eof
  154. set/a poh=!悔:~2,1!,pos=!悔:~1,1!,liph=poh*2-1,lips=pos*2+1
  155. set say=say !z%pos%!!z%poh%!(%poh%)
  156. goto :eof
复制代码

[ 本帖最后由 netbenton 于 2009-5-19 12:55 编辑 ]

TOP

在顶楼更新一下就好了

TOP

^G音效太恐怖了。。。

TOP

re 楼上

我只能做到这样了。


另外,在7楼做了一点修改:增加了最后一步特别显示,这样更容易看清电脑下在哪里了。

TOP

在没有禁手的前提下,如果电脑先手,可以采用花月、浦月等必胜开局来赢棋。
楼主能否研究一下这些开局并把它们放到你这个批处理中以增加电脑的棋力?
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

zh159兄把它转换成HTA了,界面挺漂亮^_^

  1. <html>
  2. <title>五子棋界面 - zh159</title>
  3. <hrad>
  4. <HTA:APPLICATION
  5. ID="MyhyliApp"
  6. APPLICATIONNAME="五子棋界面 - zh159"
  7. BORDER="thin"
  8. BORDERSTYLE=""
  9. VERSION="1.0"
  10. SCROLL="no"
  11. ICON="C:\WINDOWS\System32\wuauclt.exe"
  12. INNERBORDER="no"
  13. CONTEXTMENU="no"
  14. CAPTION="yes"
  15. MAXIMIZEBUTTON="no"
  16. MINIMIZEBUTTON="yes"
  17. SHOWINTASKBAR="yes"
  18. SINGLEINSTANCE="yes"
  19. SYSMENU="yes"
  20. WINDOWSTATE="normal"
  21. NAVIGABLE="yes"
  22. />
  23. </hrad>
  24. <script language="javascript"></script>
  25. <script language="VBScript"></script>
  26. <style>
  27. .GUIwh {width:24;height:24;cursor:hand;}
  28. </style>
  29. <body background="bg.gif" scroll="no" style="background: SteelBlue ;color:#ffffff;">
  30. <table align="center" width="630" border="1" cellspacing="0" cellpadding="10" borderColor="#ffffff" style="font: 13px 宋体;border-collapse:collapse;">
  31.   <tr align="center">
  32.     <td width="450" height="450">
  33.       <table border="0" cellspacing="0" cellpadding="0" borderColor="#ffffff" style="font: 21px 宋体;border:2px solid #ffffff;">
  34.         <script language="VBScript">
  35.         str = "ABCDEFGHIJKLMNOPQRS"
  36.         For i = 1 To Len(str)
  37.                 with document
  38.                 .write "<tr align='center'>"
  39.                 For n = 1 To Len(str)
  40.                         stri = MID(str,i,1)
  41.                         strn = MID(str,n,1)
  42.                         tdstr = "<td id='GUI_" & strn & stri & "' class='GUIwh'><span onclick='Test(this)' onMouseOver='innerText=""●"";style.color=""blue""' onMouseOut='innerText=""┼"";style.color=""""'>┼</span></td>"
  43.                         s = "┼"
  44.                         If (stri = "A" and strn = "A") Then .write Replace(tdstr,s,"┌")
  45.                         If stri = "A" Then If not (strn = "A" or strn = "S") Then .write Replace(tdstr,s,"┬")
  46.                         If (stri = "A" and strn = "S") Then .write Replace(tdstr,s,"┐")
  47.                         If not (stri = "A" or stri = "S") Then If strn = "A" Then .write Replace(tdstr,s,"├")
  48.                         If not (stri = "A" or stri = "S" or strn = "A" or strn = "S") Then .write tdstr
  49.                         If not (stri = "A" or stri = "S") Then If strn = "S" Then .write Replace(tdstr,s,"┤")
  50.                         
  51.                         If (stri = "S" and strn = "A") Then .write Replace(tdstr,s,"└")
  52.                         If stri = "S" Then If not (strn = "A" or strn = "S") Then .write Replace(tdstr,s,"┴")
  53.                         If (stri = "S" and strn = "S") Then .write Replace(tdstr,s,"┘")
  54.                 Next
  55.                 .write "</tr>"
  56.                 end with
  57.         Next
  58.         </script>
  59.       </table>
  60.     </td>
  61.     <td>
  62.       <span id="PC"><button>电脑先下</button>
  63. 直接点击为玩家先下</span>
  64.     </td>
  65.   </tr>
  66. </table>
  67. </body>
  68. <script language="VBScript">
  69.   width = 660
  70.   height = 550
  71.   window.resizeTo width, height
  72.   ileft=(window.screen.width-width)/2
  73.   itop=(window.screen.height-height)/2
  74.   window.moveTo ileft,itop
  75.         Sub Test(this)
  76. this.parentNode.style.cursor = "default"
  77. this.parentNode.innerHtml = "●"
  78. PC.style.display = "none"
  79.         End Sub
  80.         Sub Title
  81. Document.title = "五子棋 - zh159 - " & FormatDateTime(Now, 1) & "  " & WeekdayName(WeekDay(now)) & "  " & FormatDateTime(Now, 3)
  82.         End Sub
  83. Title:setInterval "Title()",500
  84. </script>
  85. </html>
复制代码
原文地址:http://www.cn-dos.net/forum/viewthread.php?tid=47326

[ 本帖最后由 Batcher 于 2009-5-10 01:39 编辑 ]
附件: 您需要登录才可以下载或查看附件。没有帐号?注册
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

五子棋开局是有限制的哦
还有禁手规则也没添进去(不过难度比较大)

TOP

回复 13楼 的帖子

花月、浦月等开局正是在没有禁手的前提下才能必胜的,因此不是开局有限制,归根结底还是禁手的限制。
既然现在还没有添加禁手,为何不让电脑用必胜开局呢?将来添加了禁手,电脑自然就不会选择这些开局了。
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

我的电脑是怎么了,为何保存12楼的代码运行后是乱码?
技术问题请到论坛发帖求助!

TOP

返回列表