[分享]批处理对比两个文件夹并把差异文件复制到新文件夹

Batcher · 发表于 2021-12-11 23:51:47

【问题描述】

获取A原始文件夹中的文件名，汇集成A.txt (需要带后缀）获取B文件夹中的文件名，汇集成B.TXT (需要带后缀）将A.TXT与B.TXT做对比（不带后缀判断，只判断文件名），将A比B多的文件名提取成C.TXT（带A文件的后缀），建立文件夹C，将C.TXT中的文件从A文件夹复制过来。

Batcher · 发表于 2021-12-11 23:52:03

【解决方案】

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
pushd "A"
dir /b /a-d >"..\A.txt"
popd
pushd "B"
dir /b /a-d >"..\B.txt"
popd
if not exist "C" (
md "C"
)
type nul >"C.txt"
for /f "delims=" %%i in ('type "B.txt"') do (
set "%%~ni=1"
)
for /f "delims=" %%i in ('type "A.txt"') do (
if "!%%~ni!" neq "1" (
>>"C.txt" echo,%%i
copy /y "A\%%i" "C"
)
)

复制代码

smss · 发表于 2022-6-8 11:02:54

@echo off&cd /d "%~dp0"
set "WJ1=%~dp0b"
set "WJ2=%~dp0a"
set "WJ3=%~dp0c"
for /r "%WJ2%" %%i in (*) do (
set "file=%%i"
setlocal enabledelayedexpansion
if not exist "!file:%WJ2%=%WJ1%!" (
for %%j in ("!file:%WJ2%=%WJ3%!") do (
endlocal
md "%%~dpj" 2>nul
copy "%%i" "%%~dpj"
)
) else endlocal
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [分享]批处理对比两个文件夹并把差异文件复制到新文件夹

评分