[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

【已解决】【有偿求助】一个批处理具体要求来看

本帖最后由 1370481811 于 2022-1-4 09:09 编辑

在winpe系统中使用
pe系统启动时,在进入桌面之前先调用这个脚本
用来设置多个系统变量

脚本启动后,

/////画面1
标题 更改WINPE系统PATH
在上方某处显示系统的内存信息,内存大小
简介:就是文字介绍
减少X盘写入降低内存占用,小内存电脑可以运行更多软件。可保存winpe用户数据

下面可以用键盘 123 选择3个选项


★★1,【继续】
选择此项后从脚本简介(画面1)进入////画面2,////画面2上方也保留显示内存信息,////画面2中部是本地的分区信息
C:\ 卷标 总空间,可用空间
D:\   
E:\
....
请通过键盘选择分区只需输入字母
选择了分区之后,脚本继续执行, 在所选择的分区根目录建立一个PETMP.VHD虚拟磁盘文件,大小128GB,动态扩展,卷标PETMP,挂载为Y盘,然后执行修改变量如下
SETX USERPROFILE Y:\User
SETX APPDATA Y:\User\AppData\Roaming
SETX ALLUSERSPROFILE Y:\ProgramData
SETX CommonProgramFiles "Y:\Program Files\Common Files"
SETX CommonProgramFiles(x86) "Y:\Program Files (x86)\Common Files"
SETX CommonProgramW6432 "Y:\Program Files\Common Files"
SETX PUBLIC Y:\User\Public
SETX ProgramData "Y:\ProgramData"
SETX ProgramFiles "Y:\Program Files"
SETX ProgramFiles(x86) "Y:\Program Files (x86)"
SETX ProgramW6432 "Y:\Program Files"
SETX TEMP Y:\Windows\TEMP
SETX TMP Y:\Windows\TEMP
打印执行信息失败或成功并返回画面1

★★2, 【加载以前的配置】

选2之后可以for搜索全部分区根目录的PETMP.VHD并且挂载,(变量也对接)上面的 SETX。脚本窗口可以打印下执行信息,打印执行信息,成功或失败,没有找到文件,并返回画面1。
这样pe启动后相当于保存工作了

★★3,【取消】

是否取消? y/n  y自动关闭窗口

报酬150元人民币
支付方式:支付宝
联系方式 qq 928274096

  1. @echo off
  2. title 更改WINPE系统PATH
  3. :Menu
  4. cls
  5. call :ShowMemoryInfo
  6. call :ShowHelp
  7. echo.
  8. echo.           __________________________________________________________
  9. echo.                                                                  
  10. echo.                              选项                                 
  11. echo.                                                                  
  12. echo.                [1] 显示分区信息                                   
  13. echo.           __________________________________________________________
  14. echo.                                                                  
  15. echo.                [2] 加载以前配置                                   
  16. echo.           __________________________________________________________
  17. echo.                                                                  
  18. echo.                [3] 取消                                          
  19. echo.           __________________________________________________________
  20. echo.
  21. echo.
  22. choice /C:123  /M ">    请按键选择 "
  23. if %errorlevel% equ 1 goto CreateConfig
  24. if %errorlevel% equ 2 goto LoadConfig
  25. if %errorlevel% equ 3 goto Quit
  26. pause
  27. exit /b
  28. :CreateConfig
  29. cls
  30. call :ShowMemoryInfo
  31. set drives=
  32. setlocal ENABLEDELAYEDEXPANSION
  33. for /f "skip=1 tokens=1-4" %%A in ('wmic path Win32_Volume where "DriveLetter<>NULL" get Name^,FreeSpace^,Capacity^,Label') do (
  34.   echo.%%D %%C %%A %%B
  35.   set drives=!drives!%%D
  36. )
  37. set "drives=%drives::\=%"
  38. echo.
  39. choice /c %drives% /m "请选择分区:"
  40. set /a start=%errorlevel%-1
  41. set drive=!drives:~%start%,1!
  42. set vhd=%drive%:\PETMP.VHD
  43. echo 创建VHD: %vhd%
  44. set tmpfile="%temp%\~%random%~.txt"
  45. >%tmpfile% (
  46.   echo create vdisk file=%vhd% maximum=128000 type=expandable
  47.   echo select vdisk file=%vhd%
  48.   echo attach vdisk
  49.   echo clean
  50.   echo convert gpt
  51.   echo create partition primary
  52.   echo format fs=NTFS label="PETMP" quick
  53.   echo assign letter=Y
  54.   echo exit
  55. )
  56. diskpart /s %tmpfile%
  57. del %tmpfile%
  58. call :SetEnvironment
  59. endlocal
  60. pause
  61. goto Menu
  62. exit /b
  63. :LoadConfig
  64. cls
  65. call :ShowMemoryInfo
  66. set vhd=
  67. for /f "skip=1 tokens=1" %%A in ('wmic path Win32_Volume where "DriveLetter<>NULL" get Name') do (
  68.   if exist "%%APETMP.VHD" set vhd=%%APETMP.VHD
  69. )
  70. if not defined vhd (
  71.   echo.未找到PETMP.VHD,准备创建...
  72.   pause
  73.   goto CreateConfig
  74. )
  75. echo 检测到VHD位置:%vhd%
  76. set tmpfile="%temp%\~%random%~.txt"
  77. >%tmpfile% (
  78.   echo select vdisk file=%vhd%
  79.   echo attach vdisk
  80.   echo assign letter=Y
  81.   echo exit
  82. )
  83. diskpart /s %tmpfile%
  84. del %tmpfile%
  85. call :SetEnvironment
  86. pause
  87. goto Menu
  88. exit /b
  89. :SetEnvironment
  90. SETX USERPROFILE Y:\User
  91. SETX APPDATA Y:\User\AppData\Roaming
  92. SETX ALLUSERSPROFILE Y:\ProgramData
  93. SETX CommonProgramFiles "Y:\Program Files\Common Files"
  94. SETX CommonProgramFiles(x86) "Y:\Program Files (x86)\Common Files"
  95. SETX CommonProgramW6432 "Y:\Program Files\Common Files"
  96. SETX PUBLIC Y:\User\Public
  97. SETX ProgramData "Y:\ProgramData"
  98. SETX ProgramFiles "Y:\Program Files"
  99. SETX ProgramFiles(x86) "Y:\Program Files (x86)"
  100. SETX ProgramW6432 "Y:\Program Files"
  101. SETX TEMP Y:\Windows\TEMP
  102. SETX TMP Y:\Windows\TEMP
  103. exit /b
  104. :Quit
  105. choice /C YN /M "是否退出?"
  106. if %errorlevel% equ 1 exit /b
  107. if %errorlevel% equ 2 goto Menu
  108. exit /b
  109. :ShowMemoryInfo
  110. echo.=========================== 当前内存信息(KB) ====================================
  111. wmic OS get FreePhysicalMemory,FreeVirtualMemory,TotalVisibleMemorySize,TotalVirtualMemorySize /format:table
  112. echo.============================================================================
  113. exit /b
  114. :ShowHelp
  115. echo.***************************************************************************
  116. echo.** 减少X盘写入降低内存占用,小内存电脑可以运行更多软件。可保存winpe用户数据 *****
  117. echo.***************************************************************************
  118. exit /b
复制代码
微信:flashercs
QQ:49908356

TOP

返回列表