[其他] 批处理如何获取文件md5？

304802301

1、第一段代码如下
（此代码是获取文件的md5，但遇到文件名字有空格的情况，会提示CertUtil: -hashfile 失败: 0x80070002 (WIN32: 2 ERROR_FILE_NOT_FOUND) CertUtil: 系统找不到指定的文件。如何解决？）

title md5批量生成脚本-by miles
setlocal enabledelayedexpansion
%~d0
cd %~dp0
if exist CMD-Name.txt del CMD-Name.txt
for /R %%s in (.,*) do (
echo %%s
) >>CMD-Name.txt
if exist CMD-md5.txt del CMD-md5.txt
for /f "skip=1" %%a in (CMD-Name.txt) do certutil -hashfile %%a MD5>>CMD-md5.txt
 
echo md5生成完毕
复制代码

====================================================================================================================================
2、第二段代码如下
（此代码可以获取文件的md5，包括文件名字有空格的文件，也能获取大md5，但有个致命的缺点，就是只能获取当前文件夹的md5，下面的文件夹里的文件就没法获取了，如何优化？）

@echo off
(for /f "delims=" %%i in ('dir /b /a-d') do (
    if "%%i" neq "%~nx0" (
        set /p =%%i <nul
        certutil -hashfile "%%i" MD5 | findstr /v "[^0-9a-z]"
    )
))>"MD5.txt"
复制代码

Batcher

回复 1# 304802301


第二段代码的第2行、第3行改成这样试试：
(for /f "delims=" %%i in ('dir /b /s /a-d') do (
    if "%%~nxi" neq "%~nx0" (

xp3000

@echo off & setlocal EnableDelayedExpansion
type nul>"%~dp0MD5.log"
for /f "delims=" %%a in ('dir /a-d /b /s *.*') do (
    if "%%~nxa" neq "%~nx0" (
    for /f "delims=" %%b in ('certutil -hashfile "%%a" MD5^|findstr /r /be /c:"[0-9a-f][0-9a-f ]*"') do (
        set "MD5=%%b"&set MD5=!MD5:^ =!&echo !MD5! = %%a>>"%~dp0MD5.log"
        )
    )
)
pause
复制代码

semiuel

第一段代码第10行中do certutil -hashfile %%a MD5>>CMD-md5.txt
给%%a加双引号，改成"%%a"

304802301

回复 4# semiuel


    我试过，不行的
不过还是感谢

304802301

回复 2# Batcher


大佬，能否再帮我优化下，我这边有一个文件夹，里面有将近200万个小文件，我在8号执行的代码，目前已经运行了3*24小时了，txt里没有记录任何文件的md5，cmd窗口也还在运行中，没有输出任何内容。
我现在不清楚是进程卡住了还是正在执行中，也不知道执行的进度是多少了，我怀疑是先全部验证出mad5，驻留在内存中，全部验证完后再一次性写入到txt里。能否帮我优化下，验证出一个文件的md5就立即输出到txt里，方便我查看，感谢

newswan

没有问题，每个文件验证完毕写入一次
可能程序暂停了。。。
敲下回车空格，鼠标点一下cmd窗口。

Batcher

回复 6# 304802301

@echo off
type nul>"MD5.txt" 
for /f "delims=" %%i in ('dir /b /s /a-d') do (
    if "%%~nxi" neq "%~nx0" (
        echo Processing %%i
        set /p =%%i <nul >>"MD5.txt"
        certutil -hashfile "%%i" MD5 | findstr /v "[^0-9a-z]" >>"MD5.txt"
    )
)
复制代码

304802301

回复  304802301
Batcher 发表于 2021-6-11 13:53

    大佬，这个bat在我本机（win10环境）下没问题（有路径+文件名，md5，且换行），但在服务器（win2008R2）环境下只能输出路径+文件名，无md5，且没有换行，是咋回事呢，。

304802301

回复 8# Batcher


    大佬 能不能在第一段代码的基础上，优化下文件名字有空格不能验证md5的问题。。第一段代码在服务器上是可以运行的，只不过文件名字有空格不能验证。

went

@echo off & cd /d "%~dp0"
set /a n=0
(
	for /r %%i in (*) do (
		certutil -hashfile "%%i" MD5 | findstr /v "[^0-9a-z]" 
		set /a "n+=1"
		call title %%n%%
	)
)>"MD5.txt"
pause&exit
复制代码

went

这个更快

@echo off & cd /d "%~dp0"
set /a n=0
(
	for /r %%i in (*) do (
		coder -show -action getmd5 -file "%%i" 2>nul
		echo;
		set /a "n+=1"
		call title %%n%%
	)
) > "MD5.txt"
pause&exit
复制代码

coder.exe

304802301

回复 11# went


能不能在这个基础上加一个路径和文件名？
完整的文件路径+文件名+MD5，换行。
感谢

went

回复 13# 304802301

路径|文件名|MD5

@echo off & cd /d "%~dp0"
set /a n=0
(
	for /r %%i in (*) do (
		set /p="%%i|%%~nxi|"<nul
		certutil -hashfile "%%i" MD5 | findstr /v "[^0-9a-z]" 
		set /a "n+=1"
		call title %%n%%
	)
) > "MD5.txt"
pause&exit
复制代码

304802301

回复 14# went


大佬，这个语句不能用在服务器系统上吗？我本机win10无问题，服务器win2008 r2，有路径，有文件名，但无md5，也不会换行。。。。。。。。