[文件操作] 【已解决】批处理如何播放当前日期文件夹的音乐列表

tmp05

试过各类定时音乐播放系统，都不行，不知批处理能否实现？
如图：按日期建立了几个文件夹，每个文件夹内有5首mp3

edison_zhu

我不会啊。简单分析一下
开机，判断当前时间,打开相应文件夹，打开所有文件
这样就行。
关于音乐播放器，默认的windows media不会添加到播放列表。会打开多个。所以安装个第三方播放器即可实现。

tmp05

结合这二贴的方法，估计能实现，但不会，哪位能帮写一个，谢了！
http://www.bathome.net/thread-22199-1-1.html
http://www.bathome.net/thread-55937-1-1.html

a20150604

将本文件和 各个日期的目录放在同一目录下, 批处理会在当前日期的目录里建立目录同名的 播放列表, 并加载播放
.m3u 文件不用你建, 是自动建的

C:\USERS\AA77D\MUSIC\PLAYLISTS
│  thread-56468-1-1.bat
│
└─20200807
        20200807.m3u
        Ana Alcaide - Tishri.mp3
        Nouri - Timeless.mp3
        Nova Menco - Tigris Palace.mp3
复制代码

REM http://www.bathome.net/thread-56468-1-1.html

@echo off & setlocal enabledelayedexpansion
chcp 936
cd /d "%~dp0"
REM echo;cd /d "%~dp0"

REM pause

for /f %%x in ('wmic path win32_localtime get /format:list ^| findstr "="') do (
    for /f "tokens=1-2 delims==" %%a in ("%%x") do (
        set "_%%a=0000%%b"
    )
)
REM set "YYYYmmdd_HHiiss=%_Year:~-4%%_Month:~-2%%_Day:~-2%_%_Hour:~-2%%_Minute:~-2%%_Second:~-2%"
set "YYYYmmdd=%_Year:~-4%%_Month:~-2%%_Day:~-2%"

if not exist "%~dp0%YYYYmmdd%\" (
    echo;program end. not exist "%~dp0%YYYYmmdd%\"
    pause
    exit
)

>"%~dp0%YYYYmmdd%\%YYYYmmdd%.m3u" dir /s /b "%~dp0%YYYYmmdd%\*.mp3"

echo;start "" wmplayer "%~dp0%YYYYmmdd%\%YYYYmmdd%.m3u"
start "" wmplayer "%~dp0%YYYYmmdd%\%YYYYmmdd%.m3u"

pause

exit
复制代码

Batcher

回复 1# tmp05

@echo off
echo 正在获取当前日期
for /f %%i in ('powershell -c "Get-Date -uformat '%%Y%%m%%d'"') do (
    set "Today=%%i"
)
echo,%Today%
cd /d "%~dp0"
set "PlayList=%~dp0MusicList.m3u"
echo 创建播放列表
dir /b /s /a-d "%Today%\*.mp3" >"%PlayList%"
start "" "C:\Program Files\Windows Media Player\wmplayer.exe" "%PlayList%"
复制代码

参考：
https://mp.weixin.qq.com/s/THUsB6JcWnww_QDkfX7zAg

tmp05

感谢楼上两位，试验成功了再来回复。

tmp05

回复  tmp05 参考：
Batcher 发表于 2020-8-7 20:03

7x64系统，运行提示乱码，但能按日期播放

Batcher

回复 7# tmp05


试试Q-04的方法：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ