[分享]批处理判断输入密码错误超过3次之后退出

Batcher

【问题描述】

谁帮忙看看怎么输入错误3次后才退出，现在是一次直接退出

Batcher

【解决方案】

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "ScriptPassword=bbs.bathome.net"
   
4. set "InputCount=0"
   
5. set "InputMax=3"
   
6. 
   
7. :GetPassword
   
8. set "InputPassword="
   
9. set /p "InputPassword=Please input password: "
   
10. set /a InputCount+=1
    
11. if "!InputPassword!" neq "%ScriptPassword%" (
    
12.     if !InputCount! lss %InputMax% (
    
13.         goto :GetPassword
    
14.     ) else (
    
15.         goto :PasswordWrong
    
16.     )
    
17. ) else (
    
18.     goto :PasswordCorrect
    
19. )
    
20. 
    
21. :PasswordWrong
    
22. echo You tried too many times.
    
23. goto :End
    
24. 
    
25. :PasswordCorrect
    
26. echo Hello World
    
27. goto :End
    
28. 
    
29. :End
    
30. pause
    
31. goto :eof

复制代码

Batcher

输入密码显示星号，且限制输错密码的次数：

1. @echo off
   
2. setlocal enabledelayedexpansion
   
3. set "ScriptPassword=BatHome"
   
4. set "InputCount=0"
   
5. set "InputMax=3"
   
6. set "str=0 1 2 3 4 5 6 7 8 9 a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
   
7. for %%a in (%str%) do (
   
8.     set /a n+=1
   
9.     set ".!n!=%%a"
   
10. )
    
11. 
    
12. :PasswordLength
    
13. set StrLen=0
    
14. for /f "skip=1 delims=:" %%a in ('^(echo "%ScriptPassword%"^&echo,^)^|findstr /o ".*"') do (
    
15.     set /a StrLen=%%a-5
    
16. )
    
17. 
    
18. :GetPassword
    
19. cls
    
20. set /p =请输入密码：<nul
    
21. if defined pwds (
    
22.     set /p =%pwds%<nul
    
23. )
    
24. if "%m%" equ "%StrLen%" (
    
25.     echo,
    
26.     goto :VerifyPassword
    
27. )
    
28. choice /n /cs /c %str: =%
    
29. set "pwds=%pwds%*"
    
30. set "pwd=%pwd%!.%errorlevel%!"
    
31. set /a m+=1
    
32. goto :GetPassword
    
33. 
    
34. :VerifyPassword
    
35. set /a InputCount+=1
    
36. if "!pwd!" neq "%ScriptPassword%" (
    
37.     if !InputCount! lss %InputMax% (
    
38.         echo 密码错误
    
39.         pause
    
40.         set "m=0"
    
41.         set "pwds="
    
42.         goto :GetPassword
    
43.     ) else (
    
44.         goto :PasswordWrong
    
45.     )
    
46. ) else (
    
47.     goto :PasswordCorrect
    
48. )
    
49. 
    
50. :PasswordWrong
    
51. echo 输错密码次错过多
    
52. goto :End
    
53. 
    
54. :PasswordCorrect
    
55. echo 密码正确
    
56. goto :End
    
57. 
    
58. :End
    
59. pause
    
60. goto :eof

复制代码

扩展阅读：批处理输入密码但显示星号
http://bbs.bathome.net/thread-2130-1-1.html