如何用bat脚本批量将左边的字，逐一替换成右边的字？

学习1995

例子：
AAAAAA絃AAAAAAA凢AAAAAAA縳AAAAAAA湏AAAAAAAAAAA㬰AAAAAAA宻AAAAAAA慿AAAAAAAAAAAAA煖AAAAAAA蹟AAAAAAA錄AAAAAAA吳AAAAAAA顚AAAAAAA

待处理的TXT文档中有几万字。需要将其中数百个的异体字替换成通用字。如：

絃        弦
凢        凡
縳        縛
湏        須
㬰        臾
宻        密
慿        憑
煖        暖
蹟        跡
錄        録
吳        吴
顚        顛

如何批量将左边的字，逐一替换成右边的字？求大神指点。感谢！

aloha20200628

回复 1# 学习1995

以下代码存为 test.bat 在当前目录中运行，须用utf-8编码保存（因转换字典表中有异体字超出简中编码字符集）
假定 1.txt 为当前目录下的源文件，2.txt 为转换结果文件
代码中5-16行对应 ‘转换字典表’，楼主可据此格式增减...

1. 
   
2. @echo off &chcp 65001>nul
   
3. (for /f "delims=" %%a in (1.txt) do (
   
4.         set "s=%%a"&setlocal enabledelayedexpansion
   
5.         for %%s in (
   
6.                 "絃=弦"
   
7.                 "凢=凡"
   
8.                 "縳=縛"
   
9.                 "湏=須"
   
10.                 "㬰=臾"
    
11.                 "宻=密"
    
12.                 "慿=憑"
    
13.                 "煖=暖"
    
14.                 "蹟=跡"
    
15.                 "錄=録"
    
16.                 "吳=吴"
    
17.                 "顚=顛"
    
18.         ) do set "s=!s:%%~s!"
    
19.         echo,!s!
    
20.         endlocal
    
21. ))>2.txt
    
22. pause&exit/b
    

复制代码

aloha20200628

回复 1# 学习1995

帮楼主再省点事儿...
假设转换字典表原始数据有数百行如下
絃        弦
凢        凡
縳        縛
...  ...  ...

已存为utf-8编码文件 "u8.dic"，并置于当前目录下，用以下代码可一气呵成楼主所求...

1. 
   
2. @echo off &chcp 65001>nul &setlocal enabledelayedexpansion
   
3. for /f "tokens=*" %%a in (u8.dic) do (set/a "n+=1"&set "_!n!=%%a")
   
4. (for /f "delims=" %%a in (1.txt) do (
   
5.         set "s=%%a"
   
6.         for /l %%n in (1,1,!n!) do for /f "tokens=1-2" %%x in ("!_%%n!") do set "s=!s:%%x=%%y!"
   
7.         echo,!s!
   
8. ))>2.txt
   
9. endlocal&pause&exit/b
   

复制代码

学习1995

回复 3# aloha20200628

非常感谢！很完美地解决了我的需求！