[文本处理] [已解决]批处理如何批量删除不包含指定字符的行？

DDDYJQ1

目录下有许多TXT文件，如何批量删除不包含指定字符，。“”？！的行？
就是说删除不含有，。“”？！这六个标点符号的行，只要含有其中一个就不删除。即把这种只有文字没有符号的行删除

罗苴子罗苴佐罗罗卫罗卧泼罗秉忠罗洛浑罗统一罗振玉罗晟炎罗常培罗福成罗福苌罗殿国罗槃国罗槃城罗玛部落罗布林卡罗布策旺罗打鼓羌罗苴子统罗施鬼国罗洪点都罗垒云端罗桑云丹罗桑四朗罗桑年扎罗桑赤烈罗桑旺秀罗桑图托罗桑索巴

hlzj88

for /f %%g in ('dir /b/on *.txt') do (
  type "%%g"|findstr /i "， 。“ ” ？ ！">>temp.txt
  move /y temp.txt "%%g"
  )
复制代码

DDDYJQ1

对，就是这样。谢谢！
再加个要求，这没有符号的行，如果出现在倒数第一行或在倒数第二行就删除，否则就不删除。可以做到吗？要怎么改进？先谢了！

qixiaobin0715

你是说只删除倒数第一行和倒数第二行符合要求的行吗？

DDDYJQ1

对的，有没有办法改进？

qixiaobin0715

效率应当不算高，未经测试。

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    for /f %%x in ('type "%%a"^|find /c /v ""') do set m1=%%x&set /a m2=m1-1
    set n=0
    (for /f "delims=" %%i in ('type "%%a"') do (
        set /a n+=1
        set str=%%i
        for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
        if not !n!==!m1! if not !n!==!m2! echo,%%i
        if !n!==!m1! if not "!str!"=="%%i" echo,%%i
        if !n!==!m2! if not "!str!"=="%%i" echo,%%i
    ))>#%%a
)
pause
复制代码

DDDYJQ1

可以，谢谢！最好效率高一点

qixiaobin0715

回复 7# DDDYJQ1
这样可能效率要高一点，只有这水平了：

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    for /f %%x in ('type "%%a"^|find /c /v ""') do set /a m=%%x-1
    set n=0
    (for /f "delims=" %%i in ('type "%%a"') do (
        set /a n+=1
        if !n! lss !m! (
            echo,%%i
        ) else (
            set str=%%i
            for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
            if not "!str!"=="%%i" echo,%%i
        )
    ))>#%%a
)
pause
复制代码

qixiaobin0715

这样效率应当可以，用到了临时文件：

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do (
    set n=0
    (for /f "delims=" %%i in ('type "%%a"^|sort /+100') do (
        set /a n+=1
        if !n! lss 3 (
            set str=%%i
            for %%y in (， 。 “ ” ？ ！) do set str=!str:%%y=!
            if not "!str!"=="%%i" echo,%%i
        ) else (
            echo,%%i
        )
    ))>a.temp
sort /+100 a.temp>#%%a
)
del a.temp
pause
复制代码

qixiaobin0715

如果每行字符较多，可以将sort /+100的数增加，比如sort /+1000。总而言之sort后面的数字一定要大于最长行的字符数。

DDDYJQ1

好用，谢谢

cutebe

虽然结帖了，但还是贴个三方sed的，交流学习下。注意备份原文本文件！

::文本倒数两行如不包含中文标点则删除。
@echo off

::删除不含六中文标点的行
::sed "/，\|。\|“\|”\|？\|！/!d" sample.txt

for %%f in (*.txt)do for /f "delims=" %%n in ('sed -n "$=" "%%f"')do (
	set line=%%n
	call :Last2no "%%f" line-1
)
goto :eof

::最后两行若不含六中文标点，则删除
:Last2no file L2
set/aL2=%2
sed -i "%L2%,${/，\|。\|“\|”\|？\|！/!d}" %1
goto :eof
复制代码

flashercs

回复 12# cutebe


    如果文本只有一行，那么倒数第二行=0了

cutebe

是没有考虑单行情况！

qixiaobin0715

文本内容千变万化，写代码按通常情况即可，考虑太多这代码就复杂了，可根据具体情况进行调整。