[已解决]求大神们写一个从本地上传到FTP的bat

4298728

本地文件夹不定时拷入新文件或者文件夹，需要把新文件或者文件夹上传到FTP服务器，只上传最新的内容。
1.ftp服务器看完文件一般都会删除。
2.只知道ftp服务器的账号密码。
3.本地文件夹路径有些很深，要求上传到ftp服务器时保持原有的路径和名字，ftp服务器不存在的文件夹能自动新建。
暂时想到用时间戳，检查本地目录哪些文件是今天产生的，如果这个目录下有今天产生的文件，就上传到FTP服务器。

idwma

1. @echo off&setlocal enabledelayedexpansion
   
2. set ip=127.0.0.1
   
3. set u=user
   
4. set p=password
   
5. set cfg=ftp.cfg
   
6. (
   
7. echo %u%
   
8. echo %p%
   
9. echo type binary
   
10. )>"%cfg%"
    
11. (for /f "delims=" %%i in ('dir /b/s /a-d') do (
    
12.     for /f %%j in ("%%~ti") do (
    
13.         if not "%%~nxi"=="%~nx0" if not "%%~nxi"=="%cfg%" if "%%j"=="%date:~0,10%" (
    
14.             set "d=%%~dpi"
    
15.             call set "d=%%d:!cd!=%%"
    
16.             echo mkdir "!d:\=/!"
    
17.             echo cd "!d:\=/!"
    
18.             set "d=%%i"
    
19.             call set "d=%%d:!cd!\=%%"
    
20.             echo put "!d:\=/!"
    
21.         )
    
22.     )
    
23. ))>>"%cfg%"
    
24. echo bye>>"%cfg%"
    
25. ftp -i -v -s:"%cfg%" %ip%
    
26. del "%cfg%"
    
27. pause
    

复制代码

4298728

回复 2# idwma


    大佬，这个怎么用，本地文件夹和ftp目标地址在哪设置？

idwma

第二行是ftp地址
可以把bat保存到本地文件夹里后运行
也可以在开头加一行指定文件夹路径

1. cd /d "f:\test\"

复制代码

4298728

@echo off&setlocal enabledelayedexpansion
cd /d "D:\ToUnicmicro\"    //本地文件夹路径
set ip=192.168.9.89        //ftp地址
set u=test                       //账号
set p=Aa4298728.          //密码
set cfg=ftp.cfg
(
echo %u%
echo %p%
echo type binary
)>"%cfg%"
(for /f "delims=" %%i in ('dir /b/s /a-d') do (
    for /f %%j in ("%%~ti") do (
        if not "%%~nxi"=="%~nx0" if not "%%~nxi"=="%cfg%" if "%%j"=="%date:~0,10%" (
            set "d=%%~dpi"
            call set "d=%%d:!cd!=%%"
            echo mkdir "!d:\=/!"
            echo cd "!d:\=/!"
            set "d=%%i"
            call set "d=%%d:!cd!\=%%"
            echo put "!d:\=/!"
        )
    )
))>>"%cfg%"
echo bye>>"%cfg%"
ftp -i -v -s:"%cfg%" %ip%
del "%cfg%"
pause

大佬，请问是这样子吗？

idwma

回复 5# 4298728


    没有ftp服务器没试过,你运行一下试试看有没有效

4298728

回复 6# idwma
用户(192.168.9.89none)):

ftp> type binary
ftp> bye
请按任意键继续. . .

运行后在CMD界面显示如上

4298728

回复 6# idwma

把本地磁盘D:\ToUnicmicro目录下的文件及文件夹上传到ftp://192.168.9.89/ 的D:\ftp文件夹上，要求：1.只上传今天产生的文件及文件夹，具体文件格式不确定。2.上传到ftp的文件和文件夹保持原有的路径和名称。

大佬麻烦再帮我看看。感谢

idwma

回复 8# 4298728

1. @echo off&setlocal enabledelayedexpansion
   
2. cd /d "D:\ToUnicmicro\"
   
3. set ip=192.168.9.89
   
4. set port=21
   
5. set u=test
   
6. set p=Aa4298728
   
7. set fd=/ftp
   
8. 
   
9. set cfg=%tmp%\ftp.cfg
   
10. (
    
11. echo open %ip% %port%
    
12. echo %u%
    
13. echo %p%
    
14. echo type binary
    
15. echo mkdir %fd%
    
16. echo cd %fd%
    
17. for /f "delims=" %%i in ('dir /b/s /a-d') do (
    
18.     for /f %%j in ("%%~ti") do (
    
19.         if "%%j"=="%date:~0,10%" if not "%%~nxi"=="%~nx0" (
    
20.             set "d=%%~dpi"
    
21.             call set "d=%%d:!cd!=%%"
    
22.             if not "!d!"=="!dd!" if not "!d!"=="\" (
    
23.                 set dd=!d!
    
24.                 set d=!d:~1,-1!
    
25.                 set t=
    
26.                 for /f "delims=" %%a in ('"echo;!d:\=&echo;!"') do (
    
27.                     set t=!t!/%%a
    
28.                     echo mkdir "%fd%!t!"
    
29.                 )
    
30.             )
    
31.             echo cd "%fd%/!d:\=/!"
    
32.             set "d=%%i"
    
33.             call set "d=%%d:!cd!\=%%"
    
34.             echo put "!d:\=/!"
    
35.         )
    
36.     )
    
37. )
    
38. echo bye
    
39. )>"%cfg%"
    
40. ftp -i -v -s:"%cfg%"
    
41. del "%cfg%"
    
42. pause
    

复制代码

4298728

回复 9# idwma

大佬，这个代码在本地运行后，在我的ftp服务器上的D:\ftp下新建了一个名为ftp的目录，里面的内容是空的，我本地D:\ToUnicmicro里面是有昨天新建的文件。

4298728

回复 9# idwma


    再次运行提示如下：
ftp> open 192.168.9.89 21
用户(192.168.9.89none)):

ftp> type binary
ftp> mkdir /ftp
Directory already exists
ftp> cd /ftp
ftp> bye
请按任意键继续. . .

idwma

不指定服务器文件夹可以把第7行删了
你不是说只上传今天的文件吗?你在D:\ToUnicmicro里随便新建一个空文件试试

4298728

回复 12# idwma


    是上传今天的文件，我刚才说错了。我把set fd=/ToUnicmicro/改成这样应该没问题吧？我现在测试是没问题的了。能不能加您微信，感谢一下大佬。

4298728

回复 12# idwma


ftp> open 192.168.9.89 21
用户(192.168.9.89none)):

ftp> type binary
ftp> mkdir /ToUnicmicro/
ftp> cd /ToUnicmicro/
ftp> cd "/ToUnicmicro//"            大佬，顺便问一下，末尾的这个 // 是什么意思
ftp> put "新建文本文档 (2).txt"

idwma

回复 13# 4298728

路径结尾不要加/
    set fd=/ToUnicmicro