[已解决]迅雷已完成文件复制到Bitcomt过程中变量和语法的问题

thp2008

我让Ai给我写了个将迅雷已下载完成的部分（跳过所有.bt.xltd文件），复制到BitComet 继继续下载，同时删除BitComet 同目录下的同名.bc!文件。
1、但是Ai始终写的，都没办法，成功跳过所有.bt.xltd文件
2、就是删除BitComet 同目录下的同名.bc!文件，Ai所始终处理不了.bc!后面这个感叹号。所以无法成功删除。
3、最好帮我加一个判断，就是迅雷已下载完成的，BitComet也完成了的，这种就跳过，不要复制了。也就是，第一段，得出的文件名，加多一个判断，如果在Bitcomt中也存在，并且没有.bc!那就跳过。
Ai也没那么聪明，有些东西，还是要靠各位高手。
帮我看看，修复这些问题。谢谢！

1. @echo off
   
2. title 将迅雷已下载完成的部分，复制到BitComet 继继续下载，同时删除BitComet 同名.bc!文件。
   
3. 
   
4. setlocal enabledelayedexpansion
   
5. 
   
6. set xl=F:\XunLei\原创精品电影1000GB电影
   
7. set bt=E:\BitComet\原创精品电影1000GB电影
   
8. 
   
9. echo.
   
10. 
    
11. rem 递归复制文件和目录结构，排除%xl%目录下的*.bt.xltd文件
    
12. echo 正在检查并移动文件...
    
13. for /r "%xl%" %%i in (*) do (
    
14.     set "exclude=%%i"
    
15.     if "!exclude!" neq ".bt.xltd" (
    
16.         set "source=%%i"
    
17.         set "destination=!source:%xl%=%bt%!"
    
18.         for %%d in (!destination!) do (
    
19.             set "destination=%%~dpd"
    
20.         )
    
21. 
    
22. rem 检查BitComet目录是否存在同名的.bc!文件
    
23. set "bcfile=!destination!%%~nxi.bc^!"
    
24. 
    
25.         if exist "!bcfile!" (
    
26.             echo 删除已存在的.bc!文件: !bcfile!
    
27.             del "!bcfile!"
    
28.         )
    
29. 
    
30.         rem 创建目标目录（如果不存在）
    
31.         if not exist "!destination!" (
    
32.             mkdir "!destination!"
    
33.         )
    
34. 
    
35.         rem 复制文件到目标目录
    
36.         copy "!source!" "!destination!"
    
37.     )
    
38. 
    
39. )
    
40. 
    
41. echo.
    
42. echo 文件移动完成！
    
43. pause
    
44. 
    
45. endlocal
    

复制代码

Batcher

回复 1# thp2008


请把迅雷和BitComet的目录结构打包上传到网盘
1、全部使用0字节空文件，只需要文件名说清楚对应关系即可
2、包含顶楼描述的所有场景

thp2008

https://netcut.cn/bathome
打开后，在中间，选“文件（1个）”下载链接在下面

Batcher

回复 3# thp2008


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

1. @echo off
   
2. set "xl=F:\XunLei\原创精品电影1000GB电影"
   
3. set "bt=E:\BitComet\原创精品电影1000GB电影"
   
4. echo 正在检查并移动文件...
   
5. for /f "delims=" %%i in ('dir /b /s /a-d "%xl%" ^| findstr /v /i /e /c:".bt.xltd"') do (
   
6.     set "SourceFolder=%%~dpi"
   
7.     set "SourceFile=%%~nxi"
   
8.     set "bcfile=%%~nxi.bc!"
   
9.     setlocal enabledelayedexpansion
   
10.     set "DestinationFolder=!SourceFolder:%xl%=%bt%!"
    
11.     if exist "!DestinationFolder!" (
    
12.         if exist "!DestinationFolder!!SourceFile!" (
    
13.             REM 检查BitComet目录是否存在同名的.bc!文件
    
14.             if exist "!DestinationFolder!!bcfile!" (
    
15.                 del /f /q "!DestinationFolder!!bcfile!"
    
16.                 copy /y "!SourceFolder!!SourceFile!" "!DestinationFolder!"
    
17.             )
    
18.         ) else (
    
19.             copy /y "!SourceFolder!!SourceFile!" "!DestinationFolder!"
    
20.         )
    
21.     ) else (
    
22.         md "!DestinationFolder!"
    
23.         copy /y "!SourceFolder!!SourceFile!" "!DestinationFolder!"
    
24.     )
    
25.     endlocal
    
26. )
    
27. pause

复制代码

terse

xcopy /t 可以复制文件结构，而不复制文件，这样在后面时候可以少个判断

1. @echo off
   
2. set "xl=F:\XunLei\原创精品电影1000GB电影\"
   
3. set "bt=E:\BitComet\原创精品电影1000GB电影\"
   
4. xcopy "%xl%" "%bt%" /T /Y
   
5. for /f "delims=" %%i in ('dir /a-d /b /s "%xl%"^|findstr /ilve ".bt.xltd"') do (
   
6.      set "exclude=%%i"
   
7.      setlocal enabledelayedexpansion
   
8.      for /f "delims=" %%a in ("!exclude:%xl%=%bt%!") do (
   
9.           endlocal
   
10.           if exist "%%a.bc!" del "%%a.bc!"
    
11.            if not exist "%%a" copy "%%i" "%%a" /b /y
    
12.      )
    
13. )
    
14. pause

复制代码

thp2008

回复  thp2008


请参考Q-04把bat文件保存为ANSI编码：
Batcher 发表于 2023-9-19 14:49

感谢老大，我测试了一下，基本上可行，只是有一点小逻辑性问题：

就是我需要运行两次这个批处理才能满足要求，第一次，不能删除，复制过去的文件.bc!
再运行一次就删除了。但是两次运行都会再复制一次，测试的小文件，没关系，但是大文件，就很浪费时间。我根据你提供的代码 ，修改了一下，已经可以了。

1. @echo off
   
2. set "xl=F:\XunLei\原创精品电影1000GB电影"
   
3. set "bt=E:\BitComet\原创精品电影1000GB电影"
   
4. echo 正在检查并移动文件...
   
5. for /f "delims=" %%i in ('dir /b /s /a-d "%xl%" ^| findstr /v /i /e /c:".bt.xltd"') do (
   
6.     set "SourceFolder=%%~dpi"
   
7.     set "SourceFile=%%~nxi"
   
8.     set "bcfile=%%~nxi.bc!"
   
9.     setlocal enabledelayedexpansion
   
10.     set "DestinationFolder=!SourceFolder:%xl%=%bt%!"
    
11.     if not exist "!DestinationFolder!" md "!DestinationFolder!"
    
12.     if exist "!DestinationFolder!!bcfile!" (
    
13.         echo 删除BitComet目录已存同名的.bc！文件： "!DestinationFolder!!bcfile!"
    
14.         del /f /q "!DestinationFolder!!bcfile!"
    
15.     )
    
16. 
    
17.     if not exist "!DestinationFolder!!SourceFile!" (
    
18.     echo   开始复制文件： "!SourceFolder!!SourceFile!" "!DestinationFolder!"
    
19.         copy /y "!SourceFolder!!SourceFile!" "!DestinationFolder!"
    
20.     )
    
21.    
    
22.     endlocal
    
23. )
    
24. pause

复制代码

thp2008

其实，在这种案例中，不需要考虑目录结构，因为BitComet在下载开始的时候，将所有目录结构都创建完成了，只是迅雷才会下一点，建一点。但是我是要求从迅雷复制到BitComet单向复制，所以就不用考虑到建目录结构，也没有关系，是我没有讲请楚，我之前的版本，Ai帮我自动做上去的，它也可能不清楚，是这么回事。

77七

1. @echo off
   
2. set "f1=d:\XunLei"
   
3. set "f2=d:\BitComet"
   
4. robocopy "%f1%" "%f2%" /s /xc /xn /xo /xf *.bt.xltd
   
5. for /r "%f2%" %%i in (*.bc!) do (
   
6.         if exist "%%~dpni" (
   
7.                 del "%%i"
   
8.         )
   
9. )
   
10. pause & exit
    
11. 
    
12. 
    
13. xunlei
    
14. 1221.txt.bt.xltd
    
15. 更多电影下载请进www..com.rar
    
16. 
    
17. bitcomt
    
18. 1221.txt.bc!
    
19. 更多电影下载请进www..com.rar.bc!

复制代码