批量将所有子文件夹的文件重命名为序号，并在序号前加上文件所在目录的文件夹名称

a6236130 · 发表于 2018-9-22 09:57:14

批量将所有子文件夹的文件重命名为序号，并在序号前加上文件所在目录的文件夹名称
下列代码有个问题；如果有的文件夹里第一个文件是从001开始的话运行该批处理后就会变成从002开始（原数据中有的文件是001开始、有的不是001开始），
求大神们帮忙修改一下。

@echo off
cd /d %~dp0
for /d %%a in (*) do (
pushd "%%~a"
for /r /d %%b in (*) do (
pushd "%%~b"
set Num=1000
for %%c in (*.jpg,*.tif) do (
set /a Num+=1
call ren "%%~c" "%%~nxb-%%Num:~1%%%%~xc"
)
popd
)
popd
)
pause

复制代码

WHY · 发表于 2018-9-22 12:53:17

假设文件夹名为：xyz
xyz 文件夹中包含文件：
a.jpg
b.jpg
xyz-001.jpg

a.jpg 重命名为 xyz-001.jpg 时遇到同名文件，重命名失败；
b.jpg 重命名为 xyz-002.jpg
xyz-001.jpg 重命名为 xyz-003.jpg

重命名结果：a.jpg，xyz-002.jpg，xyz-003.jpg

WHY · 发表于 2018-9-22 12:57:31

本帖最后由 WHY 于 2018-9-22 12:58 编辑

dir E:\Test\ -Include *.jpg, *.tif -Recurse | ?{$_.Name -like ($_.Directory.Name + '*')} | ren -NewName {$_.Name + '_'};
dir E:\Test\ -Include *.jpg, *.tif, *.jpg_, *.tif_ -Recurse | group DirectoryName | ForEach{
$fd = $_.Name -replace '.*\\';
$n = 1000;
$_.Group | ForEach{ ren $_ -NewName ($fd + '-' + ('' + ++$n).SubString(1) + ($_.Extension -replace '_$')); }
}

复制代码

zaqmlp · 发表于 2018-9-22 14:19:37

最简单的就是改一下代码中的文件夹名和数字文件名的连接符

@echo off
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /ad/b/s') do (
pushd "%%a"
for /f "delims=" %%b in ('dir /a-d/b "%%~nxa-*.jpg" "%%~nxa-*.tif" 2^>nul') do ren "%%b" "$#%%b"
set n=10000
for /f "delims=" %%b in ('dir /a-d/b *.jpg *.tif') do (
set /a n+=1
call ren "%%b" "%%~nxa-%%n:~-3%%%%~xb"
)
popd
)
pause

复制代码

a6236130 · 发表于 2018-9-22 20:09:33

回复 4# zaqmlp

:handshake 非常感谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批量将所有子文件夹的文件重命名为序号，并在序号前加上文件所在目录的文件夹名称