【已解决】求助，批处理如何快捷的批量删除某个变量中的指定字符

蚯蚓传奇

我想做的是用户输入一段话，然后用批处理自动去除句子中的停用词，我是这样写的:

1. @echo off
   
2. set /p a=:
   
3. set "a=%a:!=%"
   
4. set "a=%a:?=%"
   
5. set "a=%a:。=%"
   
6. set "a=%a:：=%"
   
7. ...
   
8. echo %a%
   
9. pause>nul
   
10. exit

复制代码

但是这样做的效率太低了
请问各位大神能不能帮我把这段代码优化一下，谢谢

77七

楼主写的其实挺好的，简单可靠。如以下这样写，此贴中提到的用call set 赋值，弊大于利。

1. @echo off
   
2. set /p a=:
   
3. for %%i in ("!" "?" "。") do (
   
4.         call set "a=%%a:%%~i=%%"
   
5. )
   
6. echo %a%
   
7. pause
   
8. exit

复制代码

代码错误，请参考3楼。

aloha20200628

回复 1# 蚯蚓传奇
回复 2# 77七

for %%c in ( ... ) 这个句式不能用于 ？ 和 * 这两个系统默认的通配符
字符串替换函数也不能替换 = 和 * 这两个字符
以下给出两个纯P版本实现批量替换...
版本一：
其中命令行参数中若采用 & 作为置换字符须用双引号包裹

1. 
   
2. @echo off &setlocal
   
3. set "s=zxc!123?qwe:789。mnb&456"
   
4. call :xxx ! ? 。 : "&"
   
5. echo,%s%
   
6. endlocal&pause&exit/b
   
7. :xxx
   
8.    if "%~1"=="" exit/b
   
9.    call set "s=%%s:%~1=%%"
   
10.    shift /1 & goto :xxx
    

复制代码

版本二：
多个置换字符用一个字符串链表表达，其中的分隔符采用 * 或采用 =，这两个均是替换函数禁用的字符

1. 
   
2. @echo off &setlocal
   
3. set "s=zxc!123?qwe:789。mnb&456"
   
4. set "cs=!*?*。*:*&"
   
5. :Loop
   
6. for /f "tokens=1* delims=*" %%a in ("%cs%") do set "cs=%%b"&call set "s=%%s:%%a=%%"
   
7. if "%cs%" neq "" goto :Loop
   
8. echo,%s%
   
9. pause&exit/b
   

复制代码

newswan

用 sed

1. echo %a% | sed -r -e '/s/[!?]/'

复制代码

或者用powershell

77七

回复 4# newswan


   
大佬，我用这个代码报错

1. sed: -e expression #1, char 1: unknown command: `''

复制代码

版本是sed (GNU sed) 4.8

aloha20200628

下载 sed.exe 如下 cmd 窗口一行流测试通过...

1. 
   
2. echo,"zxc!123?qwe:789。mnb&456^iop%()" | sed -r "s/[!\?。\:&^%%]//g"
   

复制代码

用纯P代码修理那些特殊字符确实须费心思，很容易 ‘触雷入坑’，借助外部方法可以轻松拿下，最简之道如 powershell 或 sed.exe，只不过前者首启略慢，后者则须预下载...
以下是批处调用 powershell 方法实现特殊字符替换的示例代码...

1. 
   
2. @echo off &setlocal
   
3. set "s=zxc!123?qwe:789。mnb&456^iop%()"
   
4. echo,"%s%"
   
5. for /f "delims=" %%s in ('powershell " '%s%' -replace '[!\?。\:&^%%]' " ') do set "s=%%s"
   
6. echo,"%s%"
   
7. endlocal&pause&exit/b
   

复制代码

newswan

回复 5# 77七

哎呀，手机上输入的，搞错了

后面应该是 's/[!?]//g'