[分享]批处理+PDFtk+Ghostscript删除pdf文件空白页

Batcher · 发表于 2023-7-31 20:34:03

【问题描述】

怎样删除pdf文件中的空白页？

Batcher · 发表于 2023-7-31 20:34:18

【解决方案】

处理单个PDF文件.bat

@echo off
REM 处理之前的文件名
set "OldFile=1.pdf"
REM 处理之后的文件名
set "NewFile=2.pdf"
REM 1、下载并安装 Ghostscript 这个命令行工具
REM https://www.ghostscript.com/releases/gsdnld.html
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files\gs\gs10.01.2\bin;%path%"
REM 1、下载并安装 PDFtk 这个命令行工具
REM http://bcn.bathome.net/s/tool/index.html?key=PDFtk
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files (x86)\PDFtk Server\bin;%path%"
set "NonBlank="
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%a in ('gswin64c.exe -q -o - -sDEVICE^=ink_cov "%OldFile%" ^| findstr /n "CMYK"') do (
echo %%b | findstr "[1-9]" >nul
if not errorlevel 1 (
set "NonBlank=!NonBlank! %%a"
)
)
pdftk.exe "%OldFile%" cat !NonBlank! output "%NewFile%"

复制代码

Batcher · 发表于 2023-8-1 11:43:54

处理多个PDF文件.bat

@echo off
REM 处理之前pdf所在的文件夹
set "OldFolder=C:\Test\PDF"
REM 处理之后pdf所在的文件夹
set "NewFolder=C:\Test\PDF-DelBlank"
REM 1、下载并安装 Ghostscript 这个命令行工具
REM https://www.ghostscript.com/releases/gsdnld.html
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files\gs\gs10.01.2\bin;%path%"
REM 1、下载并安装 PDFtk 这个命令行工具
REM http://bcn.bathome.net/s/tool/index.html?key=PDFtk
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files (x86)\PDFtk Server\bin;%path%"
cd /d "%OldFolder%"
if not exist "%NewFolder%" (
md "%NewFolder%"
)
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
echo Processing file: %%i
set "NonBlank="
for /f "tokens=1* delims=:" %%a in ('gswin64c.exe -q -o - -sDEVICE^=ink_cov "%%i" ^| findstr /n "CMYK"') do (
echo %%b | findstr "[1-9]" >nul
if not errorlevel 1 (
set "NonBlank=!NonBlank! %%a"
)
)
pdftk.exe "%%i" cat !NonBlank! output "%NewFolder%\%%~nxi"
)

复制代码

453765918 · 发表于 2023-11-29 11:20:59

word文档能批量删除空白页吗？

yyz219 · 发表于 2023-11-30 09:45:11

谢谢分享哦

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [分享]批处理+PDFtk+Ghostscript删除pdf文件空白页