批处理怎样替换输入的变量？

帝尊 · 发表于 2023-1-19 15:33:33

输入一些符号，按回车后如果发现输入的内容有*号，那么就再次提示输入A-Z或者C-T这样的。就会把之前的*号替换成A-Z或者C-T，然后生成对应的内容。

例如：

输入H8U-R8*
检测到*号后提示输入数值
输入C-T后生成
H8U-R8C
H8U-R8D
H8U-R8E
H8U-R8F
H8U-R8H
H8U-R8J
……
以此类推

77七 · 发表于 2023-1-19 21:24:48

@echo off
setlocal enabledelayedexpansion
set /p str=请输入:
(echo %str% | find "#" || goto:eof)>nul
set /p letter=输入开始、末尾（例： A-F ）:
set startL=!letter:~0,1!
set endL=!letter:~2,1!
for /f "tokens=2 delims=%startL%%endL%" %%A in ("1ABCDEFGHIJKLMNOPQRSTUVWXYZ1") do (
set letters=%startL%%%A%endL%
)
for /l %%i in (0,1,100) do (
if not "!letters:~%%i,1!" equ "" (
set n=!letters:~%%i,1!
call echo %str:#=!n!%
)
)
pause

复制代码

我太菜了，对通配符做替换，我不会...只好换成 # ，顺便等待高手解答

帝尊 · 发表于 2023-1-20 08:13:42

回复 2# 77七

非常感谢。

帝尊 · 发表于 2023-1-20 11:07:21

回复 2# 77七
大神，你看这样行不行。
当检测输入的字符内容H8U-R8C的时候，如果检测到-R8后面没有字符就提示输入A-Z？
比如
我输入一个H8U-R8，那么就提示，
如果输入H8U-R8C就继续下面的任务。

77七 · 发表于 2023-1-20 12:25:24

回复 4# 帝尊

@echo off
setlocal enabledelayedexpansion
set /p str=请输入:
set str2=!str:*-R8=!
if "!str2!" equ "" (
goto :A
) else (
goto :B
)
:A
set /p letter=输入开始、末尾（例： A-F ）:
set startL=!letter:~0,1!
set endL=!letter:~2,1!
for /f "tokens=2 delims=%startL%%endL%" %%A in ("1ABCDEFGHIJKLMNOPQRSTUVWXYZ1") do (
set letters=%startL%%%A%endL%
)
for /l %%i in (0,1,100) do (
if not "!letters:~%%i,1!" equ "" (
set n=!letters:~%%i,1!
echo !str!!n!
)
)
pause
exit
:B
echo 继续任务
pause

复制代码

terse · 发表于 2023-1-20 13:42:31

你开头输入字符是不是固定的“H8U-R8”？对输入位数和字符具体什么要求

帝尊 · 发表于 2023-1-28 13:08:16

本帖最后由帝尊于 2023-1-28 13:15 编辑

回复 6# terse

只需要最后一位有变化。

帝尊 · 发表于 2023-1-28 13:22:12

回复 5# 77七

再次感谢

terse · 发表于 2023-1-29 16:09:33

@echo off&setlocal enabledelayedexpansion
set "var=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set /p str=请输入:
set "s1=%str:~-1%"
if "%s1%" neq "*" if "!var:*%s1%=!" neq "!var!" goto :end
set str=%str:~,-1%
:start
set /p s1=请输入(A-Z):
if "%s1%" == "*" goto :start
if "%s1:~1%" neq "" goto :start
if "!var:*%s1%=!" == "!var!" goto :start
set str=%str%%s1%
:end
set "h=FEDCBA9876543210"
set "t=!var:*%s1%=!"
set "s=!t!"
set len=0
if "!s:~16!" neq "" (set len=16&set "s=!s:~16!")
set s=!s!!h!&set/a "len+=0x!s:~16,1!"
for /l %%i in (0,1,!len!) do echo !str:~,-1!!t:~%%i,1!
pause

复制代码

回复 7# 帝尊

帝尊 · 发表于 2023-1-30 08:18:39

回复 9# terse

非常感谢。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 批处理怎样替换输入的变量？