[文件操作] 有偿求助 如何利用批处理进行单线多宽带账号自动拨号及下载？

lzc8191

现有较多宽带账号需要进行上线，且该账号需要产生一定的流量，如何进行批量处理，请高手指点，万分感谢！

flashercs

这是要PPPoE一线多拨吗?

yhcfsr

和这位仁兄调试了几天,大概是弄好了,然后人也不见了.这里分享下代码,仅供参考
原理说明:用Rasdial命令进行拨号管理,WGET命令下载指定文件产生流量.调试过程中,用PING命令楼主反映没有产生流量.

@echo off&setlocal enabledelayedexpansion

::设置账号与密码文件路径
set "account=1.txt"

::设置拨号连接名称
set "name=宽带连接"

::设置下载文件链接
set "url=http://bcn.bathome.net/tool/ffmpeg,4.0/ffmpeg.exe"

for /f "tokens=1,2 delims=	" %%a in ('type "%account%"') do (
	rem 断开连接
	Rasdial "%name%" /disconnect
	rem 重新连接
    Rasdial "%name%" "%%a" "%%b"
    if !errorlevel! equ 0 (
		wget -q -O "./file.tmp" "%url%"
		if not exist "./file.tmp" (echo;拨号成功,无法上网:%%a>>error.log) else (del /f /q "./file.tmp")
    ) else (echo;拨号失败:%%a)>>error.log
)
pause
复制代码

以下是先前内容,对比参考
我提供一个原理性的脚本,具体效果我没有条件测试.
1.先将账号与密码写进一个TXT文件,每行第一列是账号,第二列是密码,第一列与第二列之间用TAB键分开.
2.在脚本中设置第一步生成的账号文件路径与拨号连接名称.运行脚本.

@echo off&setlocal enabledelayedexpansion

::设置账号与密码文件路径
set "account=账号与密码文件.txt"

::设置拨号连接名称
set "name=拨号连接"

for /f "tokens=1,2 delims=  " %%a in ('type "%account%"') do (
    Rasdial "%name%" "%%a" "%%b"
    ::如果拨号成功,向百度发送1M数据包
    if !errorlevel! equ 0 (
        ping baidu.com -l 256
        if !errorlevel! neq 0 echo;网络错误
    )
)
pause
复制代码

flashercs

记得是 一个拨号连接对应一个账号吧;
账号密码.txt 格式: 拨号连接名称 账号 密码
一行一个账号
拨号连接名称与账号与密码三个变量不要用空格

@echo off
REM 设置拨号连接名称,账号与密码文件的路径;
set "rasdialbook=E:\test\登陆账号密码.txt"

for /f "tokens=1,2,3" %%a in ('type "%rasdialbook%"') do (
    rasdial "%%a" "%%b" "%%c"&&ping www.baidu.com||echo,连接失败
)
pause
exit /b
复制代码

lzc8191

回复 2# flashercs


    是的，一线，多账号拨号上网