[已解决]批处理怎样把多个文件夹中相同文本名称合并后生成在新文件夹中

PCL0769 · 发表于 2021-9-6 11:41:19

202101文件夹内有以下文本
1.txt
2.txt
3.txt
4.txt
......
有N个文本
202102文件夹内有以下文本
1.txt
2.txt
3.txt
4.txt
......
有N个文本
202103文件夹内有以下文本
1.txt
2.txt
3.txt
4.txt
......
有N个文本
202104文件夹内有以下文本
1.txt
2.txt
3.txt
4.txt
......
有N个文本

202105文件夹内有以下文本
........
有N个文件夹
请帮忙写一个将以上N个文件夹中的N个同名的文本合并然后生成一个新的文件夹，文件夹中同样生成合并后同名的文本
合并文件夹内有以下文本
1.txt
2.txt
3.txt
4.txt
......
有N个文本

请老师抽空帮写一个批处理，谢谢!

qixiaobin0715 · 发表于 2021-9-6 13:53:00

回复 1# PCL0769
假设每个子文件夹中的文件名一样多，文件名都一样。
批处理文件放在与子文件夹平行的目录中。

@echo off
set "Folder=D:\abc"
md "%Folder%"
for %%i in (202101\*.txt) do (
(for /d %%a in (*) do (
type "%%a\%%~nxi"
))>"%Folder%\%%~nxi"
)
pause

复制代码

PCL0769 · 发表于 2021-9-6 14:04:07

本帖最后由 PCL0769 于 2021-9-6 14:05 编辑

回复 PCL0769
假设每个子文件夹中的文件名一样多，文件名都一样。
批处理文件放在与子文件夹平行的目录 ...
qixiaobin0715 发表于 2021-9-6 13:53

老师好！谢谢！
出现下面提示：
，
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
系统找不到指定的文件。
请按任意键继续. . .

传不图片及附件
D:\数据\周转
文件夹在周转中，里面有202101 202102 202103.....文件夹，然后每个文件夹中有30多个记事本，1.TXT 2.TXT 3.TXT.......

qixiaobin0715 · 发表于 2021-9-6 14:15:00

本帖最后由 qixiaobin0715 于 2021-9-6 14:17 编辑

回复 3# PCL0769
D盘中abc文件夹中有无合并文件？
不要先顾着评分，解决问题才是关键。

PCL0769 · 发表于 2021-9-6 14:17:32

D:\数据\周转
文件夹在周转中，里面有202101 202102 202103.....文件夹，然后每个文件夹中有30多个记事本，1.TXT 2.TXT 3.TXT.......

将同名记事本合并后在周转文件夹中生成一个合并文件夹，合并文件夹中还是按原记事本名1.TXT 2.TXT 3.TXT.......保存

PCL0769 · 发表于 2021-9-6 14:21:45

D:\abc
有文件夹，里面有个%~nxa 0KB 没看到后缀是什么

qixiaobin0715 · 发表于 2021-9-6 14:26:54

回复 6# PCL0769
应当是复制代码时出现了问题，重新复制代码再试试

Batcher · 发表于 2021-9-6 14:28:43

回复 1# PCL0769

@echo off
set "SrcFolder=D:\数据\周转"
set "DstFolder=D:\数据\合并"
if not exist "%SrcFolder%" (
goto :eof
)
if not exist "%DstFolder%" (
md "%DstFolder%"
)
for /f "delims=" %%i in ('dir /b /ad "%SrcFolder%"') do (
for /f "delims=" %%j in ('dir /b /a-d "%SrcFolder%\%%i\*.txt" 2^>nul') do (
>"%DstFolder%\%%j" type "%SrcFolder%\%%i\%%j"
for /f "delims=" %%k in ('dir /b /ad "%SrcFolder%" ^| findstr /v /b /e "%%i"') do (
if exist "%SrcFolder%\%%k\%%j" (
>>"%DstFolder%\%%j" type "%SrcFolder%\%%k\%%j"
)
)
>>"%DstFolder%\%%j" echo,
)
goto :eof
)

复制代码

qixiaobin0715 · 发表于 2021-9-6 14:28:47

代码要放在D:\数据\周转下

PCL0769 · 发表于 2021-9-6 14:32:15

本帖最后由 PCL0769 于 2021-9-6 14:52 编辑

谢谢！
可能是自制时出错，重新复制后运行。正在生成中......

PCL0769 · 发表于 2021-9-6 14:41:24

合并成功，谢谢老师的帮助！

PCL0769 · 发表于 2021-9-6 15:12:26

回复 8# Batcher
@echo off
set "SrcFolder=D:\数据\周转"
set "DstFolder=D:\数据\周转\合并"

谢谢老师出手帮助！也成功合并。

PCL0769 · 发表于 2021-9-6 15:41:34

本帖最后由 PCL0769 于 2021-9-6 15:43 编辑

回复 8# Batcher
合并后的1.txt 38.0 MB (39,897,024 字节) 里面有重复，等于是一个数据生成了两次在合并记事本里面

用楼上老师的(abc)合并后1.txt 19.0 MB (19,950,522 字节)

PCL0769 · 发表于 2021-9-6 15:46:16

知道是什么原因了，新生成的合并文件夹不能放在同一个目录

newswan · 发表于 2021-9-6 20:50:48

本帖最后由 newswan 于 2021-9-6 20:58 编辑

如果放源目录下，要排除合并的文件，避免被读取

set sour=aaa
set dest=bbb
for /f "usebackq tokens=* delims=" %%a in (`dir /s /b "%sour%\*.txt"`) do (
type "%%~fa" >> "%dest%\%%~na.txt"
)

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理怎样把多个文件夹中相同文本名称合并后生成在新文件夹中

评分

评分