【已解决】求批处理命令，将文件夹里的所有文件重命名仅保留字母数字和标点字符，内详

crownking1983

求批处理命令，将文件夹里的所有文件重命名仅保留字符、字母和数字。
实例如下：

一个文件夹里有文件
2024.05.12 美杜莎 [15P 266M].zip
2024.05.14 小舞 [26P 204M].txt
2024.05.19 千仞雪 [20P 534M].rar

批处理命令执行后 这些文件名变成

2024.05.12 [15P 266M].zip
2024.05.14 [26P 204M].txt
2024.05.19 [20P 534M].rar

也就是将所有的汉字去掉 仅保留字母数字和标点字符。谢谢各路大神

aloha20200628

回复 1# crownking1983

好在文件名中的中文字段有空格界定，代码简化多了...

1. 
   
2. @echo off & for /f "delims=" %%F in (' dir /b/a-d "* * [*].*" ') do (
   
3.         for /f "tokens=1-2* delims= " %%a in ("%%~nxF") do ren "%%F" "%%a %%c"
   
4. )
   
5. pause&exit/b
   

复制代码

crownking1983

回复 2# aloha20200628


    那大神，请问中文与字母数字之间没有空格的话，会是什么样的呢？能否出一个中文与字母数字之间不带空格的批处理代码，以便以后遇到了使用

crownking1983

回复 2# aloha20200628


貌似格式必须是固定的死的方可

aloha20200628

回复 3# crownking1983

好吧，再给一个剔除中文字段的版本，无论其前后有无空格...

1. 
   
2. @echo off &setlocal enabledelayedexpansion
   
3. for /f "delims=" %%F in (' dir /b/a-d "* * [*].*" ') do (
   
4.         (call :_cutHZ "%%~nF" cF)
   
5.         ren "%%F" "!cF!%%~xF"
   
6. )
   
7. endlocal&pause&exit/b
   
8. :_cutHZ //REM 剔除文件名中包含的全部中文字符 限定文件名最大长度=260
   
9.         set "$s=%~1"&set "_s="
   
10.         for /L %%n in (0 1 260) do (
    
11.            set "c=!$s:~%%n,1!" &if "!c!"=="" set "%~2=!_s!" &exit/b
    
12.            if "!c!" leq "Z" set "_s=!_s!!c!"
    
13.         )
    
14.         exit/b
    

复制代码

如果不约束文件名格式，只须剔除其中的中文字段，则可改变以上代码第2行如下

1. for /f "delims=" %%F in (' dir /b/a-d "*.*" ') do (

复制代码

Five66

保存为ansi或gbk编码的bat

1. 
   
2. @echo off&pause
   
3. set "@self=%~nx0"
   
4. chcp 437>nul
   
5. setlocal enabledelayedexpansion
   
6. set aaa=1
   
7. for /f "eol=/ delims=" %%i in ('dir /b') do (
   
8. if "!aaa!" == "%aaa%" endlocal&chcp 936>nul
   
9. set /a ccc+=1
   
10. set @file=%%i
    
11. call set @file%%ccc%%=%%@file%%
    
12. )
    
13. for /f "eol=/ delims=" %%i in ('dir /b') do (
    
14. set /a bbb+=1
    
15. set @file=%%i
    
16. setlocal enabledelayedexpansion
    
17. for %%c in (!bbb!) do (
    
18. if "!@file!" neq "!@self!" (
    
19. echo,rename "!@file!"  to "!@file%%c:?=!"
    
20. rename "!@file!" "!@file%%c:?=!"
    
21. )
    
22. )
    
23. endlocal
    
24. )
    
25. pause&exit/b
    

复制代码

crownking1983

回复 5# aloha20200628


    实在是太牛逼了！感谢大佬！

crownking1983

回复 6# Five66


    这个也好牛逼啊 感谢大佬！