[已解决]如何通过批处理获得指定文件的版本号？

yusukeboy · 发表于 2019-5-8 11:15:32

如何获得指定文件的版本号？路径是C:\Windows\System32\drivers\srv.sys
要获得如图中这个版本号
由于数量太多，希望能节约一点时间
谢谢大佬。

Batcher · 发表于 2019-5-8 11:31:55

wmic命令：

wmic datafile where "Name='C:\\Windows\\System32\\drivers\\srv.sys'" get Version /value

复制代码

test1.bat：

@echo off
for /f "tokens=2 delims==" %%i in ('wmic datafile where "Name='C:\\Program Files (x86)\\Tencent\\WeChat\\WeChat.exe'" get Version /value ^| findstr "="') do (
for /f %%j in ("%%i") do (
set "FileVersion=%%j"
)
)
echo %FileVersion%
pause

复制代码

test2.bat

@echo off
for /f %%i in ('powershell -c "(Get-Item -Path 'C:\Program Files (x86)\Tencent\WeChat\WeChat.exe').VersionInfo.ProductVersion"') do (
set "FileVersion=%%i"
)
echo %FileVersion%
pause

复制代码

yusukeboy · 发表于 2019-5-8 15:02:05

谢谢。完美解决

Batcher · 发表于 2021-6-6 11:47:53

【分享】批处理获取、比较新旧版本号并执行相应操作

@echo off
cd /d "%~dp0"
set "FileVersion=version.txt"
set "FileCheck=C:\Program Files (x86)\Tencent\WeChat\WeChat.exe"
set "VersionOld=0"
for /f %%i in ('powershell -c "(Get-Item -Path '%FileCheck%').VersionInfo.ProductVersion"') do (
set "VersionNew=%%i"
)
if not exist "%FileVersion%" (
>"%FileVersion%" echo %VersionNew%
echo %FileVersion% 文件不存在
goto :ExecZip
) else (
for /f %%i in ('type "%FileVersion%"') do (
set "VersionOld=%%i"
)
)
if "%VersionNew%" neq "%VersionOld%" (
echo 新旧版本号不一致
>>"%FileVersion%" echo %VersionNew%
goto :ExecZip
) else (
echo 新旧版本号一致
)
goto :eof
:ExecZip
echo 下面执行压缩命令

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] [已解决]如何通过批处理获得指定文件的版本号？